[gentoo-commits] proj/sci:master commit in: dev-python/ipyparallel/

[Justin Lecher]

commit:     8ffcba1cb3eeaf2a71050b70113ce4da9df7f286
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 28 10:45:41 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Wed Oct 28 10:45:41 2015 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=8ffcba1c

dev-python/ipyparallel: Version Bump

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 dev-python/ipyparallel/ipyparallel-4.1.0.ebuild | 58 +++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/dev-python/ipyparallel/ipyparallel-4.1.0.ebuild 
b/dev-python/ipyparallel/ipyparallel-4.1.0.ebuild
new file mode 100644
index 0000000..f951657
--- /dev/null
+++ b/dev-python/ipyparallel/ipyparallel-4.1.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Interactive Parallel Computing with IPython"
+HOMEPAGE="http://ipython.org/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+       dev-python/ipython_genutils[${PYTHON_USEDEP}]
+       dev-python/decorator[${PYTHON_USEDEP}]
+       >=dev-python/pyzmq-14.4.0[${PYTHON_USEDEP}]
+       dev-python/ipykernel[${PYTHON_USEDEP}]
+       !<dev-python/ipython-4.0.0[smp]
+       >=dev-python/ipython-4.0.0[${PYTHON_USEDEP}]
+       dev-python/jupyter_client[${PYTHON_USEDEP}]
+       "
+DEPEND="${RDEPEND}
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? (
+               dev-python/nose[${PYTHON_USEDEP}]
+               dev-python/requests[${PYTHON_USEDEP}]
+               dev-python/coverage[${PYTHON_USEDEP}]
+       )
+       "
+
+python_prepare_all() {
+       # Prevent un-needed download during build
+       if use doc; then
+               sed -e "/^    'sphinx.ext.intersphinx',/d" -i 
docs/source/conf.py || die
+       fi
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       iptest --coverage xml ipyparallel.tests || die
+}
+
+python_install_all() {
+       use doc && HTML_DOCS=( docs/build/html/. )
+       distutils-r1_python_install_all
+}