[gentoo-commits] repo/gentoo:master commit in: media-video/unifi-video/

[Ben Kohler]

commit:     1aef8a06d8be597d39ea0c2e0e63ad93f4a7d303
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 16 12:52:02 2021 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Thu Dec 16 12:52:55 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1aef8a06

media-video/unifi-video: revbump for log4j "fix"

Upstream community forums suggested this fix

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 .../unifi-video/unifi-video-3.10.13-r5.ebuild      | 92 ++++++++++++++++++++++
 1 file changed, 92 insertions(+)

diff --git a/media-video/unifi-video/unifi-video-3.10.13-r5.ebuild 
b/media-video/unifi-video/unifi-video-3.10.13-r5.ebuild
new file mode 100644
index 000000000000..09f2a37096a3
--- /dev/null
+++ b/media-video/unifi-video/unifi-video-3.10.13-r5.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+MY_PV="${PV/_beta/-beta.}"
+DESCRIPTION="UniFi Video Server"
+HOMEPAGE="https://www.ubnt.com/download/unifi-video/";
+SRC_URI="https://dl.ubnt.com/firmwares/ufv/v${MY_PV}/unifi-video.Ubuntu18.04_amd64.v${MY_PV}.deb";
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+RESTRICT="mirror"
+
+DEPEND="acct-group/unifi-video
+       acct-user/unifi-video
+       app-arch/zip"
+RDEPEND="${DEPEND}
+       dev-db/mongodb
+       dev-java/commons-daemon
+       sys-apps/lsb-release
+       sys-apps/util-linux
+       sys-libs/libcap
+       virtual/jre:1.8"
+
+S=${WORKDIR}
+QA_PREBUILT="usr/lib*/${PN}/lib/*.so usr/lib*/${PN}/bin/*"
+
+src_unpack() {
+       default
+       unpack "${WORKDIR}"/data.tar.gz
+}
+
+src_prepare() {
+       eapply "${FILESDIR}"/commons-daemon-move.patch
+       sed -i usr/sbin/${PN} \
+               -e '/require_root$/d' \
+               -e '/update_limits$/d' \
+               -e '/ulimit/d' \
+               -e '/coredump_filter/d' || die
+       default
+       #delete problematic class in bundled log4j
+       zip -q -d \
+               usr/lib/unifi-video/lib/log4j-core-2.1.jar \
+               org/apache/logging/log4j/core/lookup/JndiLookup.class || die
+}
+
+src_install() {
+       export CODEPATH=/usr/lib/${PN}
+       export DATAPATH=/var/lib/${PN}
+       LOGPATH=${DATAPATH}/logs
+       VARLOGPATH=/var/log/${PN}
+
+       insinto /usr/lib
+       doins -r .${CODEPATH}
+       into /usr
+       dosbin usr/sbin/unifi-video
+
+       keepdir ${LOGPATH}
+       dodir ${DATAPATH}
+       fowners -R ${PN}:${PN} ${DATAPATH}
+       dosym ${LOGPATH} ${VARLOGPATH}
+       dosym ${LOGPATH} ${CODEPATH}/logs
+
+       dosym ${DATAPATH} ${CODEPATH}/data
+
+       fperms 500 ${CODEPATH}/bin/ubnt.avtool
+       fperms 500 ${CODEPATH}/bin/evostreamms
+       fperms 500 /usr/sbin/${PN}
+       fowners -R ${PN}:${PN} ${CODEPATH}
+       fperms -R 0400 ${CODEPATH}/lib/
+       fperms 500 ${CODEPATH}/lib/
+
+       echo "CONFIG_PROTECT=\"${DATAPATH}/system.properties\"" > "${T}"/99${PN}
+       doenvd "${T}"/99${PN}
+
+       dosym ../../../bin/mongod ${CODEPATH}/bin/mongod
+
+       newinitd "${FILESDIR}"/${PN}.initd ${PN}
+       systemd_dounit "${FILESDIR}"/${PN}.service
+}
+
+pkg_postinst() {
+       if [[ ! -f ${DATAPATH}/system.properties ]]; then
+               cp ${CODEPATH}/etc/system.properties 
${DATAPATH}/system.properties
+               echo uuid=$(uuidgen) >> ${DATAPATH}/system.properties
+       fi
+}