Hello Michael,
I am going over all projects I help to allow libtool-2 migration and cleanups.
Please review.
If you like I can split this into smaller parts.
Please consider moving the documentation (except manpage) to separate project,
it will save
much of the ugly build stuff from this project, allow "make distcheck" work
correctly, and provide
smaller tarball for users to download. A separate tarballs (eg ecryptfs-docs)
may be provided for
this.
Attached is a patch with the following modifications:
1. Ready to libtool-2
Add -shared to modules, so that in future the .la and .a will not be generated.
Current versions of libtool ignore this.
In order to activate libtool-2 support:
Modify configure.ac:
-AC_PROG_LIBTOOL
-#LT_INIT
+#AC_PROG_LIBTOOL
+LT_INIT
Modify Makefile.am:
-#ACLOCAL_AMFLAGS = -I m4
+ACLOCAL_AMFLAGS = -I m4
2. make maintainer-clean clean most of unmonitored files (except of docs).
3. autoupdate modifications
Removes spaces.
AM_CONFIG_HEADER->AC_CONFIG_HEADERS
AC_STDC_HEADERS->AC_HEADER_STDC
4. GNU Source
Replace:
CFLAGS="${CFLAGS} -D_GNU_SOURCE"
with:
AC_GNU_SOURCE
Add to src/daemon/main.c (missing):
#include <sys/wait.h>
Remove __WNOTHREAD from waitpid (unneeded).
5. Distribute ecryptfs.7 in tarball so that pod2man is not required on target.
6. Initial work for separate build directory:
mkdir xxx
cd xxx
../configure
make
Some replacements of top_srcdir and top_builddir
Why initial? As I could not make the design doc work correctly.
7. Remove EXTRA_DIST=*.h from src/include/Makefile.am, replace with explicit
filename.
8. Create pam_ecryptfs directly and not libpam_ecryptfs.
9. Introduce DISTCHECK_HACK variable to disable tests and uninstall-local
targets
so "make distcheck" work.
10. Add some dependency to install-hooks to fix parallel make potential issues.
Regards,
Alon Bar-Lev.
---
diff --git a/Makefile.am b/Makefile.am
index f0cb95c..a9dbfaa 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -9,6 +9,19 @@
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
AUTOMAKE_OPTIONS=foreign dist-bzip2
+#ACLOCAL_AMFLAGS = -I m4
+
+MAINTAINERCLEANFILES = \
+ config.log config.status \
+ $(srcdir)/Makefile.in \
+ $(srcdir)/config.h.in $(srcdir)/config.h.in~ $(srcdir)/configure \
+ $(srcdir)/install-sh $(srcdir)/ltmain.sh $(srcdir)/missing \
+ $(srcdir)/compile $(srcdir)/depcomp $(srcdir)/aclocal.m4 \
+ $(srcdir)/config.guess $(srcdir)/config.sub \
+ $(srcdir)/m4/ltsugar.m4 $(srcdir)/m4/libtool.m4 \
+ $(srcdir)/m4/ltversion.m4 $(srcdir)/m4/lt~obsolete.m4 \
+ $(srcdir)/m4/ltoptions.m4
+
SUBDIRS = doc src
dist_doc_DATA = README
diff --git a/configure.ac b/configure.ac
index d7cb6d9..362e1da 100644
--- a/configure.ac
+++ b/configure.ac
@@ -9,13 +9,14 @@
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
-AC_PREREQ([2.59])
+AC_PREREQ(2.59)
AC_INIT([ecryptfs-utils],[46])
AC_CANONICAL_HOST
AC_CANONICAL_TARGET
AM_INIT_AUTOMAKE([${PACKAGE_NAME}], [${PACKAGE_VERSION}])
AC_CONFIG_SRCDIR([src/libecryptfs])
-AM_CONFIG_HEADER([config.h])
+AC_CONFIG_HEADERS([config.h])
+AC_CONFIG_MACRO_DIR([m4])
LIBECRYPTFS_LT_CURRENT="0"
LIBECRYPTFS_LT_REVISION="0"
@@ -26,56 +27,56 @@ AC_SUBST([LIBECRYPTFS_LT_AGE])
AC_ARG_ENABLE(
[openssl],
- [AC_HELP_STRING([--disable-openssl], [Build OpenSSL key module])],
+ [AS_HELP_STRING([--disable-openssl],[Build OpenSSL key module])],
,
[enable_openssl="detect"]
)
AC_ARG_ENABLE(
[pkcs11-helper],
- [AC_HELP_STRING([--enable-pkcs11-helper], [Build pkcs11-helper key
module])],
+ [AS_HELP_STRING([--enable-pkcs11-helper],[Build pkcs11-helper key
module])],
,
enable_pkcs11_helper="no"
)
AC_ARG_ENABLE(
[tspi],
- [AC_HELP_STRING([--enable-tspi], [Build TrouSerS key module])],
+ [AS_HELP_STRING([--enable-tspi],[Build TrouSerS key module])],
,
[enable_tspi="no"]
)
AC_ARG_ENABLE(
[gpg],
- [AC_HELP_STRING([--enable-gpg], [Build GnuPG key module])],
+ [AS_HELP_STRING([--enable-gpg],[Build GnuPG key module])],
,
[enable_gpg="no"]
)
AC_ARG_ENABLE(
[pam],
- [AC_HELP_STRING([--disable-pam], [Build PAM module])],
+ [AS_HELP_STRING([--disable-pam],[Build PAM module])],
,
[enable_pam="yes"]
)
AC_ARG_ENABLE(
[gui],
- [AC_HELP_STRING([--enable-gui], [Enable building of GUI components])],
+ [AS_HELP_STRING([--enable-gui],[Enable building of GUI components])],
,
[enable_gui="no"]
)
AC_ARG_ENABLE(
[docs],
- [AC_HELP_STRING([--enable-docs], [Enable installing document])],
+ [AS_HELP_STRING([--enable-docs],[Enable installing document])],
,
[enable_docs="no"]
)
AC_ARG_ENABLE(
[docs-gen],
- [AC_HELP_STRING([--enable-docs-gen], [Enable generating documents])],
+ [AS_HELP_STRING([--enable-docs-gen],[Enable generating documents])],
,
[enable_docs_gen="no"]
)
@@ -83,7 +84,7 @@ test "${enable_docs_gen}" = "yes" && enable_docs="yes"
AC_ARG_ENABLE(
[mudflap],
- [AC_HELP_STRING([--enable-mudflap], [Build with -fmudflap gcc option])],
+ [AS_HELP_STRING([--enable-mudflap],[Build with -fmudflap gcc option])],
[
if "${enableval}" = "yes"; then
CFLAGS="$CFLAGS -fmudflap"
@@ -94,14 +95,14 @@ AC_ARG_ENABLE(
AC_ARG_WITH(
[gpgme-prefix],
- [AC_HELP_STRING([--with-gpgme-prefix=PATH], [Specify the directory
where gpgme install, default /usr])],
+ [AS_HELP_STRING([--with-gpgme-prefix=PATH],[Specify the directory where
gpgme install, default /usr])],
,
[with_gpgme_prefix="/usr"]
)
AC_ARG_WITH(
[pamdir],
- [AC_HELP_STRING([--with-pamdir=PATH], [Specify the directory where PAM
modules are stored])],
+ [AS_HELP_STRING([--with-pamdir=PATH],[Specify the directory where PAM
modules are stored])],
[pamdir="${withval}"],
[
if test "${prefix}" = "/usr"; then
@@ -114,7 +115,7 @@ AC_ARG_WITH(
AC_ARG_WITH(
[ecryptfskeymoddir],
- [AC_HELP_STRING([--with-ecryptfskeymoddir=PATH], [Specify the directory
where key modules are stored])],
+ [AS_HELP_STRING([--with-ecryptfskeymoddir=PATH],[Specify the directory
where key modules are stored])],
[
ecryptfskeymoddir="${withval}"
full_ecryptfskeymoddir="${ecryptfskeymoddir}"
@@ -126,9 +127,12 @@ AC_ARG_WITH(
)
AC_DEFINE_UNQUOTED([ECRYPTFS_DEFAULT_KEY_MOD_DIR],
["$full_ecryptfskeymoddir"], "Location of key modules")
+AC_GNU_SOURCE
+
AC_PROG_CC
AC_MINIX
AC_PROG_LIBTOOL
+#LT_INIT
AM_PROG_CC_C_O
PKG_PROG_PKG_CONFIG
AC_PATH_PROGS([POD2MAN], [pod2man])
@@ -148,7 +152,7 @@ if test "${enable_docs_gen}" = "yes"; then
fi
AC_ISC_POSIX
-AC_STDC_HEADERS
+AC_HEADER_STDC
AC_CHECK_LIB([dl], [dlopen])
# Verify gcrypt
@@ -277,7 +281,7 @@ if test "${prefix}" = "/usr"; then
else
rootsbindir="\$(sbindir)"
fi
-CFLAGS="${CFLAGS} -D_GNU_SOURCE"
+
AC_SUBST([pamdir])
AC_SUBST([pamlibdir])
AC_SUBST([pkgconfigdir])
@@ -293,6 +297,7 @@ AM_CONDITIONAL([BUILD_PAM], [test "${enable_pam}" = "yes"])
AM_CONDITIONAL([BUILD_GUI], [test "${enable_gui}" = "yes"])
AM_CONDITIONAL([BUILD_DOCS], [test "${enable_docs}" = "yes"])
AM_CONDITIONAL([BUILD_DOCS_GEN], [test "${enable_docs_gen}" = "yes"])
+AM_CONDITIONAL([ENABLE_TESTS], [test -n "${DISTCHECK_HACK}"])
# workaround for <autoconf-2.60
if test -z "${docdir}"; then
diff --git a/doc/Makefile.am b/doc/Makefile.am
index daa29a6..0bd1426 100644
--- a/doc/Makefile.am
+++ b/doc/Makefile.am
@@ -1,3 +1,5 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+
SUBDIRS = manpage design_doc beginners_guide
dist_doc_DATA =
diff --git a/doc/beginners_guide/Makefile.am b/doc/beginners_guide/Makefile.am
index 707bd84..dfd79e1 100644
--- a/doc/beginners_guide/Makefile.am
+++ b/doc/beginners_guide/Makefile.am
@@ -1,3 +1,4 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
#
# Please note that "make dist" will also distribute
diff --git a/doc/design_doc/Makefile.am b/doc/design_doc/Makefile.am
index 2cfa30a..7f861ec 100644
--- a/doc/design_doc/Makefile.am
+++ b/doc/design_doc/Makefile.am
@@ -1,3 +1,4 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
#
# Please note that "make dist" will also distribute
diff --git a/doc/manpage/Makefile.am b/doc/manpage/Makefile.am
index 97c031e..655b276 100644
--- a/doc/manpage/Makefile.am
+++ b/doc/manpage/Makefile.am
@@ -8,18 +8,17 @@
# WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
-EXTRA_DIST=ecryptfs.pod
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+DISTCLEANFILES = ecryptfs.7
-man_MANS = ecryptfs.7
+dist_noinst_DATA = ecryptfs.pod
dist_man_MANS = \
ecryptfs-manager.8 \
mount.ecryptfs.8 \
- ecryptfsd.8
+ ecryptfsd.8 \
+ ecryptfs.7
-ecryptfs.7: ecryptfs.pod
+ecryptfs.7: $(srcdir)/ecryptfs.pod
$(POD2MAN) \
--center="eCryptfs" --section=7 \
- --release=$(PACKAGE_VERSION) ecryptfs.pod > ecryptfs.7
-
-local-clean:
- -rm -fr ecryptfs.7
+ --release=$(PACKAGE_VERSION) $(srcdir)/ecryptfs.pod > ecryptfs.7
diff --git a/src/Makefile.am b/src/Makefile.am
index f9d46dc..2641f61 100644
--- a/src/Makefile.am
+++ b/src/Makefile.am
@@ -8,4 +8,6 @@
# WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+
SUBDIRS = key_mod libecryptfs utils daemon include pam_ecryptfs
diff --git a/src/daemon/Makefile.am b/src/daemon/Makefile.am
index 23e309f..92dd426 100644
--- a/src/daemon/Makefile.am
+++ b/src/daemon/Makefile.am
@@ -1,5 +1,7 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+
bin_PROGRAMS=ecryptfsd
ecryptfsd_SOURCES = main.c
ecryptfsd_CFLAGS = $(AM_CFLAGS) $(LIBGCRYPT_CFLAGS) $(KEYUTILS_CFLAGS)
-ecryptfsd_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
$(KEYUTILS_LIBS) $(LIBGCRYPT_LIBS)
+ecryptfsd_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
$(KEYUTILS_LIBS) $(LIBGCRYPT_LIBS)
diff --git a/src/daemon/main.c b/src/daemon/main.c
index cceb487..307db5a 100644
--- a/src/daemon/main.c
+++ b/src/daemon/main.c
@@ -30,6 +30,7 @@
#include <fcntl.h>
#include <getopt.h>
#include <pthread.h>
+#include <sys/wait.h>
#include <sys/resource.h>
#include "config.h"
#include "../include/ecryptfs.h"
@@ -96,7 +97,7 @@ prompt_callback(char *prompt_type, char *prompt, char *input,
int input_size) {
fds[1] = -1;
while (
- (r=waitpid (pid, &status, __WNOTHREAD)) == 0 ||
+ (r=waitpid (pid, &status, 0)) == 0 ||
(r == -1 && errno == EINTR)
);
diff --git a/src/include/Makefile.am b/src/include/Makefile.am
index 0917369..8d56e46 100644
--- a/src/include/Makefile.am
+++ b/src/include/Makefile.am
@@ -1,3 +1,4 @@
-EXTRA_DIST=*.h
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
include_HEADERS = ecryptfs.h
+dist_noinst_HEADERS = decision_graph.h
diff --git a/src/key_mod/Makefile.am b/src/key_mod/Makefile.am
index c282d38..1af0812 100644
--- a/src/key_mod/Makefile.am
+++ b/src/key_mod/Makefile.am
@@ -1,3 +1,5 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+
ecryptfskeymod_LTLIBRARIES=libecryptfs_key_mod_passphrase.la
if BUILD_OPENSSL
@@ -16,30 +18,35 @@ endif
libecryptfs_key_mod_openssl_la_SOURCES = ecryptfs_key_mod_openssl.c
libecryptfs_key_mod_openssl_la_CFLAGS = $(AM_CFLAGS) $(OPENSSL_CFLAGS)
libecryptfs_key_mod_openssl_la_LIBADD = $(OPENSSL_LIBS)
-libecryptfs_key_mod_openssl_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version
+libecryptfs_key_mod_openssl_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version
-shared
libecryptfs_key_mod_pkcs11_helper_la_SOURCES = ecryptfs_key_mod_pkcs11_helper.c
libecryptfs_key_mod_pkcs11_helper_la_CFLAGS = $(AM_CFLAGS)
$(PKCS11_HELPER_CFLAGS) $(OPENSSL_CFLAGS)
libecryptfs_key_mod_pkcs11_helper_la_LIBADD = $(PKCS11_HELPER_LIBS)
$(OPENSSL_LIBS)
-libecryptfs_key_mod_pkcs11_helper_la_LDFLAGS = $(AM_LDFLAGS) -module
-avoid-version
+libecryptfs_key_mod_pkcs11_helper_la_LDFLAGS = $(AM_LDFLAGS) -module
-avoid-version -shared
libecryptfs_key_mod_tspi_la_SOURCES = ecryptfs_key_mod_tspi.c
libecryptfs_key_mod_tspi_la_CFLAGS = $(AM_CFLAGS) $(TSPI_CFLAGS)
libecryptfs_key_mod_tspi_la_LIBADD = $(TSPI_LIBS)
-libecryptfs_key_mod_tspi_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version
+libecryptfs_key_mod_tspi_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version
-shared
libecryptfs_key_mod_gpg_la_SOURCES = ecryptfs_key_mod_gpg.c
libecryptfs_key_mod_gpg_la_CFLAGS = $(AM_CFLAGS) $(GPGME_CFLAGS)
libecryptfs_key_mod_gpg_la_LIBADD = $(GPGME_LIBS)
-libecryptfs_key_mod_gpg_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version
+libecryptfs_key_mod_gpg_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version
-shared
libecryptfs_key_mod_passphrase_la_SOURCES = ecryptfs_key_mod_passphrase.c
libecryptfs_key_mod_passphrase_la_CFLAGS = $(AM_CFLAGS) $(LIBGCRYPT_CFLAGS)
libecryptfs_key_mod_passphrase_la_LIBADD = $(LIBGCRYPT_LIBS)
-libecryptfs_key_mod_passphrase_la_LDFLAGS = $(AM_LDFLAGS) -module
-avoid-version
+libecryptfs_key_mod_passphrase_la_LDFLAGS = $(AM_LDFLAGS) -module
-avoid-version -shared
-install-data-hook:
+# Needed until libtool-2
+install-data-hook: install-ecryptfskeymodLTLIBRARIES
for f in `echo "$(ecryptfskeymod_LTLIBRARIES)" | $(SED) 's/\.la//g'`;
do \
rm -f "$(DESTDIR)$(ecryptfskeymoddir)/$$f.la"; \
rm -f "$(DESTDIR)$(ecryptfskeymoddir)/$$f.a"; \
done
+uninstall-local:
+ for f in `echo "$(ecryptfskeymod_LTLIBRARIES)" | $(SED) 's/\.la//g'`;
do \
+ rm -f "$(DESTDIR)$(ecryptfskeymoddir)/$$f.so"; \
+ done
diff --git a/src/libecryptfs/Makefile.am b/src/libecryptfs/Makefile.am
index 9b4f79c..f5cd48d 100644
--- a/src/libecryptfs/Makefile.am
+++ b/src/libecryptfs/Makefile.am
@@ -1,5 +1,7 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+
lib_LTLIBRARIES = libecryptfs.la
-pkgconfig_DATA=libecryptfs.pc
+pkgconfig_DATA = libecryptfs.pc
libecryptfs_la_SOURCES = \
main.c \
diff --git a/src/pam_ecryptfs/Makefile.am b/src/pam_ecryptfs/Makefile.am
index 4cb37a6..98eee62 100644
--- a/src/pam_ecryptfs/Makefile.am
+++ b/src/pam_ecryptfs/Makefile.am
@@ -1,13 +1,17 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+
if BUILD_PAM
-pam_LTLIBRARIES = libpam_ecryptfs.la
+pam_LTLIBRARIES = pam_ecryptfs.la
-install-data-hook:
- rm -f "$(DESTDIR)$(pamdir)/libpam_ecryptfs.la"
- rm -f "$(DESTDIR)$(pamdir)/libpam_ecryptfs.a"
- mv -f "$(DESTDIR)$(pamdir)/libpam_ecryptfs.so"
"$(DESTDIR)$(pamdir)/pam_ecryptfs.so"
+# Needed until libtool-2
+install-data-hook: install-pamLTLIBRARIES
+ rm -f "$(DESTDIR)$(pamdir)/pam_ecryptfs.la"
+ rm -f "$(DESTDIR)$(pamdir)/pam_ecryptfs.a"
+uninstall-local:
+ rm -f "$(DESTDIR)$(pamdir)/pam_ecryptfs.so"
endif
-libpam_ecryptfs_la_SOURCES = pam_ecryptfs.c
-libpam_ecryptfs_la_CFLAGS = $(AM_CFLAGS) $(LIBGCRYPT_CFLAGS)
-libpam_ecryptfs_la_LIBADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
$(PAM_LIBS) $(LIBGCRYPT_LIBS)
-libpam_ecryptfs_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version
+pam_ecryptfs_la_SOURCES = pam_ecryptfs.c
+pam_ecryptfs_la_CFLAGS = $(AM_CFLAGS) $(LIBGCRYPT_CFLAGS)
+pam_ecryptfs_la_LIBADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
$(PAM_LIBS) $(LIBGCRYPT_LIBS)
+pam_ecryptfs_la_LDFLAGS = $(AM_LDFLAGS) -module -avoid-version -shared
diff --git a/src/utils/Makefile.am b/src/utils/Makefile.am
index cdffa53..d36c99a 100644
--- a/src/utils/Makefile.am
+++ b/src/utils/Makefile.am
@@ -1,4 +1,7 @@
+MAINTAINERCLEANFILES = $(srcdir)/Makefile.in
+
EXTRA_DIST=ecryptfsrc ecryptfs-setup-confidential ecryptfs-mount-confidential
ecryptfs-umount-confidential
+
rootsbin_PROGRAMS=mount.ecryptfs
bin_PROGRAMS=ecryptfs-manager ecryptfs-wrap-passphrase \
ecryptfs-unwrap-passphrase \
@@ -10,7 +13,10 @@ bin_SCRIPTS = ecryptfs-setup-confidential \
ecryptfs-mount-confidential \
ecryptfs-umount-confidential
noinst_PROGRAMS=test
+
+if ENABLE_TESTS
TESTS=test
+endif
if BUILD_TSPI
bin_PROGRAMS+=ecryptfs-generate-tpm-key
@@ -20,28 +26,28 @@ INCLUDES = -I$(top_srcdir)/src/include
mount_ecryptfs_SOURCES = mount.ecryptfs.c io.c io.h gen_key.c
plaintext_decision_graph.c
mount_ecryptfs_CFLAGS = $(AM_CFLAGS) $(KEYUTILS_CFLAGS) $(LIBGCRYPT_CFLAGS)
-mount_ecryptfs_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
$(KEYUTILS_LIBS) $(LIBGCRYPT_LIBS)
+mount_ecryptfs_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
$(KEYUTILS_LIBS) $(LIBGCRYPT_LIBS)
ecryptfs_manager_SOURCES = manager.c io.c io.h gen_key.c
ecryptfs_manager_CFLAGS = $(AM_CFLAGS) $(KEYUTILS_CFLAGS) $(LIBGCRYPT_CFLAGS)
-ecryptfs_manager_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
$(KEYUTILS_LIBS) $(LIBGCRYPT_LIBS)
+ecryptfs_manager_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
$(KEYUTILS_LIBS) $(LIBGCRYPT_LIBS)
ecryptfs_wrap_passphrase_SOURCES = ecryptfs_wrap_passphrase.c
-ecryptfs_wrap_passphrase_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
+ecryptfs_wrap_passphrase_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
ecryptfs_unwrap_passphrase_SOURCES = ecryptfs_unwrap_passphrase.c
-ecryptfs_unwrap_passphrase_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
+ecryptfs_unwrap_passphrase_LDADD =
$(top_builddir)/src/libecryptfs/libecryptfs.la
ecryptfs_insert_wrapped_passphrase_into_keyring_SOURCES =
ecryptfs_insert_wrapped_passphrase_into_keyring.c
-ecryptfs_insert_wrapped_passphrase_into_keyring_LDADD =
$(top_srcdir)/src/libecryptfs/libecryptfs.la
+ecryptfs_insert_wrapped_passphrase_into_keyring_LDADD =
$(top_builddir)/src/libecryptfs/libecryptfs.la
ecryptfs_rewrap_passphrase_SOURCES = ecryptfs_rewrap_passphrase.c
-ecryptfs_rewrap_passphrase_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
+ecryptfs_rewrap_passphrase_LDADD =
$(top_builddir)/src/libecryptfs/libecryptfs.la
ecryptfs_add_passphrase_SOURCES = ecryptfs_add_passphrase.c
-ecryptfs_add_passphrase_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
+ecryptfs_add_passphrase_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
ecryptfs_zombie_kill_SOURCES = ecryptfs_zombie_kill.c
-ecryptfs_zombie_kill_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
+ecryptfs_zombie_kill_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
ecryptfs_zombie_list_SOURCES = ecryptfs_zombie_list.c
-ecryptfs_zombie_list_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
+ecryptfs_zombie_list_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
ecryptfs_generate_tpm_key_SOURCES = ecryptfs_generate_tpm_key.c
ecryptfs_generate_tpm_key_CFLAGS = $(AM_CFLAGS) $(TSPI_CFLAGS)
ecryptfs_generate_tpm_key_LDADD = $(TSPI_LIBS)
test_SOURCES = test.c io.c
-test_LDADD = $(top_srcdir)/src/libecryptfs/libecryptfs.la
+test_LDADD = $(top_builddir)/src/libecryptfs/libecryptfs.la
-------------------------------------------------------------------------
Check out the new SourceForge.net Marketplace.
It's the best place to buy or sell services for
just about anything Open Source.
http://sourceforge.net/services/buy/index.php
_______________________________________________
eCryptfs-devel mailing list
eCryptfs-devel@lists.sourceforge.net
https://lists.sourceforge.net/lists/listinfo/ecryptfs-devel
