commit: 9bd0884b66c06dc814136b2d5934263ce309dddc
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 12 19:21:18 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Feb 12 20:24:15 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9bd0884b
dev-python/pandas: Bump to 1.4.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pandas/Manifest | 1 +
dev-python/pandas/pandas-1.4.1.ebuild | 192 ++++++++++++++++++++++++++++++++++
2 files changed, 193 insertions(+)
diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index f9d0d2479f80..02dc11a49026 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -2,3 +2,4 @@ DIST pandas-1.3.3.tar.gz 4730758 BLAKE2B
0ef945b2181329265b93fbdb7f9c35497ef8475
DIST pandas-1.3.4.tar.gz 4734599 BLAKE2B
a71b5b57198defcf4f6d848f445c7112668994f089b62a6bce1028ab4ba8a9bf3adc3c393699332fb0c76818ed80164843114e68e57232c495cee03ec5e88009
SHA512
c821365b1f06d69c61b957c4768a5f86b39d97d74b0732ea0eaade9d21bca8f652e38f91f83adf2fc6488f227c75d4e5e64e8f131456e7f0a93ecfcf237190a6
DIST pandas-1.3.5.tar.gz 4736591 BLAKE2B
7c7de1485028d7c610c5a23ca1cc98551b24e824b609b7a624469f2471bb8d3984a25db48ab7413aa7cdd0057c5c5c9f1eb2b59cfc5cbf6d30177e12e2acc7b3
SHA512
cf3f76894cae19784af6393d4a575d114b55621a3d594edd7e95ac6d5c8588a580135789c859c618acfeceeb710d2a1fdd94188a839a90be6b58af929e00a726
DIST pandas-1.4.0.tar.gz 4935046 BLAKE2B
f579abe78812d9c155c2d08708f6b46ac7363d351a750cc5b2017aa641f5307ae0baa7de57866dbefe74790133d2219d6742cb6f015f8a360365cf30345a0b44
SHA512
800909c4e80ab50391e22bf67ccd78532730e200bc58ffc32d4a6b9e37522a90e2ed486a02f67a4df1e28fa531c075e0caadc2c8a06b8a06c7f2ef466a371489
+DIST pandas-1.4.1.tar.gz 4941369 BLAKE2B
ce85253b32c3be6baad74e2bca98d24b43f42c311ffad128615b711e461a76067035e238cf1693eed12d4ca8e354aef56f711e45cd934a4af6222f4727838b1e
SHA512
2d8ba8f3152b5bd5495e406ce21d896342ef77473ed3c0207f77b6503c3f4353bbeb5ec573696eb6748e65e956d9d1b97d314a136104151ecb5ba822afa72422
diff --git a/dev-python/pandas/pandas-1.4.1.ebuild
b/dev-python/pandas/pandas-1.4.1.ebuild
new file mode 100644
index 000000000000..a8fcbe6d2e0d
--- /dev/null
+++ b/dev-python/pandas/pandas-1.4.1.ebuild
@@ -0,0 +1,192 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 multiprocessing optfeature virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="https://pandas.pydata.org/ https://github.com/pandas-dev/pandas/";
+SRC_URI="
+
https://github.com/pandas-dev/pandas/releases/download/v${PV}/${P}.tar.gz";
+S="${WORKDIR}/${P/_/}"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+ >=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
+ >=dev-python/numexpr-2.7.0[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+OPTIONAL_DEPEND="
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ dev-python/blosc[${PYTHON_USEDEP}]
+ || (
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ )
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ || (
+ dev-python/openpyxl[${PYTHON_USEDEP}]
+ dev-python/xlsxwriter[${PYTHON_USEDEP}]
+ )
+ >=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+ >=dev-python/xarray-0.12.3[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-1.3.0[${PYTHON_USEDEP}]
+ >=dev-python/xlrd-1.2.0[${PYTHON_USEDEP}]
+ >=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
+ !hppa? (
+ dev-python/statsmodels[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+ )
+ X? (
+ || (
+ dev-python/PyQt5[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ x11-misc/xsel
+ )
+ )
+"
+COMMON_DEPEND="
+ >=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-2.8.1-r3[${PYTHON_USEDEP}]
+ >=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+ >=dev-python/cython-0.29.24[${PYTHON_USEDEP}]
+ doc? (
+ ${VIRTUALX_DEPEND}
+ app-text/pandoc
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/ipython[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ dev-python/nbsphinx[${PYTHON_USEDEP}]
+ >=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+ >=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+ >=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/rpy[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/xlrd[${PYTHON_USEDEP}]
+ dev-python/xlwt[${PYTHON_USEDEP}]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ )
+ test? (
+ ${VIRTUALX_DEPEND}
+ ${RECOMMENDED_DEPEND}
+ ${OPTIONAL_DEPEND}
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ >=dev-python/hypothesis-5.5.3[${PYTHON_USEDEP}]
+ dev-python/openpyxl[${PYTHON_USEDEP}]
+ dev-python/pymysql[${PYTHON_USEDEP}]
+ >=dev-python/pytest-6[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-1.31[${PYTHON_USEDEP}]
+ dev-python/psycopg:2[${PYTHON_USEDEP}]
+ dev-python/xlsxwriter[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ x11-misc/xsel
+ )
+"
+# dev-python/statsmodels invokes a circular dep
+# hence rm from doc? ( ), again
+RDEPEND="${COMMON_DEPEND}
+ !minimal? ( ${RECOMMENDED_DEPEND} )
+ full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+python_prepare_all() {
+ local PATCHES=(
+ # https://github.com/pandas-dev/pandas/issues/44980
+ "${FILESDIR}"/pandas-1.4.0-distutils-hack-assertion.patch
+ )
+
+ # Prevent un-needed download during build
+ sed -e "/^ 'sphinx.ext.intersphinx',/d" \
+ -i doc/source/conf.py || die
+
+ # requires package installed
+ sed -e '/extra_compile_args =/s:"-Werror"::' \
+ -i setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile() {
+ distutils-r1_python_compile -j1
+}
+
+python_compile_all() {
+ # To build docs the need be located in $BUILD_DIR,
+ # else PYTHONPATH points to unusable modules.
+ if use doc; then
+ cd "${BUILD_DIR}"/lib || die
+ cp -ar "${S}"/doc . && cd doc || die
+ LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+ fi
+}
+
+src_test() {
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # test for rounding errors, fails if we have better precision
+ # e.g. on amd64 with FMA or on arm64
+ # https://github.com/pandas-dev/pandas/issues/38921
+
pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
+
+ # TODO
+
pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated
+
pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated_direct
+ )
+
+ local -x LC_ALL=C.UTF-8
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ "${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+ epytest pandas --skip-slow --skip-network -m "not single" \
+ -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
+ die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ if use doc; then
+ dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+ einfo "An initial build of docs is absent of references to
statsmodels"
+ einfo "due to circular dependency. To have them included,
emerge"
+ einfo "statsmodels next and re-emerge pandas with USE doc"
+ fi
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "accelerating certain types of NaN evaluations, using
specialized cython routines to achieve large speedups." dev-python/bottleneck
+ optfeature "accelerating certain numerical operations, using multiple
cores as well as smart chunking and caching to achieve large speedups"
">=dev-python/numexpr-2.1"
+ optfeature "needed for pandas.io.html.read_html"
dev-python/beautifulsoup4 dev-python/html5lib dev-python/lxml
+ optfeature "for msgpack compression using blosc" dev-python/blosc
+ optfeature "Template engine for conditional HTML formatting"
dev-python/jinja
+ optfeature "Plotting support" dev-python/matplotlib
+ optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.0"
dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+ optfeature "necessary for HDF5-based storage"
">=dev-python/pytables-3.2.1"
+ optfeature "R I/O support" dev-python/rpy
+ optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+ optfeature "SQL database support" ">=dev-python/sqlalchemy-1.3.0"
+ optfeature "miscellaneous statistical functions" dev-python/scipy
+ optfeature "necessary to use pandas.io.clipboard.read_clipboard
support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}
