commit: e770c22c50b2738c42adbd8a503135d5915f6f52
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 13 21:51:41 2021 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Apr 13 21:53:46 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e770c22c
sys-apps/fwupd: Bump to versions 1.4.8 and 1.5.9
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
sys-apps/fwupd/Manifest | 2 +
sys-apps/fwupd/fwupd-1.4.8.ebuild | 164 ++++++++++++++++++++++++++++++++++++
sys-apps/fwupd/fwupd-1.5.9.ebuild | 170 ++++++++++++++++++++++++++++++++++++++
3 files changed, 336 insertions(+)
diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index ada275e21ff..f3539abb944 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,4 +1,6 @@
DIST fwupd-1.4.6.tar.gz 2368201 BLAKE2B
86f4e8a3264b69eb72a357f59db082e81534dc28822934df328b1bf94aacb7ed1a219f8e5a03a9a37a0d07c248410822a3d12c4fd6b5df3a14157795e092a095
SHA512
c456704f40e7c5a5225255dbe3e4b794819d3fa982683a31b15a81f5467f007eef00cd80dac1844eca00ebab9ae12061139ae31c1fd7e2a6e012779d2a4b59f9
DIST fwupd-1.4.7.tar.gz 2370660 BLAKE2B
8f04ced69610278576e41c12c7c51e326bdfbea8e1470ae586795b0c20f6a5fd4385701583195f49e14d749016987a7e02fb0d071b5315cca635f69d99bb63d6
SHA512
9d293adf6e9eba9537c4be9b7a4ccc26cd5519843f1bf94557148fabef8076e4846f7018949d8ad83afd01ce4874833bf8984c2ee3981fc6b1309ebda8e313f9
+DIST fwupd-1.4.8.tar.gz 2375361 BLAKE2B
14951c8ec7d59ec53fed7b98bf0e277a7544f04f72f6a827971d45f9996190ebd46767e373850b269d8d718ec8c2b9df41bdd44614e5065832bd21c4071f012a
SHA512
25c49f5a814aaf5cd614074936f6a222c513a0e74446a48ddc19aa51fc3d3e9e79dfa77e9b80055a4e3755bca99f13d260c2e4ddf6853ba0a583162523fe7d47
DIST fwupd-1.5.7.tar.gz 2498618 BLAKE2B
ff0bf4d07a7df84232e90f5c85321dde3e08edd12f5ebf7a48130f076a52344e8654232bd0227d992fa5efbb3ce03e353da8b1511a9f39e5eab07c888b499463
SHA512
340a114123bd31a7a31370faaaa10e6517316d8f9c2b06f22d8b70bef64b7e6d9427682b8ceeea05570c8960eb7854ed5fc91aa450ff53d114fb97be43065213
DIST fwupd-1.5.8.tar.gz 3708769 BLAKE2B
e18738d5f681fd9016a609ce9d48e452628c32e731b2a1f3635ff4897ff2a910b1ca0d7836bd12f14b27254c23eb2b6d74a2c35939ac5c8484e2050ab89a33a3
SHA512
d4fecd13a223e7f544026a5ac684bd570af2b63fb509a21e98ef72ccc4d7818f32abf730e2a40943bc762f04ecd5af03bf71201518d55090bb95fe6e9dc6969e
+DIST fwupd-1.5.9.tar.gz 3712637 BLAKE2B
17429bdc3073a92b94de9bc67ce1955e928e8d6aeefa5f0ad39a9d15457f96c562ce5cfbc47e1fc450c31c2b9334ca3902ed63ef809e8d2cb5b5459cc54dec28
SHA512
ccd1246ab5b3c876251924a14d1c2c553b2df5702c6673978b1d627ea1028c3950241f73dd54e2fecb5cc204a1dc77e6597f7514eff6467beb50be7874352d78
diff --git a/sys-apps/fwupd/fwupd-1.4.8.ebuild
b/sys-apps/fwupd/fwupd-1.4.8.ebuild
new file mode 100644
index 00000000000..3ec65898041
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.4.8.ebuild
@@ -0,0 +1,164 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and
reliable"
+HOMEPAGE="https://fwupd.org";
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="agent amt dell gtk-doc elogind minimal introspection +man nvme redfish
synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ ^^ ( elogind minimal systemd )
+ dell? ( uefi )
+ minimal? ( !introspection )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gtk-doc )
+ introspection? ( dev-libs/gobject-introspection )
+ man? (
+ app-text/docbook-sgml-utils
+ sys-apps/help2man
+ )
+ test? (
+ net-libs/gnutls[tools]
+ thunderbolt? ( dev-util/umockdev )
+ )
+"
+CDEPEND="${PYTHON_DEPS}
+ >=app-arch/gcab-1.0
+ app-arch/libarchive:=
+ dev-db/sqlite
+ >=dev-libs/glib-2.45.8:2
+ dev-libs/json-glib
+ dev-libs/libgpg-error
+ dev-libs/libgudev:=
+ >=dev-libs/libgusb-0.2.9[introspection?]
+ >=dev-libs/libjcat-0.1.0[gpg,pkcs7]
+ >=dev-libs/libxmlb-0.1.13:=
+ $(python_gen_cond_dep '
+ dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+ dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+ dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+ ')
+ >=net-libs/libsoup-2.51.92:2.4[introspection?]
+ virtual/libelf:0=
+ virtual/udev
+ dell? (
+ sys-libs/efivar
+ >=sys-libs/libsmbios-2.4.0
+ )
+ elogind? ( sys-auth/elogind )
+ !minimal? (
+ >=sys-auth/polkit-0.103
+ )
+ nvme? ( sys-libs/efivar )
+ redfish? ( sys-libs/efivar )
+ systemd? ( >=sys-apps/systemd-211 )
+ tpm? ( app-crypt/tpm2-tss )
+ uefi? (
+ app-crypt/tpm2-tss
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-boot/gnu-efi
+ sys-boot/efibootmgr
+ >=sys-libs/efivar-33
+ x11-libs/cairo
+ )
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+ !<sci-chemistry/chemical-mime-data-0.1.94-r4
+ ${CDEPEND}
+ sys-apps/dbus
+"
+
+DEPEND="
+ ${CDEPEND}
+ x11-libs/pango[introspection]
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-1.3.9-logind_plugin.patch"
+ "${FILESDIR}/${PN}-1.4.4-help2man_var.patch" #728484
+)
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+ if use nvme; then
+ kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+ fi
+}
+
+src_prepare() {
+ default
+ # c.f. https://github.com/fwupd/fwupd/issues/1414
+ sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout :
120)/d" \
+ -i plugins/thunderbolt/meson.build || die
+ vala_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ --localstatedir "${EPREFIX}"/var
+ -Dbuild="$(usex minimal standalone all)"
+ $(meson_use agent)
+ $(meson_use amt plugin_amt)
+ $(meson_use dell plugin_dell)
+ $(meson_use elogind)
+ $(meson_use gtk-doc gtkdoc)
+ $(meson_use man)
+ $(meson_use nvme plugin_nvme)
+ $(meson_use introspection)
+ $(meson_use redfish plugin_redfish)
+ $(meson_use synaptics plugin_synaptics)
+ $(meson_use systemd)
+ $(meson_use test tests)
+ $(meson_use thunderbolt plugin_thunderbolt)
+ $(meson_use tpm plugin_tpm)
+ $(meson_use uefi plugin_uefi)
+ # Although our sys-apps/flashrom package now provides
+ # libflashrom.a, meson still can't find it
+ -Dplugin_flashrom="false"
+ # Dependencies are not available (yet?)
+ -Dplugin_modem_manager="false"
+ -Dconsolekit="false"
+ )
+ export CACHE_DIRECTORY="${T}"
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ if ! use minimal ; then
+ sed "s@%SEAT_MANAGER%@elogind@" \
+ "${FILESDIR}"/${PN}-r2 \
+ > "${T}"/${PN} || die
+ doinitd "${T}"/${PN}
+
+ if ! use systemd ; then
+ # Don't timeout when fwupd is running (#673140)
+ sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+ -i "${ED}"/etc/${PN}/daemon.conf || die
+ fi
+ fi
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ elog "In case you are using openrc as init system"
+ elog "and you're upgrading from <fwupd-1.1.0, you"
+ elog "need to start the fwupd daemon via the openrc"
+ elog "init script that comes with this package."
+}
diff --git a/sys-apps/fwupd/fwupd-1.5.9.ebuild
b/sys-apps/fwupd/fwupd-1.5.9.ebuild
new file mode 100644
index 00000000000..5e5f2c55a63
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.5.9.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and
reliable"
+HOMEPAGE="https://fwupd.org";
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="agent amt archive bluetooth dell gnutls gtk-doc gusb elogind flashrom
minimal introspection +man nvme policykit synaptics systemd test thunderbolt
tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ ^^ ( elogind minimal systemd )
+ dell? ( uefi )
+ minimal? ( !introspection )
+ uefi? ( gnutls )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gtk-doc )
+ introspection? ( dev-libs/gobject-introspection )
+ man? (
+ app-text/docbook-sgml-utils
+ sys-apps/help2man
+ )
+ test? (
+ thunderbolt? ( dev-util/umockdev )
+ net-libs/gnutls[tools]
+ )
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+ >=app-arch/gcab-1.0
+ dev-db/sqlite
+ >=dev-libs/glib-2.45.8:2
+ dev-libs/json-glib
+ dev-libs/libgpg-error
+ dev-libs/libgudev:=
+ >=dev-libs/libjcat-0.1.0[gpg,pkcs7]
+ >=dev-libs/libxmlb-0.1.13:=
+ $(python_gen_cond_dep '
+ dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+ dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+ dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+ ')
+ >=net-libs/libsoup-2.51.92:2.4[introspection?]
+ net-misc/curl
+ virtual/libelf:0=
+ virtual/udev
+ archive? ( app-arch/libarchive:= )
+ dell? ( >=sys-libs/libsmbios-2.4.0 )
+ elogind? ( >=sys-auth/elogind-211 )
+ flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+ gnutls? ( net-libs/gnutls )
+ gusb? ( >=dev-libs/libgusb-0.3.5[introspection?] )
+ policykit? ( >=sys-auth/polkit-0.103 )
+ systemd? ( >=sys-apps/systemd-211 )
+ tpm? ( app-crypt/tpm2-tss )
+ uefi? (
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-boot/gnu-efi
+ sys-boot/efibootmgr
+ sys-fs/udisks
+ sys-libs/efivar
+ x11-libs/cairo
+ )
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+ !<sci-chemistry/chemical-mime-data-0.1.94-r4
+ ${COMMON_DEPEND}
+ sys-apps/dbus
+"
+
+DEPEND="
+ ${COMMON_DEPEND}
+ x11-libs/pango[introspection]
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-1.5.7-logind_plugin.patch"
+)
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+ if use nvme ; then
+ kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+ fi
+}
+
+src_prepare() {
+ default
+ # c.f. https://github.com/fwupd/fwupd/issues/1414
+ sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout :
120)/d" \
+ -i plugins/thunderbolt/meson.build || die
+ sed '/platform-integrity/d' \
+ -i plugins/meson.build || die #753521
+ vala_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ --localstatedir "${EPREFIX}"/var
+ -Dbuild="$(usex minimal standalone all)"
+ $(meson_use agent)
+ $(meson_use amt plugin_amt)
+ $(meson_use archive libarchive)
+ $(meson_use bluetooth bluez)
+ $(meson_use dell plugin_dell)
+ $(meson_use elogind)
+ $(meson_use flashrom plugin_flashrom)
+ $(meson_use gnutls)
+ $(meson_use gtk-doc gtkdoc)
+ $(meson_use gusb)
+ $(meson_use gusb plugin_altos)
+ $(meson_use man)
+ $(meson_use nvme plugin_nvme)
+ $(meson_use introspection)
+ $(meson_use policykit polkit)
+ $(meson_use synaptics plugin_synaptics_mst)
+ $(meson_use synaptics plugin_synaptics_rmi)
+ $(meson_use systemd)
+ $(meson_use test tests)
+ $(meson_use thunderbolt plugin_thunderbolt)
+ $(meson_use tpm plugin_tpm)
+ $(meson_use uefi plugin_uefi_capsule)
+ $(meson_use uefi plugin_uefi_pk)
+ -Dconsolekit="false"
+ -Dcurl="true"
+ # Dependencies are not available (yet?)
+ -Dplugin_modem_manager="false"
+ )
+ use ppc64 && emesonargs+=( -Dplugin_msr="false" )
+ use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
+ export CACHE_DIRECTORY="${T}"
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ if ! use minimal ; then
+ sed "s@%SEAT_MANAGER%@elogind@" \
+ "${FILESDIR}"/${PN}-r2 \
+ > "${T}"/${PN} || die
+ doinitd "${T}"/${PN}
+
+ if ! use systemd ; then
+ # Don't timeout when fwupd is running (#673140)
+ sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+ -i "${ED}"/etc/${PN}/daemon.conf || die
+ fi
+ fi
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ elog "In case you are using openrc as init system"
+ elog "and you're upgrading from <fwupd-1.1.0, you"
+ elog "need to start the fwupd daemon via the openrc"
+ elog "init script that comes with this package."
+}
