[flexcoders] Re: Application.application.parameters.

[valdhor]

I use a custom QueryString class for this...

package
{
     import flash.external.*;
     import flash.utils.*;

     public class QueryString
     {
         private var _queryString:String;
         private var _all:String;
         private var _params:Object;

         public function get queryString():String
         {
             return _queryString;
         }
         public function get url():String
         {
             return _all;
         }
         public function get parameters():Object
         {
             return _params;
         }

         public function QueryString()
         {
             readQueryString();
         }

         private function readQueryString():void
         {
             _params = {};
             try
             {
                 _all = 
ExternalInterface.call("window.location.href.toString");
                 _queryString =
ExternalInterface.call("window.location.search.substring", 1);
                 if(_queryString)
                 {
                     var params:Array = _queryString.split('&');
                     var length:uint = params.length;

                     for (var i:uint=0,index:int=-1; i<length; i++)
                     {
                         var kvPair:String = params[i];
                         if((index = kvPair.indexOf("=")) > 0)
                         {
                             var key:String = kvPair.substring(0,index);
                             var value:String =
kvPair.substring(index+1);
                             _params[key] = value;
                         }
                     }
                 }
             }catch(e:Error) { trace("Some error occured.
ExternalInterface doesn't work in Standalone player."); }
         }
     }
}

And to use it...

import QueryString;
private var queryString:QueryString = new QueryString();
user = queryString.parameters.user_id;


HTH



Steve



--- In flexcoders@yahoogroups.com, "Tracy Spratt" <tspr...@...> wrote:
>
> The html wrapper does not automatically pass parameters into the swf.
>
>
>
> You need some java script like this to get the  parameters into an
array:
>
> var _sPassedUrlParms = new String(document.location).split('?')[1]; 
//Get
> any passed-in querystring parms
>
>
>
> then pass that into the SF in the AC_FL_RunContent() function:
>
> "flashvars", _sPassedUrlParms,
>
>
>
>
>
> Tracy Spratt,
>
> Lariat Services, development services available
>
>   _____
>
> From: flexcoders@yahoogroups.com [mailto:flexcod...@yahoogroups.com]
On
> Behalf Of Vikram Singh
> Sent: Wednesday, April 01, 2009 1:13 AM
> To: Flex Coders
> Subject: [flexcoders] Application.application.parameters.
>
>
>
> Hello Everybody.
>
> I am facing problem in getting value using
> "Application.application.parameters."
>
> I will run my application with "http://www.XYZ.
> <http://www.XYZ.com/home.html?user_id=10> com/home.html?user_id=10
>
>
>
> in Flex at initialize() function i wrote like this
>
> user = Application.application.parameters.user_id
>
>
>
> but i don't get value 10 in user variable which is declare like
>
> [Bindable] private var user : uint;
>
>
>
>
>
> is there any package to include for this?
>
>
>
> -Vikram.
>
>
>
>
>
>   _____
>
>
> Add more friends to your messenger and enjoy! Invite
>
<http://in.rd.yahoo.com/tagline_messenger_6/*http:/messenger.yahoo.com/i\
nvit
> e/>  them now.
>