commit: 80602ed04b32152f6a047f4307ec13c433178c5a
Author: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 9 17:11:29 2020 +0000
Commit: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Aug 9 20:00:21 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=80602ed0
dev-util/statifier: bump to EAPI=7
Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>
dev-util/statifier/statifier-1.7.4-r1.ebuild | 57 ++++++++++++++++++++++++++++
1 file changed, 57 insertions(+)
diff --git a/dev-util/statifier/statifier-1.7.4-r1.ebuild
b/dev-util/statifier/statifier-1.7.4-r1.ebuild
new file mode 100644
index 00000000000..046c0699da9
--- /dev/null
+++ b/dev-util/statifier/statifier-1.7.4-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MULTILIB_COMPAT=( abi_x86_{32,64} )
+
+inherit multilib-build toolchain-funcs
+
+DESCRIPTION="Statifier is a tool for creating portable, self-containing Linux
executables"
+HOMEPAGE="http://statifier.sourceforge.net";
+SRC_URI="https://sourceforge.net/projects/${PN}/files/${PN}/${PV}/${P}.tar.gz";
+
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+LICENSE="GPL-2"
+
+RDEPEND="
+ app-shells/bash
+ sys-apps/coreutils
+ virtual/awk
+"
+
+PATCHES=(
+ # Respect users CFLAGS and LDFLAGS
+ "${FILESDIR}"/${PN}-1.7.4-fix-build-system.patch
+)
+
+src_prepare() {
+ default
+
+ # Don't compile 32-bit on amd64 no-multilib profile
+ if ! use abi_x86_32; then
+ sed -i -e 's/ELF32 .*/ELF32 := no/g' configs/config.x86_64 ||
die
+ fi
+}
+
+src_configure() {
+ tc-export CC
+
+ # Fix permissions, as configure is not marked executable
+ chmod +x configure || die
+ econf
+}
+
+src_compile() {
+ # Package complains with MAKEOPTS > -j1
+ emake -j1
+}
+
+src_install() {
+ # Package complains with MAKEOPTS > -j1
+ emake -j1 DESTDIR="${ED}" install
+
+ # Install docs
+ einstalldocs
+}
