[gentoo-commits] repo/gentoo:master commit in: media-libs/vulkan-loader/

[Matt Turner]

commit:     36ec412420a5688b3b3141aacccbabd453fa2b24
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Mar  3 22:06:35 2017 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Mar  3 22:50:54 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=36ec4124

media-libs/vulkan-loader: Add git ebuild.

 media-libs/vulkan-loader/vulkan-loader-9999.ebuild | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild 
b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
new file mode 100644
index 00000000000..3ffa6bfad76
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5} )
+
+if [[ "${PV}" == "9999" ]]; then
+       
EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-LoaderAndValidationLayers.git";
+       inherit git-r3
+else
+       KEYWORDS="~amd64"
+       
SRC_URI="https://github.com/KhronosGroup/Vulkan-LoaderAndValidationLayers/archive/sdk-${PV}.tar.gz
 -> ${P}.tar.gz"
+       S="${WORKDIR}/Vulkan-LoaderAndValidationLayers-sdk-${PV}"
+fi
+
+inherit python-any-r1 cmake-multilib
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://www.khronos.org/vulkan/";
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND=""
+
+DOCS=( README.md LICENSE.txt )
+
+multilib_src_configure() {
+       local mycmakeargs=(
+               -DCMAKE_SKIP_RPATH=True
+               -DBUILD_TESTS=False
+               -DBUILD_LAYERS=False
+               -DBUILD_DEMOS=False
+               -DBUILD_VKJSON=False
+               -DBUILD_LOADER=True
+               -DBUILD_WSI_MIR_SUPPORT=False
+       )
+       cmake-utils_src_configure
+}
+
+multilib_src_install() {
+       keepdir /etc/vulkan/icd.d
+
+       cd "${BUILD_DIR}/loader" || die
+       dolib libvulkan.so.1.*
+       dosym libvulkan.so.1.* /usr/$(get_libdir)/libvulkan.so.1
+       dosym libvulkan.so.1.* /usr/$(get_libdir)/libvulkan.so
+
+       cd "${S}" || die
+       insinto /usr/include/vulkan
+       doins include/vulkan/*.h
+       einstalldocs
+}