[gentoo-commits] repo/gentoo:master commit in: sys-libs/pam_wrapper/

[Sam James]

commit:     cdd0363be9f629c0d0527e0e4d4994117eca9230
Author:     Marco Scardovi <marco <AT> scardovi <DOT> com>
AuthorDate: Mon Jul  5 20:00:23 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Oct 20 03:26:07 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cdd0363b

sys-libs/pam_wrapper: merge fprintd and pam_wrapper

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Marco Scardovi <marco <AT> scardovi.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-libs/pam_wrapper/pam_wrapper-1.1.3-r1.ebuild | 60 ++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/sys-libs/pam_wrapper/pam_wrapper-1.1.3-r1.ebuild 
b/sys-libs/pam_wrapper/pam_wrapper-1.1.3-r1.ebuild
new file mode 100644
index 00000000000..a95f837c4bb
--- /dev/null
+++ b/sys-libs/pam_wrapper/pam_wrapper-1.1.3-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+CMAKE_ECLASS=cmake
+
+inherit cmake-multilib python-r1
+
+DESCRIPTION="A tool to test PAM applications and PAM modules"
+HOMEPAGE="https://cwrap.org/pam_wrapper.html";
+SRC_URI="
+       https://www.samba.org/ftp/pub/cwrap/${P}.tar.gz
+       https://ftp.samba.org/pub/cwrap/${P}.tar.gz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+       ${PYTHON_DEPS}
+       sys-libs/pam:0=[${MULTILIB_USEDEP}]
+"
+
+DEPEND="
+       ${RDEPEND}
+       test? ( dev-util/cmocka[${MULTILIB_USEDEP}] )
+"
+
+multilib_src_configure() {
+       configure_for_python() {
+               local libpam="${EPREFIX}"
+               multilib_is_native_abi || libpam+="/usr"
+               libpam+="/$(get_libdir)/libpam.so.0"
+
+               local mycmakeargs=(
+                       -DPAM_LIBRARY="${libpam}"
+                       -DUNIT_TESTING=$(usex test)
+                       -DPYTHON2_LIBRARY="/dev/null" # Disabled
+                       -DPYTHON3_INCLUDE_DIR="$(python_get_includedir)"
+                       -DPYTHON3_SITELIB="$(python_get_sitedir)"
+               )
+               cmake_src_configure
+       }
+       python_foreach_impl configure_for_python
+}
+
+multilib_src_compile() {
+       python_foreach_impl cmake_src_compile
+}
+
+multilib_src_install() {
+       python_foreach_impl cmake_src_install
+}