commit: e91969d7a5da461dc632dd6ddbfaf987c86c34fb
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 20 05:17:42 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan 20 05:34:14 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e91969d7
dev-python/pyopengl: Bump to 3.1.9
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pyopengl/Manifest | 1 +
dev-python/pyopengl/pyopengl-3.1.9.ebuild | 82 +++++++++++++++++++++++++++++++
2 files changed, 83 insertions(+)
diff --git a/dev-python/pyopengl/Manifest b/dev-python/pyopengl/Manifest
index a5d4d4e20cc4..969c95c481ad 100644
--- a/dev-python/pyopengl/Manifest
+++ b/dev-python/pyopengl/Manifest
@@ -1,2 +1,3 @@
DIST PyOpenGL-3.1.7.tar.gz 1896446 BLAKE2B
3fd4c84bb59157b4a6ee09c2a5ecd0e4f548bf03a84d735acfd92453eafb92102677a2b9c98831a92be33e873630c815dee453745d630a4d6b044771a13c945c
SHA512
add1b4d02e7297f00f82a9c9249d6665029073fe620a1650491af9102a76a16e9320b5f227275b0c273ff5a616c284fd9f25f0f425848676c37cab9f3c22ae2e
DIST pyopengl-3.1.8.gh.tar.gz 3599436 BLAKE2B
7f33345d68d66d3cc81278eaa5f54298694f41f40583ee08a1f9f677705fb4414b6b2afbcd7b9345199b5f573478bfeba050e185b6534cbb19b45cb25c241b47
SHA512
d95014a36bd889fa014043e4640ba7f319bb996cb56e5f7086ee05d39c53d3928512d52b0ce181d7c144775a4da7eff7403cada0f91f23f56a699a1b023e00e6
+DIST pyopengl-3.1.9.tar.gz 1913642 BLAKE2B
2c2b768773b0531b432fb9add49d3c32dd468a4d8dfe0ee992064089ba3a51ecb19a7ce21c6c964935ff51fe1e37c49092540eff88f0a23c6cc754d457bbcef0
SHA512
b0fae0031cf0c47899d3cef6a334ee885595b4bc7d3da5055cd12240e6612b2ade1dc75afe1b1f6fe8e4572b994b88c4ec557d893e6606353f4700111cb6f161
diff --git a/dev-python/pyopengl/pyopengl-3.1.9.ebuild
b/dev-python/pyopengl/pyopengl-3.1.9.ebuild
new file mode 100644
index 000000000000..ece7d7b175c3
--- /dev/null
+++ b/dev-python/pyopengl/pyopengl-3.1.9.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=PyOpenGL
+PYTHON_REQ_USE="tk?"
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Python OpenGL bindings"
+HOMEPAGE="
+ https://pyopengl.sourceforge.net/
+ https://github.com/mcfletch/pyopengl/
+ https://pypi.org/project/PyOpenGL/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux
~x86-linux"
+IUSE="tk"
+
+RDEPEND="
+ media-libs/freeglut
+ virtual/opengl
+ x11-libs/libXi
+ x11-libs/libXmu
+ tk? ( dev-tcltk/togl )
+"
+DEPEND="
+ ${RDEPEND}
+"
+
+# The tests need an X server with the GLX extension. Software rendering
+# under Xvfb works but only with llvmpipe, not softpipe or swr.
+BDEPEND="
+ test? (
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pygame[${PYTHON_USEDEP},opengl,X]
+ dev-python/python-xlib[${PYTHON_USEDEP}]
+ !prefix? (
+ media-libs/mesa[llvm]
+ x11-base/xorg-server[-minimal,xorg]
+ )
+ )
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+ # https://github.com/mcfletch/pyopengl/pull/109
+ "${FILESDIR}/${PN}-3.1.7-pypy3.patch"
+)
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # fragile memory tests
+ tests/test_checks.py::test_test_glgetfloat_leak
+ tests/test_vbo_memusage.py::test_sf_2980896
+ # missing EGL stuffs?
+ tests/test_checks.py::test_check_egl_es2
+ tests/test_checks.py::test_egl_ext_enumerate
+ )
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+ # refcounting tests
+
tests/test_checks.py::test_check_leak_on_discontiguous_array
+ )
+ ;;
+ esac
+
+ nonfatal epytest tests || die "Tests failed with ${EPYTHON}"
+}
+
+src_test() {
+ virtx distutils-r1_src_test
+}
