[gentoo-commits] repo/gentoo:master commit in: dev-libs/FP16/

[Alfredo Tupone]

commit:     571099294b5332c06e6123ce9f09dc4d169e141a
Author:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 18 20:31:39 2025 +0000
Commit:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Sat Jan 18 20:32:55 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=57109929

dev-libs/FP16: add 2024.05.27

Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>

 dev-libs/FP16/FP16-2024.05.27.ebuild | 58 ++++++++++++++++++++++++++++++++++++
 dev-libs/FP16/Manifest               |  1 +
 2 files changed, 59 insertions(+)

diff --git a/dev-libs/FP16/FP16-2024.05.27.ebuild 
b/dev-libs/FP16/FP16-2024.05.27.ebuild
new file mode 100644
index 000000000000..083edbf6e0d1
--- /dev/null
+++ b/dev-libs/FP16/FP16-2024.05.27.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+inherit python-r1 cmake
+
+CommitId=95163a75c51bc8dc29f72d0d7419ec50132984ff
+
+DESCRIPTION="conversion to/from half-precision floating point formats"
+HOMEPAGE="https://github.com/Maratyszcza/FP16/";
+SRC_URI="https://github.com/Maratyszcza/${PN}/archive/${CommitId}.tar.gz
+       -> ${P}.tar.gz"
+
+S="${WORKDIR}"/${PN}-${CommitId}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="dev-libs/psimd"
+RDEPEND="
+       ${DEPEND}
+       ${PYTHON_DEPS}
+       dev-python/peachpy[${PYTHON_USEDEP}]
+"
+BDEPEND="test? ( dev-cpp/gtest )"
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-2021.03.20-gentoo.patch
+)
+
+src_prepare() {
+       cmake_src_prepare
+       mkdir -p module/fp16 || die
+       cp include/fp16/*py module/fp16 || die
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DFP16_BUILD_BENCHMARKS=OFF
+               -DFP16_BUILD_TESTS=$(usex test ON OFF)
+       )
+       cmake_src_configure
+}
+
+python_install() {
+       python_domodule module/fp16
+}
+
+src_install() {
+       cmake_src_install
+       rm "${ED}"/usr/include/fp16/*.py || die
+       python_foreach_impl python_install
+}

diff --git a/dev-libs/FP16/Manifest b/dev-libs/FP16/Manifest
index 4d5e56966264..3fd0b65e93a5 100644
--- a/dev-libs/FP16/Manifest
+++ b/dev-libs/FP16/Manifest
@@ -1,2 +1,3 @@
 DIST FP16-2021.03.20.tar.gz 71228 BLAKE2B 
e598225032324ffe38db9002e8397e67a713b6323ac57408e7e39e146826b2bb1dab60cd75181a25b1b07958463e3913bbf0e53b23803e53d472fda66b8ba6d5
 SHA512 
3f094f242425ea37de274eb8539dc5f8ab0c13fd5325d14180ef12e9c04e6002a110d086c4c667f7c8054af337deab096d59482eb95cc8a632c3c412b48e89d1
+DIST FP16-2024.05.27.tar.gz 71220 BLAKE2B 
5b101aad7a8339fff400bba1db896c82498832075f3eb00cc6eaf27608ee0988f918956b5a768262b74552a52436200d4acd17f04f4a05060a32512afb26a9ac
 SHA512 
b88fd0a91e6b6873ce5d0e2cd2afd2b8dceb8b17c366240abb8a5e2fe152faea3ba577ef420038c595cab0b61581a70b84c019c825a8dd262b1bee4686843b66
 DIST FP16-2024.06.20.tar.gz 64704 BLAKE2B 
cd086ca7419aa004c0c4c840227e61612348efb98bdddbf68ef92959267f5f4b0aef55751c5b8a6f50a1f0e7f386e4df5fac273c3849961168e0a5c03faf81e2
 SHA512 
d3ae46b5b0c944f1d8dcfbb90689266f4abaff3e0b5ef338d5d79193367f06d1bfbb9ad85a5a7685a894daeee6dc73fc5d73631718be1379cc6918655a0289aa