commit: 16466676a8be80654c41c04e1bee602bee3e5830
Author: Matthew Smith <matthew <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 28 19:26:05 2022 +0000
Commit: Matthew Smith <matthew <AT> gentoo <DOT> org>
CommitDate: Mon Feb 28 19:43:08 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=16466676
dev-python/uranium: add 4.13.0
Signed-off-by: Matthew Smith <matthew <AT> gentoo.org>
dev-python/uranium/Manifest | 1 +
dev-python/uranium/uranium-4.13.0.ebuild | 103 +++++++++++++++++++++++++++++++
2 files changed, 104 insertions(+)
diff --git a/dev-python/uranium/Manifest b/dev-python/uranium/Manifest
index 14462ae9277d..955910a6060a 100644
--- a/dev-python/uranium/Manifest
+++ b/dev-python/uranium/Manifest
@@ -1,2 +1,3 @@
DIST uranium-4.12.1.tar.gz 1071662 BLAKE2B
bb4bbcd9129dcb724a553c327a90619d12c3daaee3468ed194f8ab98f112d503638fd3ba340e67e12268d0aab23bf1cd9b4ee364c0204761949d2a58fbdfcf96
SHA512
bdf118341a52ac957ae8cc0acf2fb2c7381f9082e82c190a038333845ffc0fefa8c92702438898a63ccca9f0add69312b43168b993fcd38fe4f3ee3856b36eb9
+DIST uranium-4.13.0.tar.gz 1072294 BLAKE2B
3d5110ec4fc6bbfbf085d1f2c177ae19305d7e3828cfe44f7e83aa07397224e3c4e5441f83684f49f21fc6579eb7d3e7fc176eae80c76c3b10354757c01ecc40
SHA512
bba41754670b42eb92826fe1c2380b76afb62d16158c07f960315dbd77c55932d29dff594d71aff8eafc2f58d1aac4a14b0f6fc36a0a352872077b97c0d7f555
DIST uranium-4.9.1.tar.gz 1038046 BLAKE2B
3304e89e0a22fbda0e9e57aaf88f6f11979eb5273d6c8a69f5ec9f050741561f67667a76e2136148808862026e2330f3b5043141ed8d69d255632a8c3c869def
SHA512
e665a1ff8ebfc629e4bc2253533a3332d8f8804155432af921ad2e7251d5725daf9346cc5f110595914ac6f0d194db6d7e06dfcd3795b57e35b3d5e6dae594a7
diff --git a/dev-python/uranium/uranium-4.13.0.ebuild
b/dev-python/uranium/uranium-4.13.0.ebuild
new file mode 100644
index 000000000000..82941abd67bc
--- /dev/null
+++ b/dev-python/uranium/uranium-4.13.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake distutils-r1
+
+MY_PN="Uranium"
+
+DESCRIPTION="A Python framework for building 3D printing related applications"
+HOMEPAGE="https://github.com/Ultimaker/Uranium";
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz ->
${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug doc test"
+
+BDEPEND="${PYTHON_DEPS}
+ sys-devel/gettext
+ doc? ( app-doc/doxygen[dot] )
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/mypy[${PYTHON_USEDEP}]
+ dev-python/twisted[${PYTHON_USEDEP}]
+ ')
+ )"
+
+DEPEND="${PYTHON_DEPS}
+ ~dev-libs/libarcus-${PV}:=[python,${PYTHON_SINGLE_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/PyQt5[${PYTHON_USEDEP},declarative,network,svg]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+ sci-libs/shapely[${PYTHON_USEDEP}]
+ ')"
+
+RDEPEND="${DEPEND}
+ dev-qt/qtquickcontrols:5
+ dev-qt/qtquickcontrols2:5"
+
+DOCS=( README.md )
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ python_fix_shebang .
+
+ if ! use doc ; then
+ sed -i -e '/add_custom_target(doc/d' CMakeLists.txt || die
+ fi
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DCURA_BINARY_DATA_DIRECTORY:STRING="/usr/share/cura/"
+ -DGETTEXT_MSGINIT_EXECUTABLE="msginit"
+ )
+
+ if ! use debug; then
+ sed -i -e 's logging.DEBUG logging.ERROR g' \
+ plugins/ConsoleLogger/ConsoleLogger.py \
+ plugins/FileLogger/FileLogger.py || die
+ fi
+
+ sed -i \
+ -e "s/find_package(PythonInterp 3 REQUIRED/find_package(Python3
${EPYTHON##python} EXACT REQUIRED COMPONENTS Interpreter/g" \
+ CMakeLists.txt cmake/UraniumPluginInstall.cmake
+
+ sed -i \
+ -e "s/find_package(Python3 REQUIRED/find_package(Python3
${EPYTHON##python} EXACT REQUIRED/g" \
+ -e 's/set(Python3_EXECUTABLE ${PYTHON_EXECUTABLE})//g' \
+ cmake/UraniumPluginInstall.cmake
+
+ sed -i \
+ -e "s
lib\${LIB_SUFFIX}/python\${PYTHON_VERSION_MAJOR}.\${PYTHON_VERSION_MINOR}/site-packages
$(python_get_sitedir) g" \
+ -e 's cmake-${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} cmake
g' \
+ CMakeLists.txt
+
+ cmake_src_configure
+}
+
+src_compile() {
+ cmake_src_compile
+
+ use doc && cmake_src_compile doc
+}
+
+src_install() {
+ cmake_src_install
+
+ python_optimize "${ED}"/usr
+}
