[gentoo-commits] repo/gentoo:master commit in: dev-python/pysnmp/

[Jeroen Roovers]

commit:     64b19e1a4f5aa3ef52d6ebb7ef68bd9889305799
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 11 14:18:38 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Mon Feb 11 14:19:12 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=64b19e1a

dev-python/pysnmp: Add live ebuild

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 dev-python/pysnmp/pysnmp-999999.ebuild | 52 ++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-python/pysnmp/pysnmp-999999.ebuild 
b/dev-python/pysnmp/pysnmp-999999.ebuild
new file mode 100644
index 00000000000..7d9fdd38f8d
--- /dev/null
+++ b/dev-python/pysnmp/pysnmp-999999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+inherit distutils-r1 git-r3
+
+DESCRIPTION="Python SNMP library"
+HOMEPAGE="http://snmplabs.com/pysnmp/ https://pypi.org/project/pysnmp/ 
https://github.com/etingof/pysnmp";
+EGIT_REPO_URI="https://github.com/etingof/pysnmp";
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc examples"
+
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+RDEPEND="
+       >=dev-python/pyasn1-0.2.3[${PYTHON_USEDEP}]
+       dev-python/pysmi[${PYTHON_USEDEP}]
+       || (
+               dev-python/pycryptodome[${PYTHON_USEDEP}]
+               dev-python/pycrypto[${PYTHON_USEDEP}]
+       )
+"
+
+python_compile_all() {
+       default
+
+       if use doc; then
+               touch docs/source/conf.py
+               emake -C docs html
+       fi
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/build/html/* )
+       docinto examples
+       use examples && dodoc -r examples/* docs/mibs
+
+       distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+       elog "You may also be interested in the following packages: "
+       elog "dev-python/pysnmp-apps - example programs using pysnmp"
+       elog "dev-python/pysnmp-mibs - IETF and other mibs"
+       elog "dev-python/pysmi - to dump MIBs in python format"
+}