[gentoo-commits] repo/gentoo:master commit in: sci-electronics/pulseview/

[Andreas Sturmlechner]

commit:     c01317a60bbc97e51bf1d33efbac8b259e450a01
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  2 22:36:35 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Jul  6 18:15:27 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c01317a6

sci-electronics/pulseview: 0.4.2 version bump

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-electronics/pulseview/Manifest               |  1 +
 sci-electronics/pulseview/pulseview-0.4.2.ebuild | 74 ++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/sci-electronics/pulseview/Manifest 
b/sci-electronics/pulseview/Manifest
index 48cd9f5d045..9180854c0bb 100644
--- a/sci-electronics/pulseview/Manifest
+++ b/sci-electronics/pulseview/Manifest
@@ -1 +1,2 @@
 DIST pulseview-0.4.1.tar.gz 1342532 BLAKE2B 
759779d4024df8f972fbed515764f17557014972abcb39d3942b411bfa78c6f97a89ee98b706adb51d240bdb738925546cec073f98ba829f1e325acaac892c01
 SHA512 
0bae4357be312bf6e997885270887a5bcc0a8dfb6914e63bb0d5abb35389b6681748e0e4667556ad432c5432c861185bcdd8da7815fb570fc8a2fbbf5eed3801
+DIST pulseview-0.4.2.tar.gz 1399718 BLAKE2B 
ebbefefa55bb7ce9d1bbdfa8ea44d9536fa4f9ca9f6f13175a5bb6122dcb431ddad7c668e631128ca57fd2231021f8ce1c686fac9fa746ace24cf69ef3d71e71
 SHA512 
79f653c9faad021c03b59b4a519b594190d5558dfb9be60cabcc2a35e991e66b733b337fec58a9248699e7aef0df3be1472c81f93274b25cec1fc6b73f8f033b

diff --git a/sci-electronics/pulseview/pulseview-0.4.2.ebuild 
b/sci-electronics/pulseview/pulseview-0.4.2.ebuild
new file mode 100644
index 00000000000..33c5fe3766d
--- /dev/null
+++ b/sci-electronics/pulseview/pulseview-0.4.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit cmake python-single-r1 xdg-utils
+
+if [[ ${PV} == *9999* ]]; then
+       EGIT_REPO_URI="git://sigrok.org/${PN}"
+       inherit git-r3
+else
+       SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz";
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Qt based logic analyzer GUI for sigrok"
+HOMEPAGE="https://sigrok.org/wiki/PulseView";
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+decode static"
+REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+       dev-qt/linguist-tools:5
+       virtual/pkgconfig
+"
+RDEPEND="
+       >=dev-cpp/glibmm-2.28.0:2
+       >=dev-libs/boost-1.55:=
+       >=dev-libs/glib-2.28.0:2
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtsvg:5
+       dev-qt/qtwidgets:5
+       >=sci-libs/libsigrok-0.5.1:=[cxx]
+       decode? (
+               ${PYTHON_DEPS}
+               >=sci-libs/libsigrokdecode-0.5.2:=[${PYTHON_SINGLE_USEDEP}]
+       )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( HACKING NEWS README )
+
+pkg_setup() {
+       use decode && python_setup
+}
+
+src_prepare() {
+       cmake_src_prepare
+       cmake_comment_add_subdirectory manual
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DDISABLE_WERROR=TRUE
+               -DENABLE_DECODE=$(usex decode)
+               -DSTATIC_PKGDEPS_LIBS=$(usex static)
+       )
+       cmake_src_configure
+}
+
+pkg_postinst() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+}
+
+pkg_postrm() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+}