commit: f2c449cf191dc1fb58ec8472f5a0bfc3887f5a57
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 16 23:30:52 2020 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Apr 17 00:04:02 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f2c449cf
dev-python/translate-toolkit: 2.5.0 version bump, full python3_8 support
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-python/translate-toolkit/Manifest | 1 +
.../translate-toolkit-2.5.0.ebuild | 77 ++++++++++++++++++++++
2 files changed, 78 insertions(+)
diff --git a/dev-python/translate-toolkit/Manifest
b/dev-python/translate-toolkit/Manifest
index 7786dc1d18f..d3b39c62bbd 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1 +1,2 @@
DIST translate-toolkit-2.4.0.tar.gz 7646438 BLAKE2B
5d956ce05b57aa3ec2c7896a36f199cab5a590d4d6a4ad84263d7b757e35d5e42a40cac38ea3da1c8a11c64b1cacff5a5742b79ad5a87436842a35547d89e611
SHA512
715d9e974c451a5c3d92471287f4da8e8ba663efda849398f77a3c3d6f16e0c9a8e685261ec07c02ce9bd13f3766f0b2b1ad441b92116bb3913036ffbd415658
+DIST translate-toolkit-2.5.0.tar.gz 7679224 BLAKE2B
927b0dcfc0836ed2f2589d70f5789fc6d8b23a3e80bf4ef0054704ca12e4b5287a7e3b2a90992197bae6fc0acee1ea9d93a8eff05f6e5182f9269ca2aa9e5a66
SHA512
c4ff8fe9e7cc5b44a5448391ecbcfc454bf32d3794267e67824b020ca78cfbeba1283287a42f07859cd197a413fe8171ad5e31375f60fec77f334642ed2ad13e
diff --git a/dev-python/translate-toolkit/translate-toolkit-2.5.0.ebuild
b/dev-python/translate-toolkit/translate-toolkit-2.5.0.ebuild
new file mode 100644
index 00000000000..0686fe28f54
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-2.5.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate";
+SRC_URI="https://github.com/translate/translate/releases/download/${PV}/${P}.tar.gz";
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc +html +ical +ini +subtitles +yaml"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+ doc? ( >=dev-python/sphinx-3.0.1 )
+"
+DEPEND="
+ >=dev-python/six-1.11.0[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+ !dev-python/pydiff
+ app-text/iso-codes
+ >=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+ >=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+ >=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+ >=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+ ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+ ini? ( dev-python/iniparse[${PYTHON_USEDEP}] )
+ subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+ yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+ # Prevent unwanted d'loading in doc build
+ sed -e "/^ 'sphinx.ext.intersphinx',/d" \
+ -e "/html_theme/ s/sphinx-bootstrap/classic/" \
+ -i docs/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ emake -C docs html
+ HTML_DOCS=( "${S}"/docs/_build/html/. )
+ fi
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ rm -Rf docs || die
+ if ! use html; then
+ rm "${ED}"/usr/bin/{html2po,po2html} || die
+ fi
+ if ! use ical; then
+ rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+ fi
+ if ! use ini; then
+ rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+ fi
+ if ! use subtitles; then
+ rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+ fi
+
+ python_optimize
+}
