tomwij 14/03/10 00:31:51
Added: mate-screensaver-1.6.1.ebuild metadata.xml
ChangeLog
Log:
New ebuild for mate-extra/mate-screensaver, replaces xscreensaver,
integrating with the MATE desktop; imported from the mate-overlay, reviewed and
adjusted.
(Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key
6D34E57D)
Revision Changes Path
1.1 mate-extra/mate-screensaver/mate-screensaver-1.6.1.ebuild
file :
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/mate-screensaver/mate-screensaver-1.6.1.ebuild?rev=1.1&view=markup
plain:
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/mate-screensaver/mate-screensaver-1.6.1.ebuild?rev=1.1&content-type=text/plain
Index: mate-screensaver-1.6.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:
/var/cvsroot/gentoo-x86/mate-extra/mate-screensaver/mate-screensaver-1.6.1.ebuild,v
1.1 2014/03/10 00:31:51 tomwij Exp $
EAPI="5"
GCONF_DEBUG="yes"
inherit gnome2 multilib versionator
MATE_BRANCH="$(get_version_component_range 1-2)"
SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz";
DESCRIPTION="Replaces xscreensaver, integrating with the MATE desktop."
HOMEPAGE="http://mate-desktop.org";
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="X consolekit kernel_linux libnotify opengl pam systemd"
RDEPEND="
>=dev-libs/dbus-glib-0.71:0
>=dev-libs/glib-2.15:2
>=mate-base/libmatekbd-1.6:0
>=mate-base/mate-desktop-1.6:0
>=mate-base/mate-menus-1.6:0
>=sys-apps/dbus-0.30:0
>=x11-libs/gdk-pixbuf-2.14:2
>=x11-libs/gtk+-2.11.5:2
>=x11-libs/libX11-1:0
x11-libs/cairo:0
x11-libs/libXext:0
x11-libs/libXrandr:0
x11-libs/libXScrnSaver:0
x11-libs/libXxf86misc:0
x11-libs/libXxf86vm:0
x11-libs/libxklavier:0
x11-libs/pango:0
virtual/libintl:0
libnotify? ( >=x11-libs/libnotify-0.7:0 )
opengl? ( virtual/opengl:0 )
pam? ( virtual/pam:0 )
!pam? ( kernel_linux? ( sys-apps/shadow:0 ) )
!!<gnome-extra/gnome-screensaver-3:0"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.35:0
>=mate-base/mate-common-1.6:0
sys-devel/gettext:0
x11-proto/randrproto:0
x11-proto/scrnsaverproto:0
x11-proto/xextproto:0
x11-proto/xf86miscproto:0
virtual/libc:0
virtual/pkgconfig:0
consolekit? ( sys-auth/consolekit:0 )
systemd? ( sys-apps/systemd:0= )"
src_prepare() {
# Fix QA warnings due to missing includes in popsquares.
epatch "${FILESDIR}"/${PN}-1.2.0-fix-popsquares-includes.patch
# Fix libgl typo in configure.ac.
epatch "${FILESDIR}"/${PN}-1.2.0-fix-with-libgl.patch
# Fix intltoolize broken file, see upstream #577133.
sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in || die
# Fix forgotten gnome->mate rename.
sed -i 's:org.gnome:org.mate:' po/POTFILES.in || die
# Make tests work.
sed -i '6 a\data/lock-dialog-default.ui' po/POTFILES.in || die
# We use gnome-keyring now, update pam file.
sed -e 's:mate_keyring:gnome_keyring:g' -i data/mate-screensaver || die
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
$(use_with consolekit console-kit) \
$(use_enable debug) \
$(use_with libnotify) \
$(use_with opengl libgl) \
$(use_enable pam) \
$(use_with systemd) \
$(use_with X x) \
--enable-locking \
--with-kbd-layout-indicator \
--with-xf86gamma-ext \
--with-xscreensaverdir=/usr/share/xscreensaver/config \
--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
}
DOCS="AUTHORS ChangeLog NEWS README"
src_install() {
gnome2_src_install
# Install the conversion script in the documentation.
dodoc "${S}"/data/migrate-xscreensaver-config.sh
dodoc "${S}"/data/xscreensaver-config.xsl
dodoc "${FILESDIR}"/xss-conversion.txt
# Non PAM users will need this suid to read the password hashes.
# OpenPAM users will probably need this too when
# http://bugzilla.gnome.org/show_bug.cgi?id=370847
# is fixed.
if ! use pam ; then
fperms u+s /usr/libexec/mate-screensaver-dialog
fi
}
pkg_postinst() {
gnome2_pkg_postinst
if has_version "<x11-base/xorg-server-1.5.3-r4" ; then
ewarn "You have a too old xorg-server installation. This will
cause"
ewarn "mate-screensaver to eat up your CPU. Please consider
upgrading."
echo
fi
if has_version "<x11-misc/xscreensaver-4.22-r2" ; then
ewarn "You have xscreensaver installed, you probably want to
disable it."
ewarn "To prevent a duplicate screensaver entry in the menu,
you need to"
ewarn "build xscreensaver with -gnome in the USE flags."
ewarn "echo \"x11-misc/xscreensaver -gnome\" >>
/etc/portage/package.use"
echo
fi
elog "Information for converting screensavers is located in "
elog "/usr/share/doc/${PF}/xss-conversion.txt.${PORTAGE_COMPRESS}"
}
1.1 mate-extra/mate-screensaver/metadata.xml
file :
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/mate-screensaver/metadata.xml?rev=1.1&view=markup
plain:
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/mate-screensaver/metadata.xml?rev=1.1&content-type=text/plain
Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd";>
<pkgmetadata>
<maintainer>
<email>[email protected]</email>
<name>Tom Wijsman</name>
</maintainer>
<use>
<flag name="consolekit">Enable support for
<pkg>sys-auth/consolkekit</pkg></flag>
</use>
</pkgmetadata>
1.1 mate-extra/mate-screensaver/ChangeLog
file :
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/mate-screensaver/ChangeLog?rev=1.1&view=markup
plain:
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-extra/mate-screensaver/ChangeLog?rev=1.1&content-type=text/plain
Index: ChangeLog
===================================================================
# ChangeLog for mate-extra/mate-screensaver
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/mate-extra/mate-screensaver/ChangeLog,v 1.1
2014/03/10 00:31:51 tomwij Exp $
*mate-screensaver-1.6.1 (10 Mar 2014)
10 Mar 2014; Tom Wijsman <[email protected]>
+files/mate-screensaver-1.2.0-fix-popsquares-includes.patch,
+files/mate-screensaver-1.2.0-fix-with-libgl.patch, +files/xss-conversion.txt,
+mate-screensaver-1.6.1.ebuild, +metadata.xml:
New ebuild for mate-extra/mate-screensaver, replaces xscreensaver, integrating
with the MATE desktop; imported from the mate-overlay, reviewed and adjusted.
