commit: 23e411d40f9fb1087ec7736295444e982b437870
Author: Amadeusz Żołnowski <aidecoe <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 5 20:58:59 2016 +0000
Commit: Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo <DOT> org>
CommitDate: Wed Oct 5 20:59:14 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23e411d4
net-im/gajim: Bump version to 0.16.6
Gentoo-Bug: 595966
Package-Manager: portage-2.3.1
net-im/gajim/Manifest | 1 +
net-im/gajim/gajim-0.16.6.ebuild | 123 +++++++++++++++++++++++++++++++++++++++
2 files changed, 124 insertions(+)
diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
index abeb817..fdff1e8 100644
--- a/net-im/gajim/Manifest
+++ b/net-im/gajim/Manifest
@@ -1 +1,2 @@
DIST gajim-0.16.5.tar.bz2 4562971 SHA256
a5c015b3b140ec5e47d3842cbe701c9948af5a0cce36314248f0793c2d66d091 SHA512
d69613f9e119f128adc9e81ace2475d3e3e41b47c153ea6ae5a9fcb5be390ec900893e1ab9ce694260898ebced00cd631a3ec4271ac27ed735d3f18dd1e1b6d4
WHIRLPOOL
d1405dedd29e867d9a05ca1678f3568acfb53baf7047294af66561a5542f70a02d9b8f22e42abae670e17e6f00461b423e01748ee31b8ada7be7d352af4bb344
+DIST gajim-0.16.6.tar.bz2 4564505 SHA256
1357ed178ce497d28fc2d48960b999821e1370f42ffaa4669c1cb803fce778dc SHA512
6c8c2a38429468a1e6f02aae730ff947c649960e8cc672457c1e1733ab2dad6534b1e5ac2e1c0c385e331a6ba817c6e67c1a27443632b9fd43e7ab76ad66c935
WHIRLPOOL
c0b3bdd60405123e1d0d004eac1a606dcbf485a8adf500f2c97ede45ebaf727f0c6c29d91066a7172ac459d473d1dc7703537950d8bfd31f1dbac857b734f4cf
diff --git a/net-im/gajim/gajim-0.16.6.ebuild b/net-im/gajim/gajim-0.16.6.ebuild
new file mode 100644
index 00000000..5cb87e7
--- /dev/null
+++ b/net-im/gajim/gajim-0.16.6.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite,xml"
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils python-r1 versionator
+
+MY_PV=${PV/_/-}
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="http://www.gajim.org/";
+SRC_URI="
+ http://www.gajim.org/downloads/$(get_version_component_range
1-2)/${MY_P}.tar.bz2"
+# test? ( https://dev.gentoo.org/~jlec/distfiles/${PN}-tests-${PV}.tar.xz
)"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="avahi crypt dbus gnome gnome-keyring kde idle jingle libnotify
networkmanager nls spell +srv test X xhtml"
+
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ libnotify? ( dbus )
+ avahi? ( dbus )
+ gnome? ( gnome-keyring )"
+
+COMMON_DEPEND="
+ ${PYTHON_DEPS}
+ dev-python/pygtk:2[${PYTHON_USEDEP}]
+ x11-libs/gtk+:2"
+DEPEND="${COMMON_DEPEND}
+ >=dev-util/intltool-0.40.1
+ virtual/pkgconfig
+ >=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+ dev-python/pyasn1[${PYTHON_USEDEP}]
+ >=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+ >=dev-python/python-nbxmpp-0.5.3[${PYTHON_USEDEP}]
+ crypt? (
+ app-crypt/gnupg
+ dev-python/pycrypto[${PYTHON_USEDEP}]
+ )
+ dbus? (
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ dev-libs/dbus-glib
+ libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+ avahi? ( net-dns/avahi[dbus,gtk,python,${PYTHON_USEDEP}] )
+ )
+ gnome? (
+ dev-python/libgnome-python[${PYTHON_USEDEP}]
+ dev-python/egg-python[${PYTHON_USEDEP}]
+ )
+ gnome-keyring? ( dev-python/gnome-keyring-python[${PYTHON_USEDEP}] )
+ idle? ( x11-libs/libXScrnSaver )
+ jingle? ( net-libs/farstream:0.1[python,${PYTHON_USEDEP}] )
+ kde? ( kde-apps/kwalletmanager )
+ networkmanager? (
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ net-misc/networkmanager
+ )
+ spell? ( app-text/gtkspell:2 )
+ srv? (
+ || (
+ dev-python/libasyncns-python[${PYTHON_USEDEP}]
+ net-dns/bind-tools
+ )
+ )
+ xhtml? ( dev-python/docutils[${PYTHON_USEDEP}] )"
+
+RESTRICT="test"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+ autotools-utils_src_prepare
+ python_copy_sources
+}
+
+src_configure() {
+ configuration() {
+ local myeconfargs=(
+ $(use_enable nls)
+ $(use_with X x)
+ --docdir="/usr/share/doc/${PF}"
+ --libdir="$(python_get_sitedir)"
+ --enable-site-packages
+ )
+ run_in_build_dir autotools-utils_src_configure
+ }
+ python_foreach_impl configuration
+}
+
+src_compile() {
+ compilation() {
+ run_in_build_dir autotools-utils_src_compile
+ }
+ python_foreach_impl compilation
+}
+
+src_test() {
+ testing() {
+ run_in_build_dir ${PYTHON} test/runtests.py --verbose 3 || die
+ }
+ python_foreach_impl testing
+}
+
+src_install() {
+ installation() {
+ run_in_build_dir autotools-utils_src_install
+ python_optimize
+ }
+ python_foreach_impl installation
+
+ rm "${ED}/usr/share/doc/${PF}/README.html" || die
+ dohtml README.html
+}
