commit: b9b5e104822a6f41f31d373687173e889c063ca5
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 11 06:42:35 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 11 07:41:16 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b9b5e104
dev-python/setuptools: Bump to 62.1.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/setuptools/Manifest | 1 +
dev-python/setuptools/setuptools-62.1.0.ebuild | 132 +++++++++++++++++++++++++
2 files changed, 133 insertions(+)
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 31a1e2d6d349..5f46d4fb7593 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -6,3 +6,4 @@ DIST setuptools-60.9.2.tar.gz 2425956 BLAKE2B
09baded7eef555ebd76db1672d69cd06cf
DIST setuptools-61.3.0.gh.tar.gz 2643769 BLAKE2B
4ede87e7a597a6916dc089c311b0e4d098b08debbd1c4a9cb97078730e9cdc8dbcacd4236ca98a42e3cfafdf66d8f39bb64bc9135291335224b1c3b0bf79deff
SHA512
35e2b848cf79e577b8c469562cb68a80b27d42d2d9c1c94f84fea9beb85e2db0796ed64d414add67a404d801c4f4e6cd489a72153de4dc8ed8b45fab24c28fd9
DIST setuptools-61.3.1.tar.gz 2508220 BLAKE2B
be59b7f666d8cc583b98b73d681eddf2d15e1437f05ddb534cb6e95bf458aed01a6e136ddc10bef2b2f66fe3f888187ece8262906079f1321f194e03a93fccca
SHA512
463f2203416a298f65b66199fd62941ed32fc0914a4b6afff74b4abb8db37c063ab208a67383b5a7e6108a8c1ed0fda0fbb6b47d8fbc95c68b9e23e4ba152aec
DIST setuptools-62.0.0.tar.gz 2512032 BLAKE2B
688afed5a19e70a0fd7ab91a8d137e6641597d9f9acf31826216cd59e4632872a9661fe9ca18e45aec5cd40e52956147aa8d40ac2c376380ffa0f01dc2997e63
SHA512
9017ab055c81063eaf741d45bd2479fcf85d15795bdcf0fa55522d194a69b5a912cbdba94e9eeaa6cf2a6cdaa5dda09604205d6e02d56e7c9fd3be4c1c79ba0a
+DIST setuptools-62.1.0.tar.gz 2512885 BLAKE2B
a26a6bd5001922885b623bc7f1d42da90c59e6d9e195e9dd292ce2e73cd35a51f07fc714261c12db2fdf4510fa1137f57e7f3f649312f6a75035b9d927936a7c
SHA512
41f39b5aa22e908c123e8e04c11e505e23cd3aaaae72793e106015dc14b1a44ff3b17aa15ca3da34f34a4becc887ceea7f41932650e38d409f95d7227707d2e1
diff --git a/dev-python/setuptools/setuptools-62.1.0.ebuild
b/dev-python/setuptools/setuptools-62.1.0.ebuild
new file mode 100644
index 000000000000..0bcb480a73c4
--- /dev/null
+++ b/dev-python/setuptools/setuptools-62.1.0.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.4"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+ https://github.com/pypa/setuptools/
+ https://pypi.org/project/setuptools/
+"
+SRC_URI="
+ mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+ https://dev.gentoo.org/~mgorny/dist/python/${CPY_PATCHSET}.tar.xz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~m68k ~s390 ~x86 ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+ >=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+ dev-python/nspektr[${PYTHON_USEDEP}]
+ >=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_metadata-4.10.1-r1[${PYTHON_USEDEP}]
+ ' 3.8 3.9)
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
+ ' 3.8)
+"
+BDEPEND="
+ ${RDEPEND}
+ >=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/build[${PYTHON_USEDEP}]
+ >=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+ >=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/pip[${PYTHON_USEDEP}]
+ dev-python/pip-run[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+ dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ dev-python/tomli[${PYTHON_USEDEP}]
+ >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+ dev-python/wheel[${PYTHON_USEDEP}]
+ ' python3_{8..10} pypy3)
+ )
+"
+PDEPEND="
+ >=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+ # remove bundled dependencies, setuptools will switch to system deps
+ # automatically
+ rm -r */_vendor || die
+
+ # remove the ugly */extern hack that breaks on unvendored deps
+ rm -r */extern || die
+ find -name '*.py' -exec sed \
+ -e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+ -i {} + || die
+
+ # apply distutils patches to the bundled distutils
+ pushd setuptools/_distutils >/dev/null || die
+ # TODO: distutils C++ patch?
+ eapply -p3
"${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+ popd >/dev/null || die
+
+ distutils-r1_src_prepare
+
+ export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+ local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+ # keep in sync with python_gen_cond_dep above!
+ has "${EPYTHON}" python3.{8..10} pypy3 || continue
+
+ local EPYTEST_DESELECT=(
+ # network
+ # TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+
setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+ setuptools/tests/test_distutils_adoption.py
+ setuptools/tests/test_virtualenv.py::test_clean_env_install
+
setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+
'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+
setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+
setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+
setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+ # unhappy with pytest-xdist?
+
setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+ # TODO
+
setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+ setuptools/tests/test_test.py::test_tests_are_run_once
+
setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+
setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+ # expects bundled deps in virtualenv
+
setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+
setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+
setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+ )
+
+ # test_easy_install raises a SandboxViolation due to
${HOME}/.pydistutils.cfg
+ # It tries to sandbox the test in a tempdir
+ HOME="${PWD}" epytest \
+ -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
+}
