commit: 568aa11ed0e00086a6d28d637d7c951f0d5d0dca
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 13 12:45:59 2019 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Aug 13 12:46:19 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=568aa11e
dev-libs/libinput: Bump to version 1.14.0
Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
dev-libs/libinput/Manifest | 1 +
dev-libs/libinput/libinput-1.14.0.ebuild | 78 ++++++++++++++++++++++++++++++++
2 files changed, 79 insertions(+)
diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 7cc34fe98e2..d0c3893a8f9 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
DIST libinput-1.13.4.tar.xz 530000 BLAKE2B
96345625b98ecc5476b9525cac84ec6cffb5854ce8d9e197fa73dbcb3548ebfea7820fa32d4e808222c0471fc94d89003775587cc0ed9c8445dd5902d3463792
SHA512
ccfdfc704dab9ea19a503399ecd4ce3a95b8d9480b8dfddeb80be01236c34c6f2f472be0e12e04dddd68092611470d303351e092141bc7491729639bcf7e64d7
+DIST libinput-1.14.0.tar.xz 563272 BLAKE2B
9d5f831c9224b01aa4be92494f28ab95909dff2d81f5e60bada2ca12a2fb4f5745b99a4caa4abef06938cbd7d9e8da9aed85573e447ad6b6e52392e17534953a
SHA512
e501c5b8a58bb287c175692af0e59ff766a8613eb576aaa0700686dfbb6c6ab63b7a5d3f148fce75397c8170bc49871068861d93c352355ab5d0d9e7f1b059ec
diff --git a/dev-libs/libinput/libinput-1.14.0.ebuild
b/dev-libs/libinput/libinput-1.14.0.ebuild
new file mode 100644
index 00000000000..c6c5651aad4
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.14.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 2014-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/
https://gitlab.freedesktop.org/libinput/libinput";
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz";
+
+LICENSE="MIT"
+SLOT="0/10"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom"
+# Tests require write access to udev rules directory which is a no-no for live
system.
+# Other tests are just about logs, exported symbols and autotest of the test
library.
+RESTRICT="test"
+
+BDEPEND="
+ virtual/pkgconfig
+ doc? (
+ $(python_gen_any_dep '
+ dev-python/commonmark[${PYTHON_USEDEP}]
+ dev-python/recommonmark[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ >=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+ ')
+ >=app-doc/doxygen-1.8.3
+ >=media-gfx/graphviz-2.38.0
+ )
+"
+# test? ( dev-util/valgrind )
+RDEPEND="
+ input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+ >=dev-libs/libevdev-1.3
+ >=sys-libs/mtdev-1.1
+ virtual/libudev:=
+ virtual/udev
+"
+DEPEND="${RDEPEND}"
+# test? ( >=dev-libs/check-0.9.10 )
+
+python_check_deps() {
+ has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+ has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+ has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+ has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+ # gui can be built but will not be installed
+ local emesonargs=(
+ -Ddebug-gui=false
+ $(meson_use doc documentation)
+ $(meson_use input_devices_wacom libwacom)
+ -Dtests=false # tests are restricted
+ -Dudev-dir="$(get_udevdir)"
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ if use doc ; then
+ docinto html
+ dodoc -r "${BUILD_DIR}"/Documentation/.
+ fi
+}
+
+pkg_postinst() {
+ udevadm hwdb --update --root="${ROOT}"
+}
