commit: 1b53db154bff325b09498cdd32db9a460e8eda84
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 25 22:42:26 2017 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Nov 25 22:55:53 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1b53db15
xfce-base/thunar: Bump to 1.7.0, development GTK+3 branch
xfce-base/thunar/Manifest | 1 +
xfce-base/thunar/thunar-1.7.0.ebuild | 78 ++++++++++++++++++++++++++++++++++++
2 files changed, 79 insertions(+)
diff --git a/xfce-base/thunar/Manifest b/xfce-base/thunar/Manifest
index 9c66372f035..79c38325b03 100644
--- a/xfce-base/thunar/Manifest
+++ b/xfce-base/thunar/Manifest
@@ -1,3 +1,4 @@
DIST Thunar-1.6.10.tar.bz2 1948762 SHA256
7e9d24067268900e5e44d3325e60a1a2b2f8f556ec238ec12574fbea15fdee8a SHA512
56f9407907c85a631b390b6bf363ee863b5a126afc32e1b10e34434b997e82b86223737a0b0a1a8faf801258ad1cfa0585c9c3537c167f6968a2c4dac458395a
WHIRLPOOL
813e3a1628227fbe27d221739e4946aa38b147ff4b165ff915b6a57b38ae544f54dc8facf19af0519fac5e903924459a34b6372c42985ed00e997e02434f4b71
DIST Thunar-1.6.12.tar.bz2 1929112 BLAKE2B
51e347340bdd322bcbd46a10b5b59c8249ac3761077a5bdacece47350cdd5f1426faf5ec81b850715619ffdd81faddfab28a15996a097c589c041678288b92cf
SHA512
d18e0fb6b58a65889dc47852a4c513acb7ff9a99fd70d34cbc6b2806d7818893b3c999c0a63f1b7af599d3ff4336b9637944989b97e5cc7431761ce493d2259d
DIST Thunar-1.6.13.tar.bz2 1937341 BLAKE2B
fc47188876e694f724e3f10a0c1e621b5cae4112c9cf4951e670cb56d30ab532b04e77a29fca79096b58aac260ae8a065a6b0caf72c8b4750944dea593be9f2f
SHA512
d1ae8efd0652c21b14ff45be9eef2ccf6b4400c744b08b2096a47b1af4eade2df1a237d03ede3e5dccea018b626dd67ffda2ed946b31fc2d3ff214c79e30168f
+DIST Thunar-1.7.0.tar.bz2 2235806 BLAKE2B
dfe81012dd0c8e760497f5c919bc2e7d4dd5e3fe78969776022f769b6332d15c9bbfadee8eef8eb5cb60d8e482ada9b7d9c2673db4252d6ae2adc4788e0d257e
SHA512
28f88108a2e6c415f81363330eae6046e858988b06cf6fc4408043dc6225e229aafcc1ccd5245568fb8910594a42bc7917a259eebe3ba597f453c6635c8ce639
diff --git a/xfce-base/thunar/thunar-1.7.0.ebuild
b/xfce-base/thunar/thunar-1.7.0.ebuild
new file mode 100644
index 00000000000..e3bf41864d8
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.7.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2-utils virtualx xdg-utils
+
+MY_P=${P^}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/
https://docs.xfce.org/xfce/thunar/start";
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86
~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre test +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+ >=dev-libs/glib-2.30:=
+ >=x11-libs/gdk-pixbuf-2.14:=
+ >=x11-libs/gtk+-3.20:3=
+ >=xfce-base/exo-0.10:=
+ >=xfce-base/libxfce4ui-4.12:=
+ >=xfce-base/libxfce4util-4.12:=
+ >=xfce-base/xfconf-4.12:=
+ exif? ( >=media-libs/libexif-0.6.19:= )
+ introspection? ( dev-libs/gobject-introspection:= )
+ libnotify? ( >=x11-libs/libnotify-0.7:= )
+ pcre? ( >=dev-libs/libpcre-6:= )
+ trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+ udisks? ( virtual/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+ >=dev-util/desktop-file-utils-0.20-r1
+ x11-misc/shared-mime-info
+ trash-panel-plugin? ( ${GVFS_DEPEND} )
+ udisks? (
+ virtual/udev
+ ${GVFS_DEPEND}[udisks,udev]
+ )"
+DEPEND="${COMMON_DEPEND}
+ dev-util/intltool
+ sys-devel/gettext
+ virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+PATCHES=(
+ "${FILESDIR}"/thunar-1.16.2-integer-overflow.patch
+)
+
+src_configure() {
+ local myconf=(
+ $(use_enable introspection)
+ $(use_enable udisks gudev)
+ $(use_enable libnotify notifications)
+ $(use_enable exif)
+ $(use_enable pcre)
+ $(use_enable trash-panel-plugin tpa-plugin)
+ )
+
+ econf "${myconf[@]}"
+}
+
+src_test() {
+ virtx emake check
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}
