commit: a290a166bd138022885798abc5f6daa65b2c579b
Author: Chris Reffett <creffett <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 21 00:53:51 2017 +0000
Commit: Chris Reffett <creffett <AT> gentoo <DOT> org>
CommitDate: Mon Aug 21 00:53:51 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a290a166
app-text/xiphos: Bump to 4.0.6a wrt bug 623804
Gentoo-Bug: 623804
Package-Manager: Portage-2.3.8, Repoman-2.3.3
app-text/xiphos/Manifest | 1 +
app-text/xiphos/xiphos-4.0.6a.ebuild | 90 ++++++++++++++++++++++++++++++++++++
2 files changed, 91 insertions(+)
diff --git a/app-text/xiphos/Manifest b/app-text/xiphos/Manifest
index e118bc67a1c..8ab8f859c84 100644
--- a/app-text/xiphos/Manifest
+++ b/app-text/xiphos/Manifest
@@ -1 +1,2 @@
DIST xiphos-4.0.4-20150830.tar.gz 8040173 SHA256
413bb8acb444946ccde1fb9fcfa3ff4bdb622cb56995b557f3215fab42193f20 SHA512
337503ee4cc6139ec8724266f3c9c0ce5d17518c48f7aab03ea8213165054854c8dd7317ff9e1b9097ece12292b52f1c8002684c00c5a7b43c5b4810edd6ecda
WHIRLPOOL
a1795b6fe5c978fcfc2c1f17f48844797bcf6e07a272181168717807dfd0a7b6e9359380a21fa330c539f1197c54c7e7293457f7733ab55d9dcca274ba044991
+DIST xiphos-4.0.6a-20170820.tar.gz 30584893 SHA256
f5d8464974828dd4f1cf27269ed00f64739ad4afa7c0d853c55b7713e25eb31d SHA512
a0577521c6b9033b74b3b0a0fd7a88222de00dc2e9db100d66e1bb60bc117173badd26c47d2e896ffa167c52a263c9bf9046d650a9b4ae497bec6164bfb0a29b
WHIRLPOOL
251aff54a9113c42eb2c8cb46f7c7c581177d906177f34681c82abf81c611cd5bd41fd597539b5b228c35e605c5c02f5d51b70795c9ae971323d703181201258
diff --git a/app-text/xiphos/xiphos-4.0.6a.ebuild
b/app-text/xiphos/xiphos-4.0.6a.ebuild
new file mode 100644
index 00000000000..ee8a6ba21b8
--- /dev/null
+++ b/app-text/xiphos/xiphos-4.0.6a.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit flag-o-matic gnome2-utils python-single-r1 toolchain-funcs
+
+MY_PV="${PV}-20170820"
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="A bible study frontend for Sword (formerly known as GnomeSword)"
+HOMEPAGE="http://xiphos.org/";
+SRC_URI="https://github.com/crosswire/${PN}/releases/download/${PV}/${MY_P}.tar.gz";
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2 MIT MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dbus debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+ >=app-text/sword-1.7.4
+ >=dev-libs/glib-2[${PYTHON_USEDEP}]
+ dev-libs/libxml2[${PYTHON_USEDEP}]
+ gnome-base/gconf[${PYTHON_USEDEP}]
+ gnome-extra/gtkhtml:4.0
+ >=gnome-extra/libgsf-1.14
+ net-libs/webkit-gtk:4
+ x11-libs/gtk+:3
+ dbus? ( dev-libs/dbus-glib )
+"
+DEPEND="${RDEPEND}
+ app-text/docbook2X
+ app-text/gnome-doc-utils[${PYTHON_USEDEP}]
+ app-text/rarian
+ dev-libs/libxslt[${PYTHON_USEDEP}]
+ dev-util/intltool
+ >=net-libs/biblesync-1.1.2-r1[-static]
+ virtual/pkgconfig
+ sys-devel/gettext
+"
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ sed -i \
+ -e '/FLAGS_DEBUG/s:-g:-Wall:' \
+ -e '/FLAGS_RELEASE/s:-O2:-Wall:' \
+ wscript || die
+ default
+}
+
+src_configure() {
+ append-cppflags -DNO_SWORD_SET_RENDER_NOTE_NUMBERS=1
+
+ tc-export AR CC CPP CXX RANLIB
+
+ CCFLAGS="${CFLAGS}" \
+ LINKFLAGS="${LDFLAGS}" \
+ SGML2MAN="$(type -P docbook2man.pl)" \
+ ./waf -v \
+ --prefix=/usr \
+ --gtk=3 \
+ --enable-webkit2 \
+ --debug-level=$(use debug && echo debug || echo
release) \
+ $(use dbus || echo --disable-dbus) \
+ configure || die
+}
+
+src_compile() {
+ ./waf -v build || die
+}
+
+src_install() {
+ ./waf -v --destdir="${D}" install || die
+
+ doman ${PN}.1
+ dodoc AUTHORS ChangeLog RELEASE-NOTES TODO
+
+ dodoc Xiphos.ogg
+ docompress -x /usr/share/doc/${PF}/Xiphos.ogg
+
+ rm -rf "${ED}"/usr/share/doc/${PN}
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }
