commit: 0649522d1987df1844e32c7f3a2229871be417a9
Author: Patrick McLean <patrick.mclean <AT> sony <DOT> com>
AuthorDate: Tue Jul 28 00:14:07 2020 +0000
Commit: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Tue Jul 28 00:14:27 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0649522d
dev-util/trace-cmd-2.9.1: Version bump
Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>
dev-util/trace-cmd/Manifest | 1 +
dev-util/trace-cmd/trace-cmd-2.9.1.ebuild | 130 ++++++++++++++++++++++++++++++
2 files changed, 131 insertions(+)
diff --git a/dev-util/trace-cmd/Manifest b/dev-util/trace-cmd/Manifest
index 4c4cec3dacc..53023f987a4 100644
--- a/dev-util/trace-cmd/Manifest
+++ b/dev-util/trace-cmd/Manifest
@@ -1 +1,2 @@
DIST trace-cmd-v2.8.3.tar.gz 1996617 BLAKE2B
0ab77649af90a0a9368ff118dc94e6fd003b18ceb2065ae3a4559a1d2cfa93be44d87bfb97e2e2f06898508699ff5ce18face4edefd7e40b3b9cca405a626cff
SHA512
51166c4276abda209a099cc6fe9081ad6d403cbfd9d4a53bc5bb068392327e88fe647e9324a527e68730d73d1a5f7f74126718547f94c652bb12e51c7518a58b
+DIST trace-cmd-v2.9.1.tar.gz 4298008 BLAKE2B
f7aa2f12b2c90f35390857ed6f5818b74c42be36ce70835d86410f9f4931d27410123baaad007fa2795c1ba1f5bafc739db620f467ccc48021d774ee7be8a68d
SHA512
186bfdd8ff1e88e9e6d3ae87b123f049892deaaa8d6a42944b6f8abee6b828946b88774029aa96daf4423a3dfc01b42835508f44f636dd02579ef9a8ef425131
diff --git a/dev-util/trace-cmd/trace-cmd-2.9.1.ebuild
b/dev-util/trace-cmd/trace-cmd-2.9.1.ebuild
new file mode 100644
index 00000000000..05cc150deec
--- /dev/null
+++ b/dev-util/trace-cmd/trace-cmd-2.9.1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_OPTIONAL=1
+
+inherit linux-info bash-completion-r1 python-r1 toolchain-funcs
+
+DESCRIPTION="User-space front-end for Ftrace"
+HOMEPAGE="https://git.kernel.org/cgit/linux/kernel/git/rostedt/trace-cmd.git";
+
+if [[ ${PV} == *9999 ]] ; then
+
EGIT_REPO_URI="https://git.kernel.org/pub/scm/linux/kernel/git/rostedt/${PN}.git";
+ inherit git-r3
+else
+
SRC_URI="https://git.kernel.org/pub/scm/utils/trace-cmd/trace-cmd.git/snapshot/${PN}-v${PV}.tar.gz";
+ KEYWORDS="~amd64 ~arm64 ~x86"
+ S="${WORKDIR}/${PN}-v${PV}"
+fi
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0/${PV}"
+IUSE="+audit doc python test udis86"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ audit? ( sys-process/audit )
+ python? ( ${PYTHON_DEPS} )
+ udis86? ( dev-libs/udis86 )
+"
+DEPEND="${RDEPEND}
+ sys-kernel/linux-headers
+ test? ( dev-util/cunit )
+"
+BDEPEND="
+ python? (
+ virtual/pkgconfig
+ dev-lang/swig
+ )
+ doc? ( app-text/asciidoc )
+"
+
+# having trouble getting tests to compile
+RESTRICT+=" test"
+
+pkg_setup() {
+ local CONFIG_CHECK="
+ ~TRACING
+ ~FTRACE
+ ~BLK_DEV_IO_TRACE"
+
+ linux-info_pkg_setup
+}
+
+src_prepare() {
+ default
+ sed -r -e 's:([[:space:]]+)install_bash_completion($|[[:space:]]+):\1:'
\
+ -i Makefile || die "sed failed"
+}
+
+src_configure() {
+ EMAKE_FLAGS=(
+ BUILD_OUTPUT="${WORKDIR}/${P}_build"
+ "prefix=${EPREFIX}/usr"
+ "libdir=${EPREFIX}/usr/$(get_libdir)"
+ "CC=$(tc-getCC)"
+ "AR=$(tc-getAR)"
+ "BASH_COMPLETE_DIR=$(get_bashcompdir)"
+ "etcdir=/etc"
+ $(usex audit '' 'NO_AUDIT=' '' '1')
+ $(usex test 'CUNIT_INSTALLED=' '' '1' '')
+ $(usex udis86 '' 'NO_UDIS86=' '' '1')
+ VERBOSE=1
+ )
+}
+
+src_compile() {
+ emake "${EMAKE_FLAGS[@]}" NO_PYTHON=1 \
+ trace-cmd
+
+ if use python; then
+ python_copy_sources
+ python_foreach_impl python_compile
+ fi
+
+ use doc && emake doc
+}
+
+python_compile() {
+ pushd "${BUILD_DIR}" > /dev/null || die
+
+ emake "${EMAKE_FLAGS[@]}" \
+ PYTHON_VERS="${EPYTHON}" \
+ PYTHON_PKGCONFIG_VERS="${EPYTHON//python/python-}" \
+ python_dir=$(python_get_sitedir)/${PN} \
+ python ctracecmd.so
+
+ popd > /dev/null || die
+}
+
+src_test() {
+ emake "${EMAKE_FLAGS[@]}" test
+}
+
+src_install() {
+ emake "${EMAKE_FLAGS[@]}" NO_PYTHON=1 \
+ DESTDIR="${D}" \
+ install install_libs
+
+ newbashcomp tracecmd/trace-cmd.bash "${PN}"
+
+ use doc && emake DESTDIR="${D}" install_doc
+ use python && python_foreach_impl python_install
+}
+
+python_install() {
+ pushd "${BUILD_DIR}" > /dev/null || die
+
+ emake "${EMAKE_FLAGS[@]}" DESTDIR="${D}" \
+ PYTHON_VERS="${EPYTHON}" \
+ PYTHON_PKGCONFIG_VERS="${EPYTHON//python/python-}" \
+ python_dir=$(python_get_sitedir)/${PN} \
+ install_python
+
+ popd > /dev/null || die
+
+ python_optimize
+}
