[gentoo-commits] repo/gentoo:master commit in: dev-python/ruamel-yaml/

[Michał Górny]

commit:     d65f2478d7e150da55478970413dd4b22caed465
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Nov  1 07:21:28 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Nov  1 08:32:02 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d65f2478

dev-python/ruamel-yaml: Bump to 0.17.17

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/ruamel-yaml/Manifest                   |  1 +
 dev-python/ruamel-yaml/ruamel-yaml-0.17.17.ebuild | 47 +++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/dev-python/ruamel-yaml/Manifest b/dev-python/ruamel-yaml/Manifest
index 436be85cfdc..e594df7f047 100644
--- a/dev-python/ruamel-yaml/Manifest
+++ b/dev-python/ruamel-yaml/Manifest
@@ -1 +1,2 @@
 DIST ruamel.yaml-0.17.16.tar.xz 183884 BLAKE2B 
3f7b0995cfa49ed9e19b5dafbddc7514f58ab23186410b4a718027112be471d9136675259800e0136b21ad6d1645c364f14ac071dc10d12a5f60aefdc05bc56f
 SHA512 
7da1e5c229b78ecdccd648fb6a734095c0a1e0848eaf46af93e6ce69f5e065cdd07eb65217f8b3e4c82ce383dc11de07a1345026c6782aa26c4ad0f5a85fd80f
+DIST ruamel.yaml-0.17.17.tar.xz 184120 BLAKE2B 
05bd1dd719677918a49798f377c5e52bd1b8c7e3bd38a416626330baec90f3e7a71509f236151be73b1773e48ae02d25ac01ef970ebe6cf15ccca49a01a996d1
 SHA512 
72fbdda33c193dfb556367d79b50e148d2aecd4f2b04cf5b48f2dcf4b690e0796b40273995badec655891408bb8ba6a7e84992e6911e55e75ab453403da3397f

diff --git a/dev-python/ruamel-yaml/ruamel-yaml-0.17.17.ebuild 
b/dev-python/ruamel-yaml/ruamel-yaml-0.17.17.ebuild
new file mode 100644
index 00000000000..f87789872e5
--- /dev/null
+++ b/dev-python/ruamel-yaml/ruamel-yaml-0.17.17.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+inherit distutils-r1
+
+MY_P="${P/-/.}"
+DESCRIPTION="YAML parser/emitter that supports roundtrip comment preservation"
+HOMEPAGE="
+       https://pypi.org/project/ruamel.yaml/
+       https://sourceforge.net/p/ruamel-yaml/";
+# PyPI tarballs do not include tests
+SRC_URI="mirror://sourceforge/ruamel-dl-tagged-releases/${MY_P}.tar.xz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+       dev-python/namespace-ruamel[${PYTHON_USEDEP}]
+       dev-python/ruamel-yaml-clib[${PYTHON_USEDEP}]"
+BDEPEND="
+       test? (
+               dev-python/ruamel-std-pathlib[${PYTHON_USEDEP}]
+       )"
+
+distutils_enable_tests pytest
+
+# Old PyYAML tests from lib/ require special set-up and are invoked indirectly
+# via test_z_olddata, tell pytest itself to leave the subdir alone.
+python_test() {
+       local deselect=()
+
+       [[ ${EPYTHON} == pypy3 ]] && deselect+=(
+               _test/test_deprecation.py::test_collections_deprecation
+       )
+
+       epytest --ignore _test/lib/ ${deselect[@]/#/--deselect }
+}
+
+python_install() {
+       distutils-r1_python_install --single-version-externally-managed
+       find "${ED}" -name '*.pth' -delete || die
+}