commit: 055dc8c8cb3f99ea08a2b0a76307cde1072e8438
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 27 03:23:21 2022 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Jan 27 03:24:38 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=055dc8c8
net-misc/gnome-remote-desktop: Version bump to 41.2
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
net-misc/gnome-remote-desktop/Manifest | 1 +
.../gnome-remote-desktop-41.2.ebuild | 62 ++++++++++++++++++++++
2 files changed, 63 insertions(+)
diff --git a/net-misc/gnome-remote-desktop/Manifest
b/net-misc/gnome-remote-desktop/Manifest
index 3680f1ca71ce..dba1849c41bf 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
DIST gnome-remote-desktop-40.2.tar.xz 65400 BLAKE2B
47be88529c365e5ab72b225aae1ad0fdca4748c39476ea1251db8f317e7fc25e90acf0b908f64f0a2111e0c59d8a213ede6945fe75151cdca6ab2cf8a77351cc
SHA512
f39feb5b4b89d1c504a07c5dcf5962a4340cfc45c70d806a2b6739512ca80671dd8b7928a6dad83165dbba50b17c7961e329ecae0dd59f3f57f4fcf0f7969466
+DIST gnome-remote-desktop-41.2.tar.xz 111000 BLAKE2B
1d6dfcc9860a5253cfb2a8111c5c039e7d236f45fa79a74ddc479f449b01ddb231368c4b604d28a8f796ab33f1648a332e110fd2adb9b739032dba67c029b9f8
SHA512
7636c0446c86748ce51c869734a2d33d8285c30616a28a0358f45d8399fd9f5dba7a1bdb830d3ca4753982ac3b9715604eb5934906645a1c11c58b4342c524eb
diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-41.2.ebuild
b/net-misc/gnome-remote-desktop/gnome-remote-desktop-41.2.ebuild
new file mode 100644
index 000000000000..f620ffba9531
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-41.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+inherit gnome.org gnome2-utils meson python-any-r1 systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop";
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+ x11-libs/cairo
+ >=dev-libs/glib-2.68:2
+ >=media-video/pipewire-0.3.0:=
+ app-crypt/libsecret
+ x11-libs/libnotify
+ rdp? (
+ >=net-misc/freerdp-2.3:=[server]
+ >=sys-fs/fuse-3.9.1
+ >=x11-libs/libxkbcommon-1.0.0
+ )
+ vnc? (
+ net-libs/libvncserver
+ )
+"
+RDEPEND="${DEPEND}
+ x11-wm/mutter[screencast]
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ virtual/pkgconfig
+"
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use rdp)
+ $(meson_use vnc)
+ -Dnvenc=false
+ $(meson_use systemd)
+ -Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
