Hello,
I commited eight patches. They are very simple, so I hope you don't
mind that I packed them in one mail. Below are the respective changelog
entries.
Have a nice day,
Stepan
* lib/autoconf/general.m4 (AC_MSG_CHECKING, AC_MSG_RESULT):
Put braces around the two echo commands, for consistency
with AC_MSG_ERROR and such.
* lib/m4sugar/m4sh.m4 (_AS_ECHO_LOG): New macro to factor out
common code; used in many places in the tree.
* lib/m4sugar/m4sh.m4 (AS_ESCAPE): Make the pattern a bit simpler;
use \& insetad of \1.
* lib/m4sugar/m4sh.m4 (_AS_ECHO_UNQUOTED): Move the macro lower;
no code change.
* lib/m4sugar/m4sugar.m4 (m4_ifset): Use m4_ifval.
* lib/autoconf/general.m4 (_AC_INIT_SRCDIR): Merge the two error
messages when ac_unique_file is not found.
* lib/autoconf/general.m4 (AC_CONFIG_MACRO_DIR): Simplify the
`if' at the end.
* bin/autoconf.as: Make more use of "shift 2" in option processing.
2005-05-24 Stepan Kasal <[EMAIL PROTECTED]>
* lib/autoconf/general.m4 (AC_MSG_CHECKING, AC_MSG_RESULT):
Put braces around the two echo commands, for consistency
with AC_MSG_ERROR and such.
--- lib/autoconf/general.m4 2005-05-24 08:04:39.000000000 +0200
+++ lib/autoconf/general.m4 2005-05-24 08:05:09.000000000 +0200
@@ -2020,16 +2020,16 @@
# AC_MSG_CHECKING(FEATURE)
# ------------------------
m4_define([AC_MSG_CHECKING],
-[_AS_ECHO_LOG([checking $1])
-_AS_ECHO_N([checking $1... ])[]dnl
+[{ _AS_ECHO_LOG([checking $1])
+_AS_ECHO_N([checking $1... ]); }dnl
])
# AC_MSG_RESULT(RESULT)
# ---------------------
m4_define([AC_MSG_RESULT],
-[_AS_ECHO_LOG([result: $1])
-_AS_ECHO([${ECHO_T}$1])[]dnl
+[{ _AS_ECHO_LOG([result: $1])
+_AS_ECHO([${ECHO_T}$1]); }dnl
])
2005-05-24 Stepan Kasal <[EMAIL PROTECTED]>
* lib/m4sugar/m4sh.m4 (_AS_ECHO_LOG): New macro to factor out
common code; used in many places in the tree.
Index: lib/autoconf/c.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/c.m4,v
retrieving revision 1.200
diff -u -r1.200 c.m4
--- lib/autoconf/c.m4 14 May 2005 07:00:39 -0000 1.200
+++ lib/autoconf/c.m4 24 May 2005 06:02:12 -0000
@@ -479,8 +479,7 @@
test -z "$CC" && AC_MSG_FAILURE([no acceptable C compiler found in \$PATH])
# Provide some information about the compiler.
-echo "$as_me:$LINENO:" \
- "checking for _AC_LANG compiler version" >&AS_MESSAGE_LOG_FD
+_AS_ECHO_LOG([checking for _AC_LANG compiler version])
ac_compiler=`set X $ac_compile; echo $[2]`
_AC_EVAL([$ac_compiler --version >&AS_MESSAGE_LOG_FD])
_AC_EVAL([$ac_compiler -v >&AS_MESSAGE_LOG_FD])
@@ -714,8 +713,7 @@
fi
fi
# Provide some information about the compiler.
-echo "$as_me:$LINENO:" \
- "checking for _AC_LANG compiler version" >&AS_MESSAGE_LOG_FD
+_AS_ECHO_LOG([checking for _AC_LANG compiler version])
ac_compiler=`set X $ac_compile; echo $[2]`
_AC_EVAL([$ac_compiler --version >&AS_MESSAGE_LOG_FD])
_AC_EVAL([$ac_compiler -v >&AS_MESSAGE_LOG_FD])
Index: lib/autoconf/fortran.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/fortran.m4,v
retrieving revision 1.190
diff -u -r1.190 fortran.m4
--- lib/autoconf/fortran.m4 14 May 2005 07:00:39 -0000 1.190
+++ lib/autoconf/fortran.m4 24 May 2005 06:02:12 -0000
@@ -361,8 +361,7 @@
[_AC_F95_FC _AC_F90_FC _AC_F77_FC])))
# Provide some information about the compiler.
-echo "$as_me:__oline__:" \
- "checking for _AC_LANG compiler version" >&AS_MESSAGE_LOG_FD
+_AS_ECHO_LOG([checking for _AC_LANG compiler version])
ac_compiler=`set X $ac_compile; echo $[2]`
_AC_EVAL([$ac_compiler --version >&AS_MESSAGE_LOG_FD])
_AC_EVAL([$ac_compiler -v >&AS_MESSAGE_LOG_FD])
@@ -526,7 +525,8 @@
# flags.
ac_save_FFLAGS=$[]_AC_LANG_PREFIX[]FLAGS
_AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS m4_default([$1],
[$ac_cv_prog_[]_AC_LANG_ABBREV[]_v])"
-(eval echo $as_me:__oline__: \"$ac_link\") >&AS_MESSAGE_LOG_FD
+eval ac_link_cmd=\"$ac_link\"
+_AS_ECHO_LOG([$ac_link_cmd])
ac_[]_AC_LANG_ABBREV[]_v_output=`eval $ac_link AS_MESSAGE_LOG_FD>&1 2>&1 |
grep -v 'Driving:'`
echo "$ac_[]_AC_LANG_ABBREV[]_v_output" >&AS_MESSAGE_LOG_FD
_AC_LANG_PREFIX[]FLAGS=$ac_save_FFLAGS
Index: lib/autoconf/general.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/general.m4,v
retrieving revision 1.857
diff -u -r1.857 general.m4
--- lib/autoconf/general.m4 20 May 2005 07:58:43 -0000 1.857
+++ lib/autoconf/general.m4 24 May 2005 06:02:12 -0000
@@ -2020,7 +2020,7 @@
# AC_MSG_CHECKING(FEATURE)
# ------------------------
m4_define([AC_MSG_CHECKING],
-[_AS_ECHO([$as_me:$LINENO: checking $1], AS_MESSAGE_LOG_FD)
+[_AS_ECHO_LOG([checking $1])
_AS_ECHO_N([checking $1... ])[]dnl
])
@@ -2028,7 +2028,7 @@
# AC_MSG_RESULT(RESULT)
# ---------------------
m4_define([AC_MSG_RESULT],
-[_AS_ECHO([$as_me:$LINENO: result: $1], AS_MESSAGE_LOG_FD)
+[_AS_ECHO_LOG([result: $1])
_AS_ECHO([${ECHO_T}$1])[]dnl
])
@@ -2090,7 +2090,7 @@
[{ ($2) >&AS_MESSAGE_LOG_FD
($1) 2>&AS_MESSAGE_LOG_FD
ac_status=$?
- echo "$as_me:$LINENO: \$? = $ac_status" >&AS_MESSAGE_LOG_FD
+ _AS_ECHO_LOG([\$? = $ac_status])
(exit $ac_status); }])
@@ -2108,7 +2108,7 @@
grep -v '^ *+' conftest.er1 >conftest.err
rm -f conftest.er1
cat conftest.err >&AS_MESSAGE_LOG_FD
- echo "$as_me:$LINENO: \$? = $ac_status" >&AS_MESSAGE_LOG_FD
+ _AS_ECHO_LOG([\$? = $ac_status])
(exit $ac_status); }])
Index: lib/autoconf/programs.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/programs.m4,v
retrieving revision 1.44
diff -u -r1.44 programs.m4
--- lib/autoconf/programs.m4 14 May 2005 07:00:40 -0000 1.44
+++ lib/autoconf/programs.m4 24 May 2005 06:02:13 -0000
@@ -79,7 +79,7 @@
continue
fi])dnl
ac_cv_prog_$1="$3"
- echo "$as_me:$LINENO: found $as_dir/$ac_word$ac_exec_ext"
>&AS_MESSAGE_LOG_FD
+ _AS_ECHO_LOG([found $as_dir/$ac_word$ac_exec_ext])
break 2
fi
done])
@@ -145,7 +145,7 @@
[for ac_exec_ext in '' $ac_executable_extensions; do
if AS_EXECUTABLE_P(["$as_dir/$ac_word$ac_exec_ext"]); then
ac_cv_path_$1="$as_dir/$ac_word$ac_exec_ext"
- echo "$as_me:$LINENO: found $as_dir/$ac_word$ac_exec_ext"
>&AS_MESSAGE_LOG_FD
+ _AS_ECHO_LOG([found $as_dir/$ac_word$ac_exec_ext])
break 2
fi
done])
Index: lib/m4sugar/m4sh.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/m4sugar/m4sh.m4,v
retrieving revision 1.140
diff -u -r1.140 m4sh.m4
--- lib/m4sugar/m4sh.m4 20 May 2005 12:08:19 -0000 1.140
+++ lib/m4sugar/m4sh.m4 24 May 2005 06:02:13 -0000
@@ -547,6 +547,13 @@
[_AS_ECHO_UNQUOTED([_AS_QUOTE([$1])], [$2])])
+# _AS_ECHO_LOG(STRING)
+# --------------------
+# Log the string to AS_MESSAGE_LOG_FD.
+m4_define([_AS_ECHO_LOG],
+[_AS_ECHO([$as_me:$LINENO: $1], [AS_MESSAGE_LOG_FD])])
+
+
# _AS_ECHO_N_PREPARE
# ------------------
# Check whether to use -n, \c, or newline-tab to separate
@@ -583,7 +590,7 @@
# ----------------------------------------
m4_define([AS_MESSAGE],
[m4_ifset([AS_MESSAGE_LOG_FD],
- [{ _AS_ECHO([$as_me:$LINENO: $1], [AS_MESSAGE_LOG_FD])
+ [{ _AS_ECHO_LOG([$1])
_AS_ECHO([$as_me: $1], [$2]);}],
[_AS_ECHO([$as_me: $1], [$2])])[]dnl
])
2005-05-24 Stepan Kasal <[EMAIL PROTECTED]>
* lib/m4sugar/m4sh.m4 (AS_ESCAPE): Make the pattern a bit simpler;
use \& insetad of \1.
Index: lib/m4sugar/m4sh.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/m4sugar/m4sh.m4,v
retrieving revision 1.140
diff -u -r1.140 m4sh.m4
--- lib/m4sugar/m4sh.m4 20 May 2005 12:08:19 -0000 1.140
+++ lib/m4sugar/m4sh.m4 24 May 2005 05:52:28 -0000
@@ -502,8 +502,8 @@
# Escape the CHARS in STRING.
m4_define([AS_ESCAPE],
[m4_bpatsubst([$1],
- m4_ifval([$2], [[\([$2]\)]], [[\([\"$`]\)]]),
- [\\\1])])
+ m4_dquote(m4_default([$2], [\"$`])),
+ [\\\&])])
# _AS_QUOTE_IFELSE(STRING, IF-MODERN-QUOTATION, IF-OLD-QUOTATION)
2005-05-24 Stepan Kasal <[EMAIL PROTECTED]>
* lib/m4sugar/m4sh.m4 (_AS_ECHO_UNQUOTED): Move the macro lower;
no code change.
Index: lib/m4sugar/m4sh.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/m4sugar/m4sh.m4,v
retrieving revision 1.140
diff -u -r1.140 m4sh.m4
--- lib/m4sugar/m4sh.m4 20 May 2005 12:08:19 -0000 1.140
+++ lib/m4sugar/m4sh.m4 24 May 2005 05:52:17 -0000
@@ -521,13 +521,6 @@
[$2])])
-# _AS_ECHO_UNQUOTED(STRING, [FD = AS_MESSAGE_FD])
-# -----------------------------------------------
-# Perform shell expansions on STRING and echo the string to FD.
-m4_define([_AS_ECHO_UNQUOTED],
-[echo "$1" >&m4_default([$2], [AS_MESSAGE_FD])])
-
-
# _AS_QUOTE(STRING, [CHARS = `"])
# -------------------------------
# If there are quoted (via backslash) backquotes do nothing, else
@@ -540,6 +533,13 @@
$1])])
+# _AS_ECHO_UNQUOTED(STRING, [FD = AS_MESSAGE_FD])
+# -----------------------------------------------
+# Perform shell expansions on STRING and echo the string to FD.
+m4_define([_AS_ECHO_UNQUOTED],
+[echo "$1" >&m4_default([$2], [AS_MESSAGE_FD])])
+
+
# _AS_ECHO(STRING, [FD = AS_MESSAGE_FD])
# --------------------------------------
# Protect STRING from backquote expansion, echo the result to FD.
2005-05-24 Stepan Kasal <[EMAIL PROTECTED]>
* lib/m4sugar/m4sugar.m4 (m4_ifset): Use m4_ifval.
Index: lib/m4sugar/m4sugar.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/m4sugar/m4sugar.m4,v
retrieving revision 2.88
diff -u -r2.88 m4sugar.m4
--- lib/m4sugar/m4sugar.m4 17 May 2005 09:49:37 -0000 2.88
+++ lib/m4sugar/m4sugar.m4 24 May 2005 05:58:40 -0000
@@ -322,7 +322,7 @@
# expand IF-FALSE, otherwise IF-TRUE.
m4_define([m4_ifset],
[m4_ifdef([$1],
- [m4_if(m4_defn([$1]), [], [$3], [$2])],
+ [m4_ifval(m4_defn([$1]), [$2], [$3])],
[$3])])
2005-05-24 Stepan Kasal <[EMAIL PROTECTED]>
* lib/autoconf/general.m4 (_AC_INIT_SRCDIR): Merge the two error
messages when ac_unique_file is not found.
Index: lib/autoconf/general.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/general.m4,v
retrieving revision 1.857
diff -u -r1.857 general.m4
--- lib/autoconf/general.m4 20 May 2005 07:58:43 -0000 1.857
+++ lib/autoconf/general.m4 24 May 2005 05:34:36 -0000
@@ -524,11 +524,8 @@
ac_srcdir_defaulted=no
fi
if test ! -r $srcdir/$ac_unique_file; then
- if test "$ac_srcdir_defaulted" = yes; then
- AC_MSG_ERROR([cannot find sources ($ac_unique_file) in $ac_confdir or ..])
- else
- AC_MSG_ERROR([cannot find sources ($ac_unique_file) in $srcdir])
- fi
+ test "$ac_srcdir_defaulted" = yes && srcdir="$ac_confdir or .."
+ AC_MSG_ERROR([cannot find sources ($ac_unique_file) in $srcdir])
fi
(cd $srcdir && test -r ./$ac_unique_file) 2>/dev/null ||
AC_MSG_ERROR([sources are in $srcdir, but `cd $srcdir' does not work])
2005-05-24 Stepan Kasal <[EMAIL PROTECTED]>
* lib/autoconf/general.m4 (AC_CONFIG_MACRO_DIR): Simplify the
`if' at the end.
Index: lib/autoconf/general.m4
===================================================================
RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/general.m4,v
retrieving revision 1.857
diff -u -r1.857 general.m4
--- lib/autoconf/general.m4 20 May 2005 07:58:43 -0000 1.857
+++ lib/autoconf/general.m4 24 May 2005 05:44:09 -0000
@@ -1640,10 +1640,8 @@
[[\\/]]* | ?:[[\\/]]* ) ac_macro_dir=$1 ;;
*) ac_macro_dir=$srcdir/$1 ;;
esac
-if test -d "$ac_macro_dir"; then :
-else
+test -d "$ac_macro_dir" ||
AC_MSG_ERROR([cannot find macro directory `$1'])
-fi
])# AC_CONFIG_MACRO_DIR
2005-05-23 Stepan Kasal <[EMAIL PROTECTED]>
* bin/autoconf.as: Use "shift 2" in option processing.
Index: bin/autoconf.as
===================================================================
RCS file: /cvsroot/autoconf/autoconf/bin/autoconf.as,v
retrieving revision 1.13
diff -u -r1.13 autoconf.as
--- bin/autoconf.as 14 May 2005 07:00:39 -0000 1.13
+++ bin/autoconf.as 23 May 2005 15:53:00 -0000
@@ -120,9 +120,8 @@
shift ;;
--trace | -t )
test $# = 1 && eval "$exit_missing_arg"
- shift
- traces="$traces --trace='"`echo "$1" | sed "s/'/'\\\\\\\\''/g"`"'"
- shift ;;
+ traces="$traces --trace='"`echo "$2" | sed "s/'/'\\\\\\\\''/g"`"'"
+ shift 2 ;;
--initialization | -i )
autom4te_options="$autom4te_options --melt"
shift;;
@@ -132,9 +131,8 @@
shift ;;
--output | -o )
test $# = 1 && eval "$exit_missing_arg"
- shift
- outfile=$1
- shift ;;
+ outfile=$2
+ shift 2 ;;
-- ) # Stop option processing
shift; break ;;
