commit: d3709f58e5f121e56112d622f8e2cefb964ee562
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 1 14:31:48 2020 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Jan 1 14:33:23 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d3709f58
sys-apps/fwupd: Bump to version 1.3.6
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
sys-apps/fwupd/Manifest | 1 +
sys-apps/fwupd/fwupd-1.3.6.ebuild | 161 ++++++++++++++++++++++++++++++++++++++
sys-apps/fwupd/metadata.xml | 1 +
3 files changed, 163 insertions(+)
diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 6ae3d823709..85bd3c118fc 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -2,3 +2,4 @@ DIST fwupd-1.2.11.tar.gz 1945646 BLAKE2B
4eb6d5008d0e515880147a94b2632ed70b5f7ab
DIST fwupd-1.2.8.tar.gz 1911999 BLAKE2B
61a24ce24f778b96f7ad23496890f7a1d20c09e6bbd707f29d154992668d5c0a25cfd31b5d0d11519740e086c098cbdfd440fe9f5cab4dde0ac43fe6b438e911
SHA512
d603f9f4e5a4c0fc6abb0b75f7d884eff47fb8a16285aa545f7140fe98ce781d127ff3769f9c206bb3bfd084bbc5bf6abf9424f70e727ff79162416fe7881154
DIST fwupd-1.3.4.tar.gz 2151009 BLAKE2B
3ea171d4a9498963b6082ae2e3f9b41edde862b84f3f506e403bc2dd6a08ec27ccbac6c5891bdf567860f43b008ccd36a7e6d40e72f2d252eceb913833372719
SHA512
00b6ba394c74252c1c7eba5e5e1fd92f234fb6db6de8bca69fbc578bf3b12790867b6adaef6c422c801d28990d390bbe8af67ab0f5bd3a744adbeb053708a254
DIST fwupd-1.3.5.tar.gz 2164874 BLAKE2B
aa268f3d94b3c7104cad5e80de81a724ba978e3da468cd2d44833656c5b0a95b1f720f5c7a0dd9812b8afce4c58e8f777e13ea2e1f4ce0b8b582ee3c731b744a
SHA512
b1944b06bed9cb10ec90219235b168a76fcf6ff7b8938dfba36259f07efed71a755d7b91fcbe8f6fda00ac971bd5d4734a49e045005e2e1c32b49fc5b86c48dd
+DIST fwupd-1.3.6.tar.gz 2207849 BLAKE2B
465055d90576d4c0a7812f2554d2bc3298a12030816a2469ce653d28f9ea81e363c401355191d41b200975a615cfc64b954e0cced6b6f6bbfbbf26f63163a25e
SHA512
20a5f346563b1cb8296f31ea448f336d8b54df2e5296524e2fa040a31001838b0de4a88f0d4aad9f5eeaeb4acc46919c0effb254ce681556db00cec5a4a1bc78
diff --git a/sys-apps/fwupd/fwupd-1.3.6.ebuild
b/sys-apps/fwupd/fwupd-1.3.6.ebuild
new file mode 100644
index 00000000000..6eda785bfe3
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.3.6.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and
reliable"
+HOMEPAGE="https://fwupd.org";
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="agent amt consolekit dell gtk-doc elogind minimal +gpg introspection
+man nvme pkcs7 redfish synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ ^^ ( consolekit elogind minimal systemd )
+ dell? ( uefi )
+ minimal? ( !introspection )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gtk-doc )
+ introspection? ( dev-libs/gobject-introspection )
+ man? (
+ app-text/docbook-sgml-utils
+ sys-apps/help2man
+ )
+ test? (
+ thunderbolt? ( dev-util/umockdev )
+ net-libs/gnutls[tools]
+ )
+"
+DEPEND="${PYTHON_DEPS}
+ >=app-arch/gcab-1.0
+ app-arch/libarchive:=
+ dev-db/sqlite
+ >=dev-libs/glib-2.45.8:2
+ dev-libs/json-glib
+ dev-libs/libgpg-error
+ dev-libs/libgudev:=
+ >=dev-libs/libgusb-0.2.9[introspection?]
+ >=dev-libs/libxmlb-0.1.13
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+ >=net-libs/libsoup-2.51.92:2.4[introspection?]
+ virtual/libelf:0=
+ virtual/udev
+ consolekit? ( >=sys-auth/consolekit-1.0.0 )
+ dell? (
+ sys-libs/efivar
+ >=sys-libs/libsmbios-2.4.0
+ )
+ elogind? ( sys-auth/elogind )
+ gpg? (
+ app-crypt/gpgme
+ dev-libs/libgpg-error
+ )
+ !minimal? (
+ >=sys-auth/polkit-0.103
+ )
+ nvme? ( sys-libs/efivar )
+ pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+ redfish? ( sys-libs/efivar )
+ systemd? ( >=sys-apps/systemd-211 )
+ thunderbolt? (
+ sys-apps/thunderbolt-software-user-space
+ )
+ tpm? ( app-crypt/tpm2-tss )
+ uefi? (
+ app-crypt/tpm2-tss
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-boot/gnu-efi
+ sys-boot/efibootmgr
+ >=sys-libs/efivar-33
+ x11-libs/cairo
+ )
+"
+RDEPEND="
+ ${DEPEND}
+ sys-apps/dbus
+"
+
+pkg_setup() {
+ tc-ld-disable-gold # bug https://github.com/fwupd/fwupd/issues/1530
+
+ python-single-r1_pkg_setup
+ if use nvme; then
+ kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+ fi
+}
+
+src_prepare() {
+ default
+ # c.f. https://github.com/fwupd/fwupd/issues/1414
+ sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout :
120)/d" \
+ -i plugins/thunderbolt/meson.build || die
+ vala_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ --localstatedir "${EPREFIX}"/var
+ -Dbuild="$(usex minimal standalone all)"
+ $(meson_use agent)
+ $(meson_use amt plugin_amt)
+ $(meson_use consolekit)
+ $(meson_use dell plugin_dell)
+ $(meson_use elogind)
+ $(meson_use gpg)
+ $(meson_use gtk-doc gtkdoc)
+ $(meson_use man)
+ $(meson_use nvme plugin_nvme)
+ $(meson_use pkcs7)
+ $(meson_use redfish plugin_redfish)
+ $(meson_use synaptics plugin_synaptics)
+ $(meson_use systemd)
+ $(meson_use test tests)
+ $(meson_use thunderbolt plugin_thunderbolt)
+ $(meson_use tpm plugin_tpm)
+ $(meson_use uefi plugin_uefi)
+ # Requires libflashrom which our sys-apps/flashrom
+ # package does not provide
+ -Dplugin_flashrom="false"
+ # Dependencies are not available (yet?)
+ -Dplugin_modem_manager="false"
+ )
+ export CACHE_DIRECTORY="${T}"
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ if ! use minimal ; then
+ sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
+ "${FILESDIR}"/${PN}-r1 \
+ > "${T}"/${PN} || die
+ doinitd "${T}"/${PN}
+
+ if ! use systemd ; then
+ # Don't timeout when fwupd is running (#673140)
+ sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+ -i "${ED}"/etc/${PN}/daemon.conf || die
+ fi
+ fi
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ elog "In case you are using openrc as init system"
+ elog "and you're upgrading from <fwupd-1.1.0, you"
+ elog "need to start the fwupd daemon via the openrc"
+ elog "init script that comes with this package."
+}
diff --git a/sys-apps/fwupd/metadata.xml b/sys-apps/fwupd/metadata.xml
index 1d2ad3564b9..2dedd857c0d 100644
--- a/sys-apps/fwupd/metadata.xml
+++ b/sys-apps/fwupd/metadata.xml
@@ -22,6 +22,7 @@
<flag name="redfish">Install redfish plugin</flag>
<flag name="synaptics">Install synaptics plugin</flag>
<flag name="thunderbolt">Install Thunderbolt plugin</flag>
+ <flag name="tpm">Install Trusted Platform Module plugin</flag>
<flag name="uefi">Enable UEFI support</flag>
</use>
<upstream>
