[gentoo-commits] repo/gentoo:master commit in: dev-python/scikit-build/

[Michał Górny]

commit:     4220e645f59b7009682feba2c4299724037803fe
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 11 05:19:34 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Aug 11 05:22:59 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4220e645

dev-python/scikit-build: Bump to 0.12.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/scikit-build/Manifest                   |  1 +
 dev-python/scikit-build/scikit-build-0.12.0.ebuild | 53 ++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-python/scikit-build/Manifest b/dev-python/scikit-build/Manifest
index 2670eba2759..9180ab42c1d 100644
--- a/dev-python/scikit-build/Manifest
+++ b/dev-python/scikit-build/Manifest
@@ -1 +1,2 @@
 DIST scikit-build-0.11.1.tar.gz 132025 BLAKE2B 
0f818d8da896695ee0d6b046249e74cbd4ea643bec0515d6ac6ff4276d92430a1dbf81abb3b7c10890538c373225a45cc21b0906de891f1a5390226be914dacd
 SHA512 
030c6cc727d39cbafd2865722de9c45ba2f13461461cf75019b9caf6afd0a776b4f598fa2ce102b5adbc770140ab1de2c33e2bbd3ef03c958ae8849e5fc26cb4
+DIST scikit-build-0.12.0.tar.gz 138053 BLAKE2B 
5007bd070cee14056cbc9cc24a022a39c920ce7fa794a79dcdb707f185529e1ed2442a201593f6df8d2dd9b4ab7a9a1ed209b0bc08f3feae748edd06894f8661
 SHA512 
76be92d8ff96dc230e38dc36a58021399dd8c57b6883dc032fbcd8f01ce42c879c6d557e7a46d48aa9b8bc724270f409f3760824d5810654b53a1aca25ec1cf9

diff --git a/dev-python/scikit-build/scikit-build-0.12.0.ebuild 
b/dev-python/scikit-build/scikit-build-0.12.0.ebuild
new file mode 100644
index 00000000000..18279621e56
--- /dev/null
+++ b/dev-python/scikit-build/scikit-build-0.12.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Improved build system generator for Python C/C++/Fortran/Cython 
extensions"
+HOMEPAGE="https://github.com/scikit-build/scikit-build";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+       dev-python/distro[${PYTHON_USEDEP}]
+       dev-python/packaging[${PYTHON_USEDEP}]
+       dev-python/wheel[${PYTHON_USEDEP}]"
+
+DEPEND="
+       test? (
+               dev-python/cython[${PYTHON_USEDEP}]
+               dev-python/path-py[${PYTHON_USEDEP}]
+               dev-python/pytest-mock[${PYTHON_USEDEP}]
+               dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+               dev-python/requests[${PYTHON_USEDEP}]
+               dev-python/six[${PYTHON_USEDEP}]
+               dev-python/virtualenv[${PYTHON_USEDEP}]
+       )"
+
+distutils_enable_sphinx docs \
+       dev-python/sphinx_rtd_theme \
+       dev-python/sphinx-issues
+distutils_enable_tests pytest
+
+src_prepare() {
+       # not packaged
+       sed -i -e '/cmakedomain/d' docs/conf.py || die
+       distutils-r1_src_prepare
+}
+
+python_test() {
+       local deselect=(
+               # sandbox violations
+               tests/test_hello_cpp.py::test_hello_develop
+               tests/test_issue274_support_default_package_dir.py
+               tests/test_issue274_support_one_package_without_package_dir.py
+               tests/test_issue334_configure_cmakelists_non_cp1252_encoding.py
+       )
+       epytest ${deselect[@]/#/--deselect }
+}