[gentoo-commits] repo/gentoo:master commit in: dev-python/zope-deprecation/

[Michał Górny]

commit:     ad347a5dbed08f11f9ecc2b52598a212697ee8df
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  9 19:02:41 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr  9 19:07:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ad347a5d

dev-python/zope-deprecation: EAPI 8, PEP517, remove namespace dep

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../zope-deprecation-4.4.0-r1.ebuild               | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-python/zope-deprecation/zope-deprecation-4.4.0-r1.ebuild 
b/dev-python/zope-deprecation/zope-deprecation-4.4.0-r1.ebuild
new file mode 100644
index 000000000000..3aa022b61549
--- /dev/null
+++ b/dev-python/zope-deprecation/zope-deprecation-4.4.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Zope Deprecation Infrastructure"
+HOMEPAGE="
+       https://pypi.org/project/zope.deprecation/
+       https://github.com/zopefoundation/zope.deprecation/
+"
+SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+       # strip rdep specific to namespaces
+       sed -i -e "/'setuptools'/d" setup.py || die
+       distutils-r1_src_prepare
+}
+
+python_compile() {
+       distutils-r1_python_compile
+       find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+       cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+       # this is needed to keep the tests working while
+       # dev-python/namespace-zope is still installed
+       cat > zope/__init__.py <<-EOF || die
+               __path__ = __import__('pkgutil').extend_path(__path__, __name__)
+       EOF
+       eunittest
+       rm zope/__init__.py || die
+}