commit: 0c9510be859b254a93da1dff7682c7f3d62bdb7e
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 1 06:35:32 2021 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Oct 1 06:43:56 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c9510be
kde-plasma/plasma-firewall: 5.22.90 version bump
Package-Manager: Portage-3.0.26, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
kde-plasma/plasma-firewall/Manifest | 1 +
.../plasma-firewall/plasma-firewall-5.22.90.ebuild | 64 ++++++++++++++++++++++
2 files changed, 65 insertions(+)
diff --git a/kde-plasma/plasma-firewall/Manifest
b/kde-plasma/plasma-firewall/Manifest
index 010e1f1629f..92bae30365b 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1 +1,2 @@
DIST plasma-firewall-5.22.5.tar.xz 339372 BLAKE2B
332a7fd2be63429c452f43371b2875f8838e05b107a6c3472974c5db123eef9e415ec70601cb830a743d77422639225e01611e52c07a2b3fe079572278e2f638
SHA512
cc81884550b5c73061f5a1df24c0b32e5fff234a51e56153e95a9e4b0e23c305a555c2deff69633b9cd21dff7bfbcf5d9fcbd5ab3605d4ffa87be57514a91901
+DIST plasma-firewall-5.22.90.tar.xz 342912 BLAKE2B
1dc1423c44b356d37de654d2e1a950a1e20ce01867273b5797f2b85914e39515f6f6a947b0d4e5cd83f041a9cd31a0487eadcf0fe06cb503a6f7ffb0843dc0a1
SHA512
9f4b3142e93472e6926cac394f7710cebba547b951ebefeb3ad33292c5910c66fc4406b0401f007e178ef02c9b0af57841b503949e29f4e93c8be640587ba2eb
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.22.90.ebuild
b/kde-plasma/plasma-firewall/plasma-firewall-5.22.90.ebuild
new file mode 100644
index 00000000000..dfd7cff0454
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.22.90.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.86.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall";
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5
+ >=dev-qt/qtx11extras-${QTMIN}:5
+ >=dev-qt/qtxml-${QTMIN}:5
+ >=kde-frameworks/kauth-${KFMIN}:5
+ >=kde-frameworks/kcmutils-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kdeclarative-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+ ${PYTHON_DEPS}
+ firewalld? ( net-firewall/firewalld )
+ ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+ ecm_src_prepare
+ # this kind of cmake magic doesn't work for us at all.
+ sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+ -i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+ -DBUILD_UFW_BACKEND=$(usex ufw)
+ )
+ ecm_src_configure
+}
+
+pkg_postinst () {
+ ecm_pkg_postinst
+
+ if ! has_version sys-apps/systemd; then
+ ewarn "${PN} is not functional without sys-apps/systemd at this
point."
+ ewarn "See also: https://bugs.gentoo.org/778527";
+ fi
+}
