commit: de865ac40e1186e05ef225cc726ef3168c29e903
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 6 06:14:19 2021 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct 6 07:16:01 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de865ac4
dev-python/flask: Bump to 2.0.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/flask/Manifest | 1 +
dev-python/flask/flask-2.0.2.ebuild | 58 +++++++++++++++++++++++++++++++++++++
2 files changed, 59 insertions(+)
diff --git a/dev-python/flask/Manifest b/dev-python/flask/Manifest
index b4b785b2121..c0896d22ffe 100644
--- a/dev-python/flask/Manifest
+++ b/dev-python/flask/Manifest
@@ -1,2 +1,3 @@
DIST Flask-1.1.4.tar.gz 635920 BLAKE2B
c1f19e7449177ecf6e901d5932ad25cbe866ff53b9323f717541922b1ea5b10203ff07630fcf3eabaedd9b6a24ef031ad2aaa2e2f759925363bebfa7e5d967da
SHA512
6f427a1264921b8560446afacee2757d16de0dc22d6ed249b7bc5d6f50f3af50c89b79ce900d75b41af4befc53910f2b532c2e280de42837e2133acb6b1bd80d
DIST Flask-2.0.1.tar.gz 626851 BLAKE2B
05273edacd6d66237a552410df7ef7ff367e28c273cc89f654eac5ed2eb3d26f71437169905372b398cc6c5c5067dcbea54aa1cab782e03c6186ac9ae3949f4c
SHA512
fefed4971f0542b25ba2867919aa54a83b6e3f47e7cee94586543843e7e00ba209ac15d8fe28a3c53981f587aebcf2f3915a49e1a9cd1b729099dccbed3783c2
+DIST Flask-2.0.2.tar.gz 628479 BLAKE2B
13555ce0602e685b5fe29ba51e05534263d70440c56c9096e95e0893e010d877154d3d1db1bff47209e6b70e91612a71e8aed149a067465f9e3a11486d843a86
SHA512
341be4e453dd5f682e465af356ff85ffe76f52a62e529e6cd251f95199e73b0f93414af093f899f61721e9bb351f09972a433a55beacc972b5e577b86e003081
diff --git a/dev-python/flask/flask-2.0.2.ebuild
b/dev-python/flask/flask-2.0.2.ebuild
new file mode 100644
index 00000000000..0d065b5c197
--- /dev/null
+++ b/dev-python/flask/flask-2.0.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="https://github.com/pallets/flask/";
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+if [[ ${PV} == *9999* ]]; then
+ EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git";
+ inherit git-r3
+else
+ SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~x86"
+ S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/click-7.1.2[${PYTHON_USEDEP}]
+ dev-python/blinker[${PYTHON_USEDEP}]
+ >=dev-python/itsdangerous-2.0[${PYTHON_USEDEP}]
+ >=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+ >=dev-python/werkzeug-2.0[${PYTHON_USEDEP}]"
+BDEPEND="
+ test? (
+ >=dev-python/asgiref-3.2[${PYTHON_USEDEP}]
+ )"
+
+distutils_enable_sphinx docs \
+ dev-python/pallets-sphinx-themes \
+ dev-python/sphinx-issues \
+ dev-python/sphinx-tabs \
+ dev-python/sphinxcontrib-log_cabinet
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=()
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ # https://github.com/pallets/flask/issues/4292
+ # (test xfailed in newer version)
+ tests/test_cli.py::test_lazy_load_error
+ )
+
+ epytest -p no:httpbin
+}
+
+python_install_all() {
+ use examples && dodoc -r examples
+ distutils-r1_python_install_all
+}
