[gentoo-commits] repo/gentoo:master commit in: dev-util/debugedit/

[Michał Górny]

commit:     c0c99015001c32b40a0cc0b7b41885fc20e3a7be
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 19 22:22:20 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Sep 19 22:25:35 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c0c99015

dev-util/debugedit: Bump to 4.14.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/debugedit/Manifest                |  1 +
 dev-util/debugedit/debugedit-4.14.2.ebuild | 89 ++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)

diff --git a/dev-util/debugedit/Manifest b/dev-util/debugedit/Manifest
index eab9b10ef33..9a83bb233b3 100644
--- a/dev-util/debugedit/Manifest
+++ b/dev-util/debugedit/Manifest
@@ -1 +1,2 @@
 DIST debugedit-5.3.5.tar.bz2 27799 BLAKE2B 
f81b39122502afe66386b962d0e50e9a16a314f31acf2a44c6d53f16d24ac91b62483a67fed43d085c3dd573adcd312cbb5e15c214fd8f00bc5415835c2caa37
 SHA512 
afac800a8f2e035705fcf997500d8fd2c3dc658850f47754863e8811db97859748721c5a252cc90dc81d07bf08763a9507e2272e983ee3f6bf16d8016fe5b8c9
+DIST rpm-4.14.2.tar.bz2 4151934 BLAKE2B 
eb7e32dd736a195f2e5effc184ee8f2c700dcaf80477574c2112b6c96504d86a67c81e611f82ea35ce244e95fad339bd262eb51c35ada5eeffa8d306b6938cb7
 SHA512 
22e309e8be936e6070430cedd6f5ea0c3871db4c6aadd0d567a9c418796c178c8dd45d44920d7eaa66681790cc2821347affe471cb215d7a490fe7947fbf291c

diff --git a/dev-util/debugedit/debugedit-4.14.2.ebuild 
b/dev-util/debugedit/debugedit-4.14.2.ebuild
new file mode 100644
index 00000000000..754bbccb0cf
--- /dev/null
+++ b/dev-util/debugedit/debugedit-4.14.2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+MY_P=rpm-${PV}
+DESCRIPTION="Stand-alone debugedit from RPM"
+HOMEPAGE="http://www.rpm.org
+       https://github.com/rpm-software-management/rpm";
+SRC_URI="http://ftp.rpm.org/releases/rpm-$(ver_cut 1-2).x/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+       sys-libs/zlib:=
+       >=dev-libs/popt-1.7
+       dev-libs/elfutils
+       dev-libs/nss
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+       eapply_user
+
+       # cheat it into believing we're bundling db
+       mkdir -p db/dist || die
+       touch db/dist/configure || die
+       chmod +x db/dist/configure || die
+       echo 'install:' > db3/Makefile || die
+
+       # TODO: why do we need to do this?
+       mkdir rpm || die
+       find -name '*.h' -exec cp {} rpm/ ';' || die
+}
+
+src_configure() {
+       append-cppflags -I"${EPREFIX}/usr/include/nss" 
-I"${EPREFIX}/usr/include/nspr"
+       local myconf=(
+               # force linking to static librpmio
+               --disable-shared
+
+               # disable linking compression libraries
+               ac_cv_header_bzlib_h=no
+               ac_cv_header_lzma_h=no
+               --disable-zstd
+
+               # fake some libraries we don't use
+               ac_cv_header_magic_h=yes
+               ac_cv_lib_magic_magic_open=yes
+
+               # use nss as crypto provider
+               --with-crypto=nss
+
+               # disable other stuff irrelevant to debugedit
+               --disable-nls
+               --disable-python
+               --without-acl
+               --without-archive
+               --without-cap
+               --without-external-db
+               --without-hackingdocs
+               --without-lua
+               --without-selinux
+       )
+       econf "${myconf[@]}"
+}
+
+src_compile() {
+       emake -C misc
+       emake -C rpmio
+       emake debugedit
+}
+
+src_test() {
+       :
+}
+
+src_install() {
+       dobin debugedit
+}