commit: d47abc394732d47765fa5560581dfde698e52607
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 17 20:51:18 2017 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Feb 17 20:53:26 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d47abc39
www-apps/pyblosxom: distutils-r1, EAPI=6
.../pyblosxom/files/pyblosxom-1.4.2-gentoo.patch | 4 +-
www-apps/pyblosxom/pyblosxom-1.4.3-r1.ebuild | 50 +++++++++++++++++
www-apps/pyblosxom/pyblosxom-1.4.3.ebuild | 65 ----------------------
3 files changed, 52 insertions(+), 67 deletions(-)
diff --git a/www-apps/pyblosxom/files/pyblosxom-1.4.2-gentoo.patch
b/www-apps/pyblosxom/files/pyblosxom-1.4.2-gentoo.patch
index cc7d59f8a0..5f55faf5fb 100644
--- a/www-apps/pyblosxom/files/pyblosxom-1.4.2-gentoo.patch
+++ b/www-apps/pyblosxom/files/pyblosxom-1.4.2-gentoo.patch
@@ -1,5 +1,5 @@
---- setup.py.orig 2007-12-18 11:13:36.439046250 +0100
-+++ setup.py 2007-12-18 11:14:05.216844750 +0100
+--- a/setup.py 2007-12-18 11:13:36.439046250 +0100
++++ b/setup.py 2007-12-18 11:14:05.216844750 +0100
@@ -73,9 +73,7 @@
# we want to move the web script files as well, so we sneak them
# in here.
diff --git a/www-apps/pyblosxom/pyblosxom-1.4.3-r1.ebuild
b/www-apps/pyblosxom/pyblosxom-1.4.3-r1.ebuild
new file mode 100644
index 0000000000..3c31e6dd0e
--- /dev/null
+++ b/www-apps/pyblosxom/pyblosxom-1.4.3-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 webapp
+
+DESCRIPTION="Lightweight weblog system"
+HOMEPAGE="http://pyblosxom.sourceforge.net/";
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~x86"
+
+# This installs python library files.
+SLOT=0
+WEBAPP_MANUAL_SLOT=yes
+
+IUSE=""
+
+DEPEND=""
+RDEPEND=""
+
+PATCHES=(
+ "${FILESDIR}/${PN}-1.4.2-gentoo.patch"
+)
+
+src_install() {
+ webapp_src_preinst
+
+ distutils-r1_src_install
+
+ keepdir /usr/share/${P}/plugins
+ keepdir "${MY_HTDOCSDIR}"/data
+ keepdir "${MY_HTDOCSDIR}"/log
+
+ insinto "${MY_CGIBINDIR}"/pyblosxom
+ doins web/{config.py,pyblosxom.cgi}
+
+ webapp_configfile "${MY_CGIBINDIR}"/pyblosxom/config.py
+
+ webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+ webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt
+ webapp_hook_script "${FILESDIR}"/config-hook.sh
+
+ webapp_src_install
+}
diff --git a/www-apps/pyblosxom/pyblosxom-1.4.3.ebuild
b/www-apps/pyblosxom/pyblosxom-1.4.3.ebuild
deleted file mode 100644
index 524311ead1..0000000000
--- a/www-apps/pyblosxom/pyblosxom-1.4.3.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="3"
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* *-jython"
-
-inherit distutils eutils webapp
-
-DESCRIPTION="PyBlosxom is a lightweight weblog system"
-HOMEPAGE="http://pyblosxom.sourceforge.net/";
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-KEYWORDS="~amd64 ~arm ~x86"
-
-# This installs python library files.
-SLOT=0
-WEBAPP_MANUAL_SLOT=yes
-
-IUSE=""
-
-DEPEND=""
-RDEPEND=""
-
-PYTHON_MODNAME="Pyblosxom"
-
-pkg_setup() {
- python_pkg_setup
- webapp_pkg_setup
-}
-
-src_prepare() {
- distutils_src_prepare
- epatch "${FILESDIR}/${PN}-1.4.2-gentoo.patch"
-}
-
-src_install() {
- webapp_src_preinst
-
- distutils_src_install
- dodoc README
-
- keepdir /usr/share/${P}/plugins
- keepdir "${MY_HTDOCSDIR}"/data
- keepdir "${MY_HTDOCSDIR}"/log
-
- mkdir -p "${D}${MY_CGIBINDIR}"/pyblosxom
- cp web/{config.py,pyblosxom.cgi} "${D}${MY_CGIBINDIR}"/pyblosxom/
-
- webapp_configfile "${MY_CGIBINDIR}"/pyblosxom/config.py
-
- webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
- webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt
- webapp_hook_script "${FILESDIR}"/config-hook.sh
-
- webapp_src_install
-}
-
-pkg_postinst() {
- distutils_pkg_postinst
- webapp_pkg_postinst
-}
