commit: 870e668928bbdd0868df69337c73e6fd0902853c
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 28 05:07:05 2018 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Dec 28 05:12:30 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=870e6689
net-wireless/blueman: Bump to 2.1alpha3
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
net-wireless/blueman/Manifest | 1 +
net-wireless/blueman/blueman-2.1_alpha3.ebuild | 130 +++++++++++++++++++++++++
2 files changed, 131 insertions(+)
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index 8bfb88933d5..7f7f0743ec3 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1 +1,2 @@
DIST blueman-2.1.alpha2.tar.xz 977344 BLAKE2B
c5d3d0a96c1220596647ade310263342cdaaeef511a2fb36973d182025330a29b41fb805ce54e10a2f48c1c66312006858789233f8f0a93923952bb03ac32b19
SHA512
bde4922a93087d07fd99b165255ded8d9465866e62662f644beaafe363d5618a107abbd9d951cfbd034b02b6ece11fb8117efdd5d453632e4a2fea13d3825643
+DIST blueman-2.1.alpha3.tar.xz 977724 BLAKE2B
a1b02956249c65bb9dc870f9585f917b17e99d570c2a3f05f505de9ea4ec004ff9ad5d88e958ec84566fdcf0f3fe6cf1965dcdc050241feedbd08fff98d18b22
SHA512
e2ad9aff87148e522705872829e9c4c78a1bfbe29e102b69b1f1f56348743343cb543eaac4c21e157aa579b76f023ca9164700a4a08848f55f17d025cead23a6
diff --git a/net-wireless/blueman/blueman-2.1_alpha3.ebuild
b/net-wireless/blueman/blueman-2.1_alpha3.ebuild
new file mode 100644
index 00000000000..2d562123946
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.1_alpha3.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{3_4,3_5,3_6,3_7} )
+inherit gnome2-utils linux-info python-single-r1 systemd
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman";
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/blueman-project/blueman.git";
+ KEYWORDS=""
+else
+
SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz";
+ KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio"
+
+COMMON_DEPEND="
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ >=net-wireless/bluez-5:=
+ ${PYTHON_DEPS}"
+DEPEND="${COMMON_DEPEND}
+ dev-python/cython[${PYTHON_USEDEP}]
+ virtual/pkgconfig
+ nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${COMMON_DEPEND}
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ sys-apps/dbus
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify[introspection]
+ || (
+ x11-themes/adwaita-icon-theme
+ x11-themes/faenza-icon-theme
+ x11-themes/mate-icon-theme
+ )
+ appindicator? ( dev-libs/libappindicator:3[introspection] )
+ network? (
+ net-firewall/iptables
+ || (
+ sys-apps/net-tools
+ sys-apps/iproute2
+ )
+ || (
+ net-dns/dnsmasq
+ net-misc/dhcp
+ >=net-misc/networkmanager-0.8
+ )
+ )
+ policykit? ( sys-auth/polkit )
+ pulseaudio? ( media-sound/pulseaudio[bluetooth] )
+ !net-wireless/gnome-bluetooth
+"
+
+S=${WORKDIR}/${P/_/.}
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+ if use network; then
+ local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+ ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+ linux-info_pkg_setup
+ fi
+}
+
+pkg_setup() {
+ pkg_pretend
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ [[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+ local myconf=(
+ --docdir=/usr/share/doc/${PF}
+ --disable-runtime-deps-check
+ --disable-static
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ --with-systemduserunitdir="$(systemd_get_userunitdir)"
+ $(use_enable appindicator)
+ $(use_enable policykit polkit)
+ $(use_enable nls)
+ $(use_enable pulseaudio)
+ # thunar integration is a single data file with no extra deps
+ # so install it unconditionally
+ --enable-thunar-sendto
+ # ignore pointless check
+ NETWORKTOOLS=/bin/true
+ )
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+
+ if use policykit; then
+ # Allow users in plugdev group to modify connections
+ insinto /usr/share/polkit-1/rules.d
+ doins "${FILESDIR}/01-org.blueman.rules"
+ fi
+
+ python_fix_shebang "${D}"
+ rm "${D}"/$(python_get_sitedir)/*.la || die
+}
+
+pkg_preinst() {
+ gnome2_icon_savelist
+ gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ gnome2_schemas_update
+}
