commit:     123ec368a1004f2cd4cb4b52d53c6942a95322ab
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 16 17:51:55 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Fri Sep 16 19:37:58 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=123ec368

games-simulation/micropolis: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

 .../micropolis/micropolis-1.0-r1.ebuild            | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/games-simulation/micropolis/micropolis-1.0-r1.ebuild 
b/games-simulation/micropolis/micropolis-1.0-r1.ebuild
new file mode 100644
index 00000000..4d9db49
--- /dev/null
+++ b/games-simulation/micropolis/micropolis-1.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Free version of the well-known city building simulation"
+HOMEPAGE="http://www.donhopkins.com/home/micropolis/";
+SRC_URI="http://www.donhopkins.com/home/micropolis/${PN}-activity-source.tgz
+       http://rmdir.de/~michael/${PN}_git.patch";
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+       media-libs/libsdl
+       media-libs/sdl-mixer
+       x11-libs/libX11
+       x11-libs/libXpm"
+DEPEND="${RDEPEND}
+       sys-devel/bison"
+
+S=${WORKDIR}/${PN}-activity/
+
+PATCHES=(
+       "${DISTDIR}"/${PN}_git.patch
+)
+
+src_unpack() {
+       unpack ${PN}-activity-source.tgz
+}
+
+src_prepare() {
+       default
+
+       sed -i -e "s:-O3:${CFLAGS}:" \
+               src/tclx/config.mk src/{sim,tcl,tk}/makefile || die
+       sed -i -e "s:XLDFLAGS=:&${LDFLAGS}:" \
+               src/tclx/config.mk || die
+}
+
+src_compile() {
+       emake -C src LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+       local dir=/usr/share/${PN}
+
+       exeinto "${dir}/res"
+       doexe src/sim/sim
+       insinto "${dir}"
+       doins -r activity cities images manual res
+
+       make_wrapper micropolis res/sim "${dir}"
+       doicon Micropolis.png
+       make_desktop_entry micropolis "Micropolis" Micropolis
+}

Reply via email to