commit: 4435adc512c3d77a39b948ef86f89d78b7738239
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 16 22:55:23 2021 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Apr 17 01:20:46 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4435adc5
dev-libs/folks: Version bump to 0.15.2
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-libs/folks/Manifest | 1 +
dev-libs/folks/folks-0.15.2.ebuild | 88 ++++++++++++++++++++++++++++++++++++++
2 files changed, 89 insertions(+)
diff --git a/dev-libs/folks/Manifest b/dev-libs/folks/Manifest
index 9e39ef6f57f..3fb904cc6d1 100644
--- a/dev-libs/folks/Manifest
+++ b/dev-libs/folks/Manifest
@@ -1 +1,2 @@
DIST folks-0.14.0.tar.xz 520924 BLAKE2B
3154e0a7e6fe8c60aa81f4772af2b9d09b88785187c87e93869f668af46549383866cfa2e50d3d29009d0acb77c26cd852c7c9a3c6188ff3e5ef53c06b11b781
SHA512
94dc025668ac34df203ea351430bf82dddb4e275d936e2b959a1b9a4cf0fff0218a4baa7d3a89c152a2cb21a94250d731c8e7470d50ac4b658fbe1448974a69e
+DIST folks-0.15.2.tar.xz 489236 BLAKE2B
63bcfedb88205b37c6e9595c3e0c34f7fc869045648e04042cce9300776e4b7d102f91312434545581882f0959502be7ba1bc2f77d50ec2af7f649444da9197d
SHA512
c327e39b7cf32b72db3f84504f8ec2a4bc2d98693ca5ff21c3b544e37b58a1df9241dd1be541a39be83468b62dd0f5d7b5a3a0ca4bde5e94d1e075d77d3be505
diff --git a/dev-libs/folks/folks-0.15.2.ebuild
b/dev-libs/folks/folks-0.15.2.ebuild
new file mode 100644
index 00000000000..1bd8463e3fd
--- /dev/null
+++ b/dev-libs/folks/folks-0.15.2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+VALA_MAX_API_VERSION="0.48"
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Library for aggregating people from multiple sources"
+HOMEPAGE="https://wiki.gnome.org/Projects/Folks";
+
+LICENSE="LGPL-2.1+"
+SLOT="0/26" # subslot = libfolks soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+
+IUSE="bluetooth eds +telepathy test utils"
+REQUIRED_USE="bluetooth? ( eds )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+ >=dev-libs/glib-2.58:2
+ >=dev-libs/libgee-0.10:0.8[introspection]
+ >=dev-libs/gobject-introspection-1.54:=
+ telepathy? (
+ >=net-libs/telepathy-glib-0.19.9
+ dev-libs/dbus-glib
+ )
+ eds? ( >=gnome-extra/evolution-data-server-3.38:= )
+ dev-libs/libxml2:2
+ utils? ( sys-libs/readline:0= )
+"
+# telepathy-mission-control needed at runtime; it is used by the telepathy
+# backend via telepathy-glib's AccountManager binding.
+RDEPEND="${DEPEND}
+ bluetooth? ( >=net-wireless/bluez-5[obex] )
+ telepathy? ( net-im/telepathy-mission-control )
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ $(vala_depend)
+ telepathy? ( net-libs/telepathy-glib[vala] )
+ eds? ( gnome-extra/evolution-data-server[vala] )
+ test? (
+ sys-apps/dbus
+ bluetooth? ( $(python_gen_any_dep
'dev-python/dbusmock[${PYTHON_USEDEP}]') )
+ )
+"
+
+python_check_deps() {
+ if use test && use bluetooth; then
+ has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+ fi
+}
+
+src_prepare() {
+ vala_src_prepare
+ xdg_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use bluetooth bluez_backend)
+ $(meson_use eds eds_backend)
+ $(meson_use eds ofono_backend)
+ $(meson_use telepathy telepathy_backend)
+ -Dzeitgeist=false # last rited package
+ -Dimport_tool=true
+ $(meson_use utils inspect_tool)
+ $(meson_use test tests)
+ -Dinstalled_tests=false
+ -Ddocs=false # Needs find_program sedding to specific version;
only dev docs, don't bother
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
