[gentoo-commits] repo/gentoo:master commit in: dev-libs/capstone/

[Sergei Trofimovich]

commit:     474fa516153f0d047ea0a2797ba81bbf043eda1b
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 29 08:58:53 2017 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Sat Jul 29 09:26:37 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=474fa516

dev-libs/capstone: add basic support for python bindings

Package-Manager: Portage-2.3.6, Repoman-2.3.3

 dev-libs/capstone/capstone-3.0.5_rc2-r1.ebuild | 82 ++++++++++++++++++++++++++
 1 file changed, 82 insertions(+)

diff --git a/dev-libs/capstone/capstone-3.0.5_rc2-r1.ebuild 
b/dev-libs/capstone/capstone-3.0.5_rc2-r1.ebuild
new file mode 100644
index 00000000000..fa2b8736435
--- /dev/null
+++ b/dev-libs/capstone/capstone-3.0.5_rc2-r1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_4} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="disassembly/disassembler framework + bindings"
+HOMEPAGE="http://www.capstone-engine.org/";
+SRC_URI="https://github.com/aquynh/${PN}/archive/${PV/_rc/-rc}.tar.gz -> 
${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3" # libcapstone.so.3
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="python"
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+PATCHES=(
+       "${FILESDIR}"/${P}-CVE-2017-6952.patch
+       "${FILESDIR}"/${P}-FLAGS.patch
+)
+
+S=${WORKDIR}/${P/_rc/-rc}
+
+wrap_python() {
+       if use python; then
+               pushd bindings/python >/dev/null || die
+               distutils-r1_${1} "$@"
+               popd >/dev/null
+       fi
+}
+
+src_prepare() {
+       default
+
+       wrap_python ${FUNCNAME}
+}
+
+src_configure() {
+       {
+               cat <<-EOF
+               # Gentoo overrides:
+               #   verbose build
+               V = 1
+               #   toolchain
+               AR = $(tc-getAR)
+               CC = $(tc-getCC)
+               RANLIB = $(tc-getRANLIB)
+               #  toolchain flags
+               CFLAGS = ${CFLAGS}
+               LDFLAGS = ${LDFLAGS}
+               #  libs
+               LIBDIRARCH = $(get_libdir)
+               EOF
+       } >> config.mk || die
+
+       wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+       default
+
+       wrap_python ${FUNCNAME}
+}
+
+src_test() {
+       default
+
+       wrap_python ${FUNCNAME}
+}
+
+src_install() {
+       default
+
+       wrap_python ${FUNCNAME}
+}