commit: a4b044549ba6bccd3f3fdf1fdb79a05728fd95cc
Author: David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 8 07:49:00 2016 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Mon Aug 8 07:49:45 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a4b04454
dev-python/Kivy: Version bump, add py3.5 support
* EAPI=6
* Also fix overlong DESCRIPTION
Package-Manager: portage-2.3.0
dev-python/Kivy/Kivy-1.9.0-r1.ebuild | 4 +--
dev-python/Kivy/Kivy-1.9.1.ebuild | 69 ++++++++++++++++++++++++++++++++++++
dev-python/Kivy/Manifest | 1 +
3 files changed, 72 insertions(+), 2 deletions(-)
diff --git a/dev-python/Kivy/Kivy-1.9.0-r1.ebuild
b/dev-python/Kivy/Kivy-1.9.0-r1.ebuild
index 1ce542c..843807e 100644
--- a/dev-python/Kivy/Kivy-1.9.0-r1.ebuild
+++ b/dev-python/Kivy/Kivy-1.9.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
@@ -8,7 +8,7 @@ PYTHON_COMPAT=( python{2_7,3_3,3_4} )
inherit distutils-r1 eutils
-DESCRIPTION="A software library for rapid development of hardware-accelerated
multitouch applications"
+DESCRIPTION="Library for rapid development of hardware-accelerated multitouch
applications"
HOMEPAGE="http://kivy.org/";
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
diff --git a/dev-python/Kivy/Kivy-1.9.1.ebuild
b/dev-python/Kivy/Kivy-1.9.1.ebuild
new file mode 100644
index 0000000..670d584
--- /dev/null
+++ b/dev-python/Kivy/Kivy-1.9.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DESCRIPTION="Library for rapid development of hardware-accelerated multitouch
applications"
+HOMEPAGE="http://kivy.org/";
+SRC_URI="https://pypi.io/packages/source/${PN:0:1}/${PN}/${P,,}.tar.gz";
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cairo camera doc examples garden gstreamer +sdl spell test"
+
+RDEPEND="
+ dev-python/pillow[${PYTHON_USEDEP}]
+ cairo? ( dev-python/pycairo[${PYTHON_USEDEP}] )
+ camera? ( media-libs/opencv )
+ garden? ( dev-python/kivy-garden[${PYTHON_USEDEP}] )
+ gstreamer? ( dev-python/gst-python:1.0[${PYTHON_USEDEP}] )
+ sdl? ( media-libs/libsdl2
+ media-libs/sdl2-ttf
+ media-libs/sdl2-image
+ media-libs/sdl2-mixer )
+ !sdl? ( dev-python/pygame[${PYTHON_USEDEP}] )
+ spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+ test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${P,,}"
+
+python_prepare_all() {
+ sed -e '/data_files=/d' -i "${S}/setup.py" || die
+ sed -e 's/PYTHON = python/PYTHON ?= python/' -i Makefile || die
+
+ export USE_SDL2=$(usex sdl 1 0)
+ export USE_GSTREAMER=$(usex gstreamer 1 0)
+ export KIVY_USE_SETUPTOOLS=1
+ distutils-r1_python_prepare_all
+}
+
+python_compile() {
+ esetup.py build_ext --inplace
+ esetup.py build
+}
+
+python_compile_all() {
+ use doc && emake html
+}
+
+python_test() {
+ emake test PYTHON="${PYTHON}"
+}
+
+python_install_all() {
+ use doc && HTML_DOCS=( doc/build/html/. )
+ use examples && EXAMPLES=( examples )
+ distutils-r1_python_install_all
+}
diff --git a/dev-python/Kivy/Manifest b/dev-python/Kivy/Manifest
index 7e5371c..3cd62f4 100644
--- a/dev-python/Kivy/Manifest
+++ b/dev-python/Kivy/Manifest
@@ -1 +1,2 @@
DIST Kivy-1.9.0.tar.gz 16178808 SHA256
b828617f858963f7873f5c81bb8824ca1dfa265e7811fce03599e2ba7200ffa0 SHA512
e0efc27f8ae070f5748570ee9224220791d32e931bbaf0bad5ddee894cf1d0f9ded5eebcc54d3b666491edaab0316923311f5e0cc7b1e46929d87ea3bec87f21
WHIRLPOOL
c57c696752c88d3c8643e126180aa00b864df45bad0de4e6456143fd0f1486085a258a787ec2e4017b982004dd5a1212b11dbcb352f1f72b77591fa5fd9c934e
+DIST kivy-1.9.1.tar.gz 16363833 SHA256
29bc45be34c26a8acb1dafdd329145f997a473be344cd052659f821f6478637e SHA512
1ae3ff3979a89e41c0af6493b7523835c1d01ee36fcd524f15d329b8fa875c6ca9bd25db3a844597fbc5370ff86b55ce177d3e66cc169223b02eb114c88c9989
WHIRLPOOL
f2eebf64f3abc2b63d307d8aadc87d0beb980e9bf5f85ff664e973b5c014ccb4f3fed58d24e2ca1e416e959ece1c094e34c0d75630003c89ab3a36237137042d
