Re: [flexcoders] Re: How to make FormItem labels left aligned?

[EECOLOR]

If you would use the following class it is ;)


Greetz Erik


package fly.flex.containers
{
import mx.containers.FormItem;
import mx.core.EdgeMetrics;
import mx.core.UIComponent;
import mx.core.mx_internal;
import mx.styles.CSSStyleDeclaration;
import mx.styles.StyleManager;

[Style(name="labelAlign",type="String",enumeration="left,right",inherit="no")]

public class ExtendedFormItem extends FormItem
{
 private static var _CLASS_CONTRUCTED_BOOL:Boolean = _CLASS_CONTRUCT();

 private static function _CLASS_CONTRUCT():Boolean
 {
  if (!StyleManager.getStyleDeclaration("ExtendedFormItem"))
  {
   var newStyleDeclaration:CSSStyleDeclaration = new CSSStyleDeclaration();
   newStyleDeclaration.setStyle("labelAlign", "left");
   StyleManager.setStyleDeclaration("ExtendedFormItem",
newStyleDeclaration, true);

  };
  return true;
 };

 override protected function updateDisplayList(unscaledWidth:Number,
unscaledHeight:Number):void
 {
  super.updateDisplayList(unscaledWidth, unscaledHeight);

  var labelAlign_str:String = getStyle("labelAlign");

  if (labelAlign_str == "left")
  {
   var vm:EdgeMetrics = viewMetricsAndPadding;
   var labelObject:UIComponent = mx_internal::labelObject as UIComponent;
   labelObject.move(vm.left, labelObject.y);
  };

 };
};
};