Colin Paul Adams wrote:
> How can I generate xhtml whilst chunking?
If you are using Saxon, use following customization layer. If you are
using Xalan, change saxon:xhtml to xml. For XT you can make similar
customization. Just grab original template write.chunk from
xtchunker.xsl instead from chunker.xsl. This example was succesfully
tested with Saxon 6.0.2 and stylesheets 1.34. Do not forget to modify
path in <xsl:import> instruction.
<?xml version='1.0' encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:saxon="http://icl.com/saxon"
xmlns:lxslt="http://xml.apache.org/xslt"
xmlns:xalanredirect="org.apache.xalan.xslt.extensions.Redirect"
xmlns:doc="http://nwalsh.com/xsl/documentation/1.0"
version="1.1"
exclude-result-prefixes="doc"
extension-element-prefixes="saxon xalanredirect lxslt">
<xsl:import href="file:///e:/sgml/stylesheets/dbx134/html/chunk.xsl"/>
<xsl:template name="write.chunk">
<xsl:param name="filename" select="''"/>
<xsl:param name="method" select="'saxon:xhtml'"/>
<xsl:param name="encoding" select="'ISO-8859-1'"/>
<xsl:param name="content" select="''"/>
<xsl:variable name="vendor" select="system-property('xsl:vendor')"/>
<xsl:choose>
<xsl:when test="contains($vendor, 'SAXON 6.2')">
<!-- Saxon 6.2.x uses xsl:document -->
<xsl:document version="1.1" href="{$filename}"
method="{$method}"
encoding="{$encoding}">
<xsl:copy-of select="$content"/>
</xsl:document>
</xsl:when>
<xsl:when test="contains($vendor, 'SAXON')">
<!-- Saxon uses saxon:output -->
<saxon:output file="{$filename}"
href="{$filename}"
method="{$method}"
encoding="{$encoding}">
<xsl:copy-of select="$content"/>
</saxon:output>
</xsl:when>
<xsl:when test="contains($vendor, 'Apache')">
<!-- Xalan uses xalanredirect -->
<xalanredirect:write file="{$filename}">
<xsl:copy-of select="$content"/>
</xalanredirect:write>
</xsl:when>
<xsl:otherwise>
<!-- it doesn't matter since we won't be making chunks... -->
<xsl:message terminate="yes">
<xsl:text>Can't make chunks with </xsl:text>
<xsl:value-of select="$vendor"/>
<xsl:text>'s processor.</xsl:text>
</xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
-----------------------------------------------------------------
Jirka Kosek
e-mail: [EMAIL PROTECTED]
http://www.kosek.cz
------------------------------------------------------------------
To unsubscribe from this elist send a message with the single word
"unsubscribe" in the body to: [EMAIL PROTECTED]
