commit: 244624aaf54a6fa919266b600cf9480f44193687
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 10 20:06:16 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jan 10 20:43:53 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=244624aa
dev-python/inline-snapshot: Bump to 0.19.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/inline-snapshot/Manifest | 1 +
.../inline-snapshot/inline-snapshot-0.19.0.ebuild | 63 ++++++++++++++++++++++
2 files changed, 64 insertions(+)
diff --git a/dev-python/inline-snapshot/Manifest
b/dev-python/inline-snapshot/Manifest
index c468fce166de..87c7ab22cffe 100644
--- a/dev-python/inline-snapshot/Manifest
+++ b/dev-python/inline-snapshot/Manifest
@@ -1 +1,2 @@
DIST inline_snapshot-0.18.2.tar.gz 225777 BLAKE2B
45a08224c8ec94e052c6fe1393ad9b12c7227b9208ef591f323b15baf1622866fcfc7c91167fa8d352dae895e140348df4b3e492c52e441c2b8799e7f53f7ca5
SHA512
6b370ee0a717834f361b712ee71434362a44e92688df298572a801bbf384d69bd37816b2aa1e701f77d72149fff2ec5da9fceb24980af15de807973451e161c9
+DIST inline_snapshot-0.19.0.tar.gz 87554 BLAKE2B
9cb8d15b1d33844053b0ed5df8a4d47ea290bf3c67872671e147fb284e1fb2013bffda21fb38e96c01336b768a1315b81ba8a71d9df8a716ee4ffd92658160a8
SHA512
bb528a6657196938994e678042e379159d28635cc7679ab21a42e550efb35e1edc58fd58ec0b25560866062c6956b8d73f475a682c43255ff18ce31ed55cf9fd
diff --git a/dev-python/inline-snapshot/inline-snapshot-0.19.0.ebuild
b/dev-python/inline-snapshot/inline-snapshot-0.19.0.ebuild
new file mode 100644
index 000000000000..fd8a5cc819a8
--- /dev/null
+++ b/dev-python/inline-snapshot/inline-snapshot-0.19.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Create and update inline snapshots in your Python tests"
+HOMEPAGE="
+ https://15r10nk.github.io/inline-snapshot/
+ https://github.com/15r10nk/inline-snapshot/
+ https://pypi.org/project/inline-snapshot/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/asttokens-2.0.5[${PYTHON_USEDEP}]
+ >=dev-python/executing-2.1.0[${PYTHON_USEDEP}]
+ >=dev-python/rich-13.7.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-2.0.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ dev-python/attrs[${PYTHON_USEDEP}]
+ >=dev-python/black-23.3.0[${PYTHON_USEDEP}]
+ >=dev-python/click-8.1.4[${PYTHON_USEDEP}]
+ >=dev-python/dirty-equals-0.7.0[${PYTHON_USEDEP}]
+ >=dev-python/hypothesis-6.75.5[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/mypy[${PYTHON_USEDEP}]
+ ' 'python*')
+ >=dev-python/pydantic-2[${PYTHON_USEDEP}]
+ >=dev-python/pytest-freezer-0.4.8[${PYTHON_USEDEP}]
+ >=dev-python/pytest-mock-3.14.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-subtests-0.11.0[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # requires pyright
+ 'tests/test_typing.py::test_typing[pyright]'
+ # TODO
+ tests/test_formating.py::test_format_command_fail
+ )
+
+ local -x COLUMNS=80
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x
PYTEST_PLUGINS=inline_snapshot.pytest_plugin,pytest_freezer,pytest_subtests.plugin,xdist.plugin
+ local -x PYTHONPATH=${S}/src
+ epytest -p pytest_mock
+}
