commit:     7205313d9c1616cedf6934de8bcd06bc5756b0a2
Author:     Sergey Popov <pinkbyte <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  8 11:34:48 2017 +0000
Commit:     Sergey Popov <pinkbyte <AT> gentoo <DOT> org>
CommitDate: Tue Aug  8 11:36:03 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7205313d

media-gfx/gimageview: revision bump

Bump EAPI to 6, add subslot operator to libpng and libmng dependencies.
Add support for user patches.
Use prune_libtool_files instead of manual cleanup.
Throw away einstall, banned in EAPI 6

Gentoo-Bug: 521556

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 media-gfx/gimageview/gimageview-0.2.27-r4.ebuild | 76 ++++++++++++++++++++++++
 1 file changed, 76 insertions(+)

diff --git a/media-gfx/gimageview/gimageview-0.2.27-r4.ebuild 
b/media-gfx/gimageview/gimageview-0.2.27-r4.ebuild
new file mode 100644
index 00000000000..d44c15f5177
--- /dev/null
+++ b/media-gfx/gimageview/gimageview-0.2.27-r4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+# TODO: USE xine could be restored if support for xine-lib-1.2.x
+# is patched in wrt #397639
+
+EAPI=6
+
+inherit eutils libtool
+
+DESCRIPTION="Powerful GTK+ based image & movie viewer"
+HOMEPAGE="http://gtkmmviewer.sourceforge.net/";
+SRC_URI="mirror://sourceforge/gtkmmviewer/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="mng nls mplayer svg wmf" #xine
+
+RDEPEND="app-arch/bzip2
+       x11-libs/gtk+:2
+       >=media-libs/libpng-1.2:0=
+       x11-libs/libXinerama
+       wmf? ( >=media-libs/libwmf-0.2.8 )
+       mng? ( media-libs/libmng:= )
+       svg? ( gnome-base/librsvg )
+       mplayer? ( media-video/mplayer )"
+#xine? ( media-libs/xine-lib )
+DEPEND="${RDEPEND}
+       nls? ( sys-devel/gettext )
+       virtual/pkgconfig"
+
+src_prepare() {
+       # link gimv executable against -lm for floor() and pow()
+       sed -i -e 's/$(gimv_LDADD)/& -lm/' src/Makefile.in || die #417995
+
+       epatch \
+               "${FILESDIR}"/${P}-sort_fix.diff \
+               "${FILESDIR}"/${P}-gtk12_fix.diff \
+               "${FILESDIR}"/${P}-gtk2.patch \
+               "${FILESDIR}"/${P}-libpng15.patch
+
+       # desktop-file-validate
+       sed -i \
+               -e '/^Term/s:0:false:' \
+               -e '/^Icon/s:.png::' \
+               etc/${PN}.desktop.in || die
+
+       eapply_user
+       elibtoolize
+}
+
+src_configure() {
+       econf \
+               --disable-imlib \
+               $(use_enable nls) \
+               --enable-splash \
+               $(use_enable mplayer) \
+               --with-gtk2 \
+               $(use_with mng libmng) \
+               $(use_with svg librsvg) \
+               $(use_with wmf libwmf) \
+               --without-xine
+}
+
+src_install() {
+       emake \
+               bindir="${ED}usr/bin" \
+               datadir="${ED}usr/share" \
+               desktopdir="${ED}usr/share/applications" \
+               gimv_docdir="${ED}usr/share/doc/${PF}" \
+               libdir="${ED}usr/$(get_libdir)" \
+               install
+
+       prune_libtool_files --all
+}

Reply via email to