commit: 03b1b7242350d39868cf92e032f69dc3b96c9d15
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 8 14:10:55 2020 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Dec 8 14:12:47 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03b1b724
sys-apps/fwupd: Bump to version 1.5.3
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
sys-apps/fwupd/Manifest | 1 +
sys-apps/fwupd/fwupd-1.5.3.ebuild | 162 ++++++++++++++++++++++++++++++++++++++
2 files changed, 163 insertions(+)
diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index cb7cb3e3215..5e402ac22f6 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -3,3 +3,4 @@ DIST fwupd-1.3.11.tar.gz 2255359 BLAKE2B
0f91c32602459d31e53c63647762307cfe2313c
DIST fwupd-1.4.6.tar.gz 2368201 BLAKE2B
86f4e8a3264b69eb72a357f59db082e81534dc28822934df328b1bf94aacb7ed1a219f8e5a03a9a37a0d07c248410822a3d12c4fd6b5df3a14157795e092a095
SHA512
c456704f40e7c5a5225255dbe3e4b794819d3fa982683a31b15a81f5467f007eef00cd80dac1844eca00ebab9ae12061139ae31c1fd7e2a6e012779d2a4b59f9
DIST fwupd-1.5.1.tar.gz 2398842 BLAKE2B
dce2da9807bc28c502281a75b98b21bab8fc34778ca1ed5e43b944cec2043ced7d3b997402d904eaceeb62d139182b883dfac0f4b6228750b18f8d0c66539d4f
SHA512
57fa13d0c24cf9c8ec5341dca5392e054194861885233284a5a26d7c351ccdaab5a9ac9853681258882d42d21732302324719a709ff7e713885a9977430683ce
DIST fwupd-1.5.2.tar.gz 2416756 BLAKE2B
8b5849c3b1a0758489cdc369dfa85658a3904bb9483484aded4a4f0d3ed39f0fa819171273dabf18c62a0249f09b1058269cdb57eb3c75590242f1ba6b1a0a85
SHA512
1ea7104c95f884ba52194d3136058f685ac1ad6d705930c4bc584aa4b1902164393d8702a14ec4a6af84e8b06d778a4896e63cbe9d3266f20da31d3795fc7ca7
+DIST fwupd-1.5.3.tar.gz 2429886 BLAKE2B
576823f6d235ed9ce2854cd0f44b9a7dd1eace46180ce978f906becaaefabb32e93f86cc672abafc99387427d33e3ab17052e98adfba4b6cbed85c5502a7ec1b
SHA512
0c98dd7ca55afeaa4c895a837fc8d6eafcc51d215cc02be659916c7a39ddaa6bc3752adddba8cd2a9c77a4eca707b6c71522645f2847330c1c2ef44910451bf3
diff --git a/sys-apps/fwupd/fwupd-1.5.3.ebuild
b/sys-apps/fwupd/fwupd-1.5.3.ebuild
new file mode 100644
index 00000000000..4f976f3aff6
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.5.3.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and
reliable"
+HOMEPAGE="https://fwupd.org";
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="agent amt dell gtk-doc elogind flashrom minimal introspection +man nvme
policykit synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ ^^ ( elogind minimal systemd )
+ dell? ( uefi )
+ minimal? ( !introspection )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gtk-doc )
+ introspection? ( dev-libs/gobject-introspection )
+ man? (
+ app-text/docbook-sgml-utils
+ sys-apps/help2man
+ )
+ test? (
+ thunderbolt? ( dev-util/umockdev )
+ net-libs/gnutls[tools]
+ )
+"
+CDEPEND="${PYTHON_DEPS}
+ >=app-arch/gcab-1.0
+ app-arch/libarchive:=
+ dev-db/sqlite
+ >=dev-libs/glib-2.45.8:2
+ dev-libs/json-glib
+ dev-libs/libgpg-error
+ dev-libs/libgudev:=
+ >=dev-libs/libgusb-0.3.5[introspection?]
+ >=dev-libs/libjcat-0.1.0[gpg,pkcs7]
+ >=dev-libs/libxmlb-0.1.13:=
+ $(python_gen_cond_dep '
+ dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+ dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+ dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+ ')
+ >=net-libs/libsoup-2.51.92:2.4[introspection?]
+ net-misc/curl
+ virtual/libelf:0=
+ virtual/udev
+ dell? (
+ >=sys-libs/libsmbios-2.4.0
+ )
+ elogind? ( >=sys-auth/elogind-211 )
+ flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+ policykit? (
+ >=sys-auth/polkit-0.103
+ )
+ systemd? ( >=sys-apps/systemd-211 )
+ tpm? ( app-crypt/tpm2-tss )
+ uefi? (
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-boot/gnu-efi
+ sys-boot/efibootmgr
+ sys-libs/efivar
+ x11-libs/cairo
+ )
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+ !<sci-chemistry/chemical-mime-data-0.1.94-r4
+ ${CDEPEND}
+ sys-apps/dbus
+"
+
+DEPEND="
+ ${CDEPEND}
+ x11-libs/pango[introspection]
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-1.3.9-logind_plugin.patch"
+)
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+ if use nvme; then
+ kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+ fi
+}
+
+src_prepare() {
+ default
+ # c.f. https://github.com/fwupd/fwupd/issues/1414
+ sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout :
120)/d" \
+ -i plugins/thunderbolt/meson.build || die
+ sed '/platform-integrity/d' \
+ -i plugins/meson.build || die #753521
+ vala_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ --localstatedir "${EPREFIX}"/var
+ -Dbuild="$(usex minimal standalone all)"
+ $(meson_use agent)
+ $(meson_use amt plugin_amt)
+ $(meson_use dell plugin_dell)
+ $(meson_use elogind)
+ $(meson_use flashrom plugin_flashrom)
+ $(meson_use gtk-doc gtkdoc)
+ $(meson_use man)
+ $(meson_use nvme plugin_nvme)
+ $(meson_use introspection)
+ $(meson_use policykit polkit)
+ $(meson_use synaptics plugin_synaptics)
+ $(meson_use systemd)
+ $(meson_use test tests)
+ $(meson_use thunderbolt plugin_thunderbolt)
+ $(meson_use tpm)
+ $(meson_use uefi plugin_uefi)
+ # Dependencies are not available (yet?)
+ -Dplugin_modem_manager="false"
+ -Dconsolekit="false"
+ )
+ use ppc64 && emesonargs+=( -Dplugin_msr="false" )
+ export CACHE_DIRECTORY="${T}"
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ if ! use minimal ; then
+ sed "s@%SEAT_MANAGER%@elogind@" \
+ "${FILESDIR}"/${PN}-r1 \
+ > "${T}"/${PN} || die
+ doinitd "${T}"/${PN}
+
+ if ! use systemd ; then
+ # Don't timeout when fwupd is running (#673140)
+ sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+ -i "${ED}"/etc/${PN}/daemon.conf || die
+ fi
+ fi
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ elog "In case you are using openrc as init system"
+ elog "and you're upgrading from <fwupd-1.1.0, you"
+ elog "need to start the fwupd daemon via the openrc"
+ elog "init script that comes with this package."
+}
