[gentoo-commits] repo/gentoo:master commit in: dev-python/paramiko/

[Michał Górny]

commit:     5f8627b3327fc2bf1f725cdbddd40523ae44ee67
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 26 10:15:56 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Feb 26 10:26:36 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5f8627b3

dev-python/paramiko: Migrate to PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/paramiko/paramiko-2.9.2-r1.ebuild | 54 ++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/dev-python/paramiko/paramiko-2.9.2-r1.ebuild 
b/dev-python/paramiko/paramiko-2.9.2-r1.ebuild
new file mode 100644
index 000000000000..c5a3eb1b9e81
--- /dev/null
+++ b/dev-python/paramiko/paramiko-2.9.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="SSH2 protocol library"
+HOMEPAGE="https://www.paramiko.org/ https://github.com/paramiko/paramiko/ 
https://pypi.org/project/paramiko/";
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 
~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris"
+IUSE="examples server"
+
+RDEPEND="
+       >=dev-python/bcrypt-3.1.3[${PYTHON_USEDEP}]
+       >=dev-python/cryptography-2.5[${PYTHON_USEDEP}]
+       >=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+       >=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               dev-python/mock[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_sphinx sites/docs
+distutils_enable_tests pytest
+
+src_prepare() {
+       local PATCHES=(
+               "${FILESDIR}/${PN}-2.7.1-tests.patch"
+       )
+
+       if ! use server; then
+               PATCHES+=( "${FILESDIR}/${PN}-2.4.2-disable-server.patch" )
+       fi
+       distutils-r1_src_prepare
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+
+       if use examples; then
+               docinto examples
+               dodoc -r demos/*
+       fi
+}