Setiap record membentuk dataseries baru ya...
xl2007 : klik kanan chart -> pilih select data -> tekan Add -> masukkan 1
cell nilai Y pada Y Values -> masukkan 1 cell nilai X pada X values ->
masukkan cell commant ke series name -> OK
ulangi sampai seluruh record masuk membentuk series data (maksimal, sebuah
chart berisi 255 series dan sudah terpakai 140)
(waaaa..... capek juga kalau ternyata dinamis)
Jika dengan buat chart baru dan blok seluruh kolom x dan y kemudian insert
chart tipe xyscatter jadinya hanya 1 series. Jadi tiap point gak bisa punya
simbol sendiri-sendiri kalau gak di-edit satu per satu. Begitu juga data
labelnya. Capek juga ya.
Kalau gitu pakai opsi pertama saja, walau dibatasi 255 series.
Supaya agak otomatis :
data di b3 (headernya) dan record mulai b4, ada 2 kolom, yaitu xvalues
(kolom B), yvalues (kolom C), seriesname (kolom D)
berikut langkahnya : (mungkin bisa juga untuk xl2003)
1. save as file excel (bukan save, tapi save as) -> pilih save as type yang
ekstensinya .xlsm atau .xlsb atau coba .xls -> tekan save
2. ke VBE (tekan ALT F11)
3. menu Insert -> pilih Module
4. copy script prosedur berikut :
Public Sub BuatChart()
Dim cht As Chart
Dim lSeries As Long
Dim sSeriesRef As String
Dim rngX As Range, rng As Range
With Sheet1
Set rngX = .Range("b3").CurrentRegion.Offset(1).Resize(, 1)
lSeries = rngX.Count - 1
If lSeries < 1 Then
Exit Sub
ElseIf lSeries > 255 Then
lSeries = 255
End If
Set rngX = rngX.Resize(lSeries)
lSeries = 0
sSeriesRef = "='" & .Name & "'!"
.Shapes.AddChart(xlXYScatter).Select
End With
Set cht = ActiveChart
With cht
For Each rng In rngX
.SeriesCollection.NewSeries
lSeries = lSeries + 1
With .SeriesCollection(lSeries)
.XValues = sSeriesRef & rng.Address
.Values = sSeriesRef & rng.Offset(0, 1).Address
.Name = sSeriesRef & rng.Offset(0, 2).Address
.ApplyDataLabels
.DataLabels.ShowSeriesName = True
.DataLabels.ShowValue = False
End With
Next rng
End With
End Sub
5. Kembali ke worksheet dan save (sekarang save ya. bukan save as)
6. jalankan prosedur 'BuatChart' (tekan ALT F8 lalu pilih nama
prosedur 'BuatChart' dilanjutkan tekan tombol Run)
Prosedur diatas adalah untuk buat chart baru.
Kalau mau edit chart, silakan dikembangkan saja.
Wassalam,
Kid.
2012/10/12 ngademin Thohari <[email protected]>
> **
>
>
> Be-exceller,
>
> minta advise nya, contoh ini saya ambil dari milister tapi saya terapkan
> ke data sampai 140, kok ngga tampil ya datanya
>
> terima kasih
>
> Amin
>
>
>
