commit: 1ea529fe5bbba0ef7d50024eec0d452b448ffe5e
Author: Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 13 17:30:13 2020 +0000
Commit: Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Wed Oct 14 14:42:18 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1ea529fe
mail-filter/imapfilter: migrate to lua-single.eclass
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>
.../imapfilter/imapfilter-2.6.16-r100.ebuild | 55 ++++++++++++++++++++++
1 file changed, 55 insertions(+)
diff --git a/mail-filter/imapfilter/imapfilter-2.6.16-r100.ebuild
b/mail-filter/imapfilter/imapfilter-2.6.16-r100.ebuild
new file mode 100644
index 00000000000..8709726d2a4
--- /dev/null
+++ b/mail-filter/imapfilter/imapfilter-2.6.16-r100.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} )
+
+inherit lua-single toolchain-funcs
+
+DESCRIPTION="An IMAP mail filtering utility"
+HOMEPAGE="https://github.com/lefcha/imapfilter";
+SRC_URI="https://github.com/lefcha/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE="libressl"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ dev-libs/libpcre
+ ${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS NEWS README samples/*"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-2.6.16-libressl.patch
+)
+
+src_prepare() {
+ default
+ sed -i -e "/^PREFIX/s:/usr/local:${EPREFIX}/usr:" \
+ -e "/^MANDIR/s:man:share/man:" \
+ -e "/^CFLAGS/s:CFLAGS =:CFLAGS +=:" \
+ -e "/^CFLAGS/s/-O//" \
+ src/Makefile || die
+}
+
+src_compile() {
+ emake \
+ CC="$(tc-getCC)" \
+ LDFLAGS="${LDFLAGS}" \
+ INCDIRS=$(lua_get_CFLAGS) \
+ LIBLUA=$(lua_get_LIBS)
+}
+
+src_install() {
+ default
+ doman doc/imapfilter.1 doc/imapfilter_config.5
+}
