[gentoo-commits] repo/gentoo:master commit in: dev-util/include-what-you-use/

[Florian Schmaus]

commit:     e44df6ee74cb29270f717eca970dfa5409567b8f
Author:     Florian Schmaus <flow <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  8 08:24:17 2022 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Fri Apr  8 08:26:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e44df6ee

dev-util/include-what-you-use: add 0.18

Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 dev-util/include-what-you-use/Manifest             |  1 +
 .../include-what-you-use-0.18.ebuild               | 58 ++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-util/include-what-you-use/Manifest 
b/dev-util/include-what-you-use/Manifest
index c5487da81efb..8dd48d6f4fd0 100644
--- a/dev-util/include-what-you-use/Manifest
+++ b/dev-util/include-what-you-use/Manifest
@@ -1,2 +1,3 @@
 DIST include-what-you-use-0.16.tar.gz 742573 BLAKE2B 
b8cd90db490d13f140126df8955d0968a9248480da09ca29b82fe1178c779ca75e6f29239bc6fb1556200c7d7c498f2340839e8500455ecaed9e6199fd3d55f7
 SHA512 
2923e18c40ddc5c03458b896d991adde03d489c6645ecc3cc4f69a508e323534afdef3233943e99533ffc21c64a10a8a5c635dc4797a61edf09d0a7a918a3cd5
 DIST include-what-you-use-0.17.tar.gz 747385 BLAKE2B 
0f584521b070eec6448d65d6dc4c4fe09110e85099d2696da82be800ee82522185f378c849559d899424a85864878d5b7b4790b900c438ef1f008262d6de6e28
 SHA512 
2439e3dd37163d3953fc1e45614fb4325be093a162f25d0f45fa8126b2313942a7c8d45ed12454dfbfeb4cb4fcf2f4e3eebdc0ec5da14dad23533f7a0bf58290
+DIST include-what-you-use-0.18.tar.gz 750341 BLAKE2B 
6da65c3613abe36d09a07eb56cbc40054f9176771fea61fe9ad1b662abdb8b6d7e052f6c364d618856a5dbc54655157b2d023fa42cf7e7ddf9db8dc3e736cb67
 SHA512 
bfce2ff00b572961dcba83519959cbedaf1c2ec4bd4e0a2b8b6d12f440887ee64a1c9970fa1a80c7517898ce936219436ab709893cfed92891c5c2aa5d76770e

diff --git a/dev-util/include-what-you-use/include-what-you-use-0.18.ebuild 
b/dev-util/include-what-you-use/include-what-you-use-0.18.ebuild
new file mode 100644
index 000000000000..2afa1f67ebcc
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-0.18.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake llvm python-single-r1
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/";
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LLVM_MAX_SLOT=14
+
+RDEPEND="
+       sys-devel/clang:${LLVM_MAX_SLOT}
+       sys-devel/llvm:${LLVM_MAX_SLOT}
+       ${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+llvm_check_deps() {
+       has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+       llvm_pkg_setup
+       python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       cmake_src_prepare
+       python_fix_shebang .
+}
+
+src_configure() {
+       local mycmakeargs=(
+               # Note [llvm install path]
+               # Unfortunately all binaries using clang driver
+               # have to reside at the same path depth as
+               # 'clang' binary itself. See bug #625972
+               # Thus as a hack we install it to the same directory
+               # as llvm/clang itself.
+               -DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
+       )
+       cmake_src_configure
+}
+
+src_test() {
+       "${EPYTHON}" run_iwyu_tests.py
+}