commit: 1a1837e58299e046422a9bccb266f48f9fd61428
Author: Nick Sarnie <sarnex <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 20 01:54:11 2022 +0000
Commit: Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Sun Feb 20 02:09:07 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a1837e5
dev-util/vulkan-tools: Version bump
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>
dev-util/vulkan-tools/Manifest | 1 +
dev-util/vulkan-tools/vulkan-tools-1.3.204.ebuild | 83 +++++++++++++++++++++++
2 files changed, 84 insertions(+)
diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 035961f14a8b..1e15adb6e757 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1 +1,2 @@
DIST vulkan-tools-1.2.198.tar.gz 847429 BLAKE2B
8927740853eb45d495996a8be0bae3d40f84f14f12eb838474241745321d7337a6bae7e118bd626fbb15f8ffd42d574a04c93bd3aca0b3373976d7d976c05d2d
SHA512
304ce76c47d4adef3a286439712ef4fd3f08ec8e47ed0e2a37162f9cac5e08af3c7b7fb449fddd4772080d678d84db9e238a5db4d98c7d4ee5f6d87a3f5c8f5f
+DIST vulkan-tools-1.3.204.tar.gz 860464 BLAKE2B
d0fdf95bff0dc914cb324a0780763dd87120b7f88a7bfaa6a2e0adef72263bd9cb0769636eda793ca5517560903ce314b96a5e3b00e018010ba0f99f68ba05cd
SHA512
1295d0e86b8b81e33b0cd1038847211fb808456435fce9446f9890f8653b854dbd1e8b84a22b646b0fddb8cca33aaee12a2edc043e76c9c4bc718b11f281a98f
diff --git a/dev-util/vulkan-tools/vulkan-tools-1.3.204.ebuild
b/dev-util/vulkan-tools/vulkan-tools-1.3.204.ebuild
new file mode 100644
index 000000000000..3b9fcf9a3c97
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.3.204.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Tools
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{8,9} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+ EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git";
+ EGIT_SUBMODULES=()
+ inherit git-r3
+else
+
SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.0.tar.gz ->
${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv"
+ S="${WORKDIR}"/${MY_PN}-sdk-${PV}.0
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android,
and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools";
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland +X"
+
+# Cube demo only supports one window system at a time
+REQUIRED_USE="cube? ( ^^ ( X wayland ) )"
+
+BDEPEND="${PYTHON_DEPS}
+ >=dev-util/cmake-3.10.2
+ cube? ( ~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+ ~media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+ wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+ X? (
+ x11-libs/libX11:=[${MULTILIB_USEDEP}]
+ x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+ )
+"
+DEPEND="${RDEPEND}
+ ~dev-util/vulkan-headers-${PV}
+"
+
+pkg_setup() {
+ MULTILIB_CHOST_TOOLS=(
+ /usr/bin/vulkaninfo
+ )
+
+ use cube && MULTILIB_CHOST_TOOLS+=(
+ /usr/bin/vkcube
+ /usr/bin/vkcubepp
+ )
+
+ python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+ -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+ -DCMAKE_SKIP_RPATH=ON
+ -DBUILD_VULKANINFO=ON
+ -DBUILD_CUBE=$(usex cube)
+ -DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+ -DBUILD_WSI_XCB_SUPPORT=$(usex X)
+ -DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+ -DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+ )
+
+ use cube && mycmakeargs+=(
+ -DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
+ -DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
+ )
+
+ cmake_src_configure
+}
+
+multilib_src_install() {
+ cmake_src_install
+}
