[gentoo-commits] repo/gentoo:master commit in: dev-python/notify2/

[Michał Górny]

commit:     261ad61f2235d32f95d9ae9667fd87191829f38c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 29 15:36:08 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 29 15:43:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=261ad61f

dev-python/notify2: Switch to PEP 517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/notify2/notify2-0.3.1-r3.ebuild | 40 ++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

diff --git a/dev-python/notify2/notify2-0.3.1-r3.ebuild 
b/dev-python/notify2/notify2-0.3.1-r3.ebuild
new file mode 100644
index 000000000000..18e4358229b8
--- /dev/null
+++ b/dev-python/notify2/notify2-0.3.1-r3.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Python interface to DBus notifications"
+HOMEPAGE="https://bitbucket.org/takluyver/pynotify2";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="examples"
+
+RDEPEND="dev-python/dbus-python[${PYTHON_USEDEP}]"
+BDEPEND="test? (
+       dev-python/pygobject[${PYTHON_USEDEP}]
+       sys-apps/dbus[X]
+       x11-libs/gdk-pixbuf[introspection]
+       virtual/notification-daemon
+)"
+
+distutils_enable_tests unittest
+
+python_test() {
+       virtx eunittest
+}
+
+python_install_all() {
+       if use examples; then
+               rm examples/notify2.py || die
+               dodoc -r examples
+       fi
+       distutils-r1_python_install_all
+}