Source: gnupg-pkcs11-scd
Version: 0.10.0-4
User: [email protected]
Usertags: ftcbfs
Hi Thorsten,
in your -4 upload you introduced a cross build regression.
gpg-error-config used to be fine for cross compilation. When you
switched to pkg-config, you opted for not using PKG_CHECK_MODULES, but
in doing so you ended up hard coding the build architecture one and that
tends to be wrong for cross compiling. I'm attaching a patch that really
goes to PKG_CHECK_MODULES and thus fixes the cross build again. Don't
you appreciate the reduction in boiler plate?
Helmut
--- gnupg-pkcs11-scd-0.10.0.orig/configure.ac
+++ gnupg-pkcs11-scd-0.10.0/configure.ac
@@ -214,44 +214,21 @@
AC_ARG_VAR([LIBGPG_ERROR_CFLAGS], [C compiler flags for libgpg-error])
AC_ARG_VAR([LIBGPG_ERROR_LIBS], [linker flags for libgpg-error])
-if test -z "${LIBGPG_ERROR_LIBS}"; then
- AC_MSG_CHECKING([for libgpg-error])
- if ! test -x "/usr/bin/pkg-config"; then
- AC_MSG_ERROR([Cannot locate libgpg-error])
- else
- AC_MSG_RESULT([found])
- LIBGPG_ERROR_CFLAGS="`/usr/bin/pkg-config --cflags gpg-error`"
- LIBGPG_ERROR_LIBS="`/usr/bin/pkg-config --libs gpg-error`"
- AC_MSG_RESULT([CFLAGS "${LIBGPG_ERROR_CFLAGS}"])
- AC_MSG_RESULT([LIBS "${LIBGPG_ERROR_LIBS}"])
- fi
-fi
+AS_IF([test -z "${LIBGPG_ERROR_LIBS}"],[
+ PKG_CHECK_MODULES([LIBGPG_ERROR],[gpg-error])
+])
AC_ARG_VAR([LIBASSUAN_CFLAGS], [C compiler flags for libassuan])
AC_ARG_VAR([LIBASSUAN_LIBS], [linker flags for libassuan])
-if test -z "${LIBASSUAN_LIBS}"; then
- AC_MSG_CHECKING([for libassuan])
- test -x "/usr/bin/pkg-config" || AC_MSG_ERROR([Cannot locate libassuan])
- /usr/bin/pkg-config --modversion libassuan | grep -E "^2\.|^3\." > /dev/null || AC_MSG_ERROR([Need assuan-2 or assuan-3])
-
- AC_MSG_RESULT([found])
-
- LIBASSUAN_CFLAGS="`/usr/bin/pkg-config --cflags libassuan`"
- LIBASSUAN_LIBS="`/usr/bin/pkg-config --libs libassuan`"
-fi
+AS_IF([test -z "${LIBASSUAN_LIBS}"],[
+ PKG_CHECK_MODULES([LIBASSUAN],[libassuan >= 2.0])
+])
AC_ARG_VAR([LIBGCRYPT_CFLAGS], [C compiler flags for libgcrypt])
AC_ARG_VAR([LIBGCRYPT_LIBS], [linker flags for libgcrypt])
-if test -z "${LIBGCRYPT_LIBS}"; then
- AC_MSG_CHECKING([for libgcrypt])
- if ! test -x "/usr/bin/pkg-config"; then
- AC_MSG_ERROR([Cannot locate libgcrypt])
- else
- AC_MSG_RESULT([found])
- LIBGCRYPT_CFLAGS="`/usr/bin/pkg-config --cflags libgcrypt`"
- LIBGCRYPT_LIBS="`/usr/bin/pkg-config --libs libgcrypt`"
- fi
-fi
+AS_IF([test -z "${LIBGCRYPT_LIBS}"],[
+ PKG_CHECK_MODULES([LIBGCRYPT],[libgcrypt])
+])
PKG_CHECK_MODULES([OPENSSL], [libcrypto >= 0.9.7], [HAVE_OPENSSL="yes"], [HAVE_OPENSSL="no"])
if test "${HAVE_OPENSSL}" = "no"; then
