commit: 5cb9f8d6b376352d484c7ddb04d8add46dbb92c0
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 16 20:18:35 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jan 16 22:03:19 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5cb9f8d6
dev-python/sphinx: Bump to 4.4.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sphinx/Manifest | 1 +
dev-python/sphinx/sphinx-4.4.0.ebuild | 120 ++++++++++++++++++++++++++++++++++
2 files changed, 121 insertions(+)
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 037a53dc0c0a..6b147894a1e0 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,3 +1,4 @@
DIST Sphinx-3.5.4.tar.gz 5911093 BLAKE2B
8740714dfaf3733bf57d0b277315b4e7b5cad86247ea30dcbc4f5dadf5f5169329050b7be43ec8625c47df9dcc19afcc6c4d782725c7007f8178b7eb7be7dc05
SHA512
853379f3b0496772846be9beb072c2c8a69ff899ffe4c6435b448ea639a32138c61403f9c14f62f4f78b2e526a2ee7c05b4196eabdeee37bcae6aa98df992125
DIST Sphinx-4.3.1.tar.gz 6655951 BLAKE2B
eacc9d39e1a108dba1f8d3bd96d7f78f1755f23233c8068dbe598f3d3539d9cf0ea9c12374e0ffc4f471004bbe7cbd6e80ebfa7bcfbf85e5d8c34ed4adfb2acb
SHA512
0b7ceb369783d30685c10783fe10b58e92a2f5ae50dda1b6cfb021b0d33fb424a2c6cddc6b97018b63347127fc74ed4f7a442c312ce9e75ceb537f127a46bb9d
DIST Sphinx-4.3.2.tar.gz 6657148 BLAKE2B
952cecc20e3f7e046c3ae2abc8524091af82f7947f889320deab3ec82947f793d4dab86ae47f117c84ecdb2e4e50fe531469dffca2806c45500a06c7322bb11b
SHA512
2045e1964aef54826a2cde30e6c09b7ec35d49a45b7e449c07ee107c41304435eb51e2be307af77bed4ec50534e6e4009501d58187baa1a129134b69cdc56dff
+DIST Sphinx-4.4.0.tar.gz 6690021 BLAKE2B
5f63a6a70b8fb663ff1729766183f8936c9cd3bab81437526fb099ccc2a49c2abd42b602e2fc37af79254a9c8f1238fb4c99f2659142e9b9c2c1a2bd385ac100
SHA512
f5780a7da7a5d758b0e145ab9a7f191a9c65fd3ca4624ca3a04f0d161e3cd6c7133df53ff56e42f012687cbce0460178c2e7957974b5b929b341c98db996c640
diff --git a/dev-python/sphinx/sphinx-4.4.0.ebuild
b/dev-python/sphinx/sphinx-4.4.0.ebuild
new file mode 100644
index 000000000000..e18b57cc9f30
--- /dev/null
+++ b/dev-python/sphinx/sphinx-4.4.0.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="https://www.sphinx-doc.org/
+ https://github.com/sphinx-doc/sphinx";
+SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
+S=${WORKDIR}/${P^}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390
~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+ <dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+ >=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+ <dev-python/docutils-0.18[${PYTHON_USEDEP}]
+ dev-python/imagesize[${PYTHON_USEDEP}]
+ >=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+ >=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_metadata-4.4[${PYTHON_USEDEP}]
+ ' python3_{8,9} pypy3)
+ latex? (
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )"
+BDEPEND="
+ doc? (
+ dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+ media-gfx/graphviz
+ )
+ test? (
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ virtual/imagemagick-tools[jpeg,png,svg]
+ dev-texlive/texlive-fontsextra
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-3.2.1-doc-link.patch"
+ "${FILESDIR}/${PN}-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # disable internet access
+ sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+ doc/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ esetup.py build_sphinx
+ HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+ fi
+}
+
+python_test() {
+ mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+ local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+ local EPYTEST_DESELECT=(
+ # these tests require Internet access
+ tests/test_build_latex.py::test_latex_images
+ tests/test_build_linkcheck.py::test_defaults
+ tests/test_build_linkcheck.py::test_defaults_json
+ tests/test_build_linkcheck.py::test_anchors_ignored
+ tests/test_build_linkcheck.py::test_linkcheck_exclude_documents
+ # TODO
+ tests/test_ext_autodoc_autoclass.py::test_classes
+ tests/test_ext_autodoc_autofunction.py::test_classes
+ )
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ tests/test_build_linkcheck.py::test_connect_to_selfsigned_fails
+ tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+
tests/test_ext_autodoc.py::test_autodoc_typed_inherited_instance_variables
+ tests/test_ext_autodoc.py::test_autodoc_typed_instance_variables
+ tests/test_ext_autodoc.py::test_automethod_for_builtin
+ tests/test_ext_autodoc.py::test_cython
+ tests/test_ext_autodoc.py::test_partialfunction
+ tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+
tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+
tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+ tests/test_ext_autodoc_autodata.py::test_autodata_type_comment
+ tests/test_ext_autodoc_autofunction.py::test_builtin_function
+ tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+ tests/test_ext_autodoc_configs.py::test_autodoc_type_aliases
+
tests/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
+
tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+
tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+ tests/test_pycode_parser.py::test_annotated_assignment
+ )
+
+ epytest
+}
